Rychlý start: Vytvoření účtu Batch pomocí souboru Bicep

  • Článek

Začněte se službou Azure Batch pomocí souboru Bicep a vytvořte účet Batch, včetně úložiště. K vytvoření výpočetních prostředků (fondů výpočetních uzlů) a úloh Batch potřebujete účet Batch. Účet Azure Storage můžete propojit s účtem Batch, který je užitečný k nasazení aplikací a ukládání vstupních a výstupních dat pro většinu reálných úloh.

Po dokončení tohoto rychlého startu porozumíte klíčovým konceptům služby Batch a budete připraveni vyzkoušet službu Batch s realističtějšími úlohami ve větším měřítku.

Bicep je jazyk specifický pro doménu (DSL), který k nasazování prostředků Azure používá deklarativní syntaxi. Poskytuje stručnou syntaxi, spolehlivou bezpečnost typů a podporu pro opakované použití kódu. Bicep nabízí nejlepší prostředí pro vytváření obsahu pro řešení infrastruktury jako kódu v Azure.

Požadavky

Musíte mít aktivní předplatné Azure.

Kontrola souboru Bicep

Soubor Bicep použitý v tomto rychlém startu pochází ze šablon Azure Pro rychlý start.

@description('Batch Account Name')
param batchAccountName string = '${toLower(uniqueString(resourceGroup().id))}batch'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountsku string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

var storageAccountName = '${uniqueString(resourceGroup().id)}storage'

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountsku
  }
  kind: 'StorageV2'
  tags: {
    ObjectName: storageAccountName
  }
  properties: {
    minimumTlsVersion: 'TLS1_2'
    allowBlobPublicAccess: false
    networkAcls: {
      defaultAction: 'Deny'
    }
    supportsHttpsTrafficOnly: true
  }
}

resource batchAccount 'Microsoft.Batch/batchAccounts@2024-02-01' = {
  name: batchAccountName
  location: location
  tags: {
    ObjectName: batchAccountName
  }
  properties: {
    autoStorage: {
      storageAccountId: storageAccount.id
    }
  }
}

output storageAccountName string = storageAccount.name
output batchAccountName string = batchAccount.name
output location string = location
output resourceGroupName string = resourceGroup().name
output resourceId string = batchAccount.id

V souboru Bicep se definují dva prostředky Azure:

Nasazení souboru Bicep

  1. Uložte soubor Bicep jako main.bicep do místního počítače.

  2. Nasaďte soubor Bicep pomocí Azure CLI nebo Azure PowerShellu.

    az group create --name exampleRG --location eastus
az deployment group create --resource-group exampleRG --template-file main.bicep

    Po dokončení nasazení by se měla zobrazit zpráva, že nasazení bylo úspěšné.

Ověření nasazení

Pomocí webu Azure Portal, Azure CLI nebo Azure PowerShellu můžete zobrazit seznam nasazených prostředků ve skupině prostředků.

az resource list --resource-group exampleRG

Vyčištění prostředků

Pokud máte v plánu pokračovat v dalších kurzech, možná budete chtít tyto prostředky ponechat na místě. Pokud už ji nepotřebujete, odstraňte skupinu prostředků a všechny její prostředky pomocí webu Azure Portal, Azure CLI nebo Azure PowerShellu.

az group delete --name exampleRG

Další kroky

V tomto rychlém startu jste vytvořili účet Batch a účet úložiště pomocí Bicep. Další informace o službě Azure Batch najdete v dalších kurzech o službě Azure Batch.

Kurzy o službě Azure Batch