Rychlý start: Vytvoření souborů Bicep pomocí editoru Visual Studio Code

Tento rychlý start vás provede postupem vytvoření souboru Bicep pomocí editoru Visual Studio Code. Vytvoříte účet úložiště a virtuální síť. Dozvíte se také, jak rozšíření Bicep zjednodušuje vývoj tím, že poskytuje bezpečnost typů, ověřování syntaxe a automatické dokončování.

Podobné prostředí pro vytváření obsahu je také podporováno v sadě Visual Studio. Viz Rychlý start: Vytváření souborů Bicep pomocí sady Visual Studio.

Požadavky

Pokud ještě nemáte předplatné Azure, vytvořte si napřed bezplatný účet.

Pokud chcete nastavit prostředí pro vývoj bicep, přečtěte si téma Instalace nástrojů Bicep. Po dokončení těchto kroků máte Visual Studio Code a rozšíření Bicep. Máte také nejnovější Azure CLI nebo nejnovější modul Azure PowerShellu.

Přidání fragmentu kódu prostředku

VS Code s rozšířením Bicep zjednodušuje vývoj tím, že poskytuje předdefinované fragmenty kódu. V tomto rychlém startu přidáte fragment kódu, který vytvoří virtuální síť.

Spusťte Visual Studio Code a vytvořte nový soubor s názvem main.bicep.

V souboru main.bicep zadejte virtuální síť a pak ze seznamu vyberte možnost res-vnet a stiskněte klávesu [TAB] nebo [ENTER].

Váš soubor Bicep teď obsahuje následující kód:

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2019-11-01' = {
  name: 'name'
  location: location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

V tomto fragmentu kódu najdete všechny potřebné hodnoty pro definování virtuální sítě. Můžete si všimnout dvou složených podtržení. Žlutá označuje upozornění související se zastaralou verzí rozhraní API, zatímco červené složených podtržení signalizuje chybu způsobenou chybějící definicí parametru.

Odeberte @2019-11-01a nahraďte ho .@ Vyberte nejnovější verzi rozhraní API.

Chybu definice chybějícího parametru opravíte v další části.

Tento kód můžete také upravit tak, aby splňoval vaše požadavky. Například name není skvělým názvem pro virtuální síť. name Změňte vlastnost na examplevnet.

name: 'exampleVNet'

Přidání parametru

Fragment kódu, který jste přidali v poslední části, vynechá definici parametru.

V horní části souboru přidejte:

param location

Když za umístění přidáte mezeru, všimněte si, že IntelliSense nabízí datové typy, které jsou pro parametr k dispozici. Vyberte řetězec.

Dejte parametru výchozí hodnotu:

param location string = resourceGroup().location

Další informace o funkci použité ve výchozí hodnotě naleznete v části resourceGroup().

Přidejte další parametr pro název účtu úložiště s výchozí hodnotou:

param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Další informace naleznete v tématu Interpolace a uniqueString().

Tento parametr funguje správně, ale účty úložiště mají omezení délky názvu. Název musí obsahovat alespoň tři znaky a nesmí být delší než 24 znaků. Tyto požadavky můžete zadat přidáním dekorátorů do parametru.

Přidejte řádek nad parametr a zadejte @. Zobrazí se dostupné dekorátory. Všimněte si, že pro minLength i maxLength existují dekorátory.

Přidejte oba dekorátory a zadejte omezení znaků:

@minLength(3)
@maxLength(24)
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Můžete také přidat popis parametru. Uveďte informace, které lidem pomáhají nasadit soubor Bicep, pochopit, jakou hodnotu chcete poskytnout.

@minLength(3)
@maxLength(24)
@description('Provide a name for the storage account. Use only lower case letters and numbers. The name must be unique across Azure.')
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Vaše parametry jsou připravené k použití.

Přidat prostředek

Místo použití fragmentu kódu k definování účtu úložiště použijete IntelliSense k nastavení hodnot. IntelliSense usnadňuje tento krok než ruční zadávání hodnot.

K definování prostředku použijte resource klíčové slovo. Pod virtuální sítí zadejte příklad prostředkuStorage:

resource exampleStorage

ExampleStorage je symbolický název prostředku, který nasazujete. Tento název můžete použít k odkazování na prostředek v jiných částech souboru Bicep.

Když za symbolický název přidáte mezeru, zobrazí se seznam typů prostředků. Pokračujte v psaní úložiště, dokud ho nebudete moct vybrat z dostupných možností.

Po výběru Microsoft.Storage/storageAccounts se zobrazí dostupné verze rozhraní API. Vyberte nejnovější verzi. Na následujícím snímku obrazovky je to 2023-05-01.

Za jedinou uvozovku pro typ prostředku přidejte = a mezeru. Zobrazí se možnosti přidání vlastností do prostředku. Vyberte požadované vlastnosti.

Tato možnost přidá všechny vlastnosti pro typ prostředku, které jsou požadovány pro nasazení. Po výběru této možnosti má váš účet úložiště následující vlastnosti:

resource exampleStorage 'Microsoft.Storage/storageAccounts@2023-05-01' = {
  name:
  location:
  sku: {
    name:
  }
  kind:
}

Už jste téměř hotovi. Stačí zadat hodnoty těchto vlastností.

IntelliSense vám opět pomůže. Nastavte name na storageAccountNamehodnotu , což je parametr, který obsahuje název účtu úložiště. Nastavte locationho na locationhodnotu , což je parametr, který jste vytvořili dříve. Při přidávání sku.name a kindzobrazí IntelliSense platné možnosti.

Pokud chcete přidat volitelné vlastnosti vedle požadovaných vlastností, umístěte kurzor na požadované místo a stiskněte klávesu Ctrl+Mezerník. IntelliSense navrhuje nepoužité vlastnosti, jak je znázorněno na následujícím snímku obrazovky:

Po dokončení máte:

@minLength(3)
@maxLength(24)
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'
param location string = resourceGroup().location

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2024-01-01' = {
  name: 'exampleVNet'
  location: resourceGroup().location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

resource exampleStorage 'Microsoft.Storage/storageAccounts@2023-05-01' = {
  name: storageAccountName
  location: 'eastus'
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
}

Další informace o syntaxi Bicep naleznete v tématu Bicep struktura.

Vizualizace prostředků

Můžete zobrazit reprezentaci prostředků v souboru.

V pravém horním rohu vyberte tlačítko vizualizéru a otevřete vizualizér Bicep.

Vizualizér zobrazuje prostředky definované v souboru Bicep s informacemi o závislostech prostředků. Dva prostředky definované v tomto rychlém startu nemají vztah závislostí, takže mezi těmito dvěma prostředky nevidíte konektor.

Nasazení souboru Bicep

1. Klikněte pravým tlačítkem myši na soubor Bicep v nástroji VS Code a pak vyberte Nasadit soubor Bicep.

   

2. Do textového pole Zadejte název nasazení zadejte deployStorageAndVNet a stiskněte [ENTER]..

3. V seznamu Vybrat skupinu prostředků v horní části vyberte Vytvořit novou skupinu prostředků.

4. Jako název skupiny prostředků zadejte exampleRG a stiskněte klávesu [ENTER]..

5. Vyberte umístění pro skupinu prostředků, vyberte USA – střed nebo umístění podle vašeho výběru a stiskněte [ENTER]..

6. V části Vyberte soubor parametrů vyberte None (Žádný).

   

Vytvoření prostředků chvíli trvá. Další informace najdete v tématu Nasazení souborů Bicep pomocí editoru Visual Studio Code.

Soubor Bicep můžete také nasadit pomocí Azure CLI nebo Azure PowerShellu:

az group create --name exampleRG --location eastus

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageAccountName=uniquename

New-AzResourceGroup -Name exampleRG -Location eastus

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageAccountName "uniquename"

Po dokončení nasazení by se měla zobrazit zpráva, že nasazení bylo úspěšné.

Vyčištění prostředků

Pokud už prostředky Azure nepotřebujete, pomocí azure CLI nebo modulu Azure PowerShell odstraňte skupinu prostředků pro rychlý start.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Další kroky