Rychlý start: Vytvoření profilu Traffic Manageru pomocí Bicep

Tento rychlý start popisuje, jak pomocí Bicep vytvořit profil Traffic Manageru s externími koncovými body pomocí metody směrování výkonu.

Bicep je jazyk specifický pro doménu (DSL), který k nasazování prostředků Azure používá deklarativní syntaxi. Poskytuje stručnou syntaxi, spolehlivou bezpečnost typů a podporu pro opakované použití kódu. Bicep nabízí nejlepší prostředí pro vytváření obsahu pro řešení infrastruktury jako kódu v Azure.

Požadavky

Pokud ještě nemáte předplatné Azure, vytvořte si napřed bezplatný účet.

Kontrola souboru Bicep

Soubor Bicep použitý v tomto rychlém startu pochází ze šablon Azure Pro rychlý start.

@description('Relative DNS name for the traffic manager profile, must be globally unique.')
param uniqueDnsName string

resource ExternalEndpointExample 'Microsoft.Network/trafficmanagerprofiles@2022-04-01' = {
  name: 'ExternalEndpointExample'
  location: 'global'
  properties: {
    profileStatus: 'Enabled'
    trafficRoutingMethod: 'Performance'
    dnsConfig: {
      relativeName: uniqueDnsName
      ttl: 30
    }
    monitorConfig: {
      protocol: 'HTTPS'
      port: 443
      path: '/'
      expectedStatusCodeRanges: [
        {
          min: 200
          max: 202
        }
        {
          min: 301
          max: 302
        }
      ]
    }
    endpoints: [
      {
        type: 'Microsoft.Network/TrafficManagerProfiles/ExternalEndpoints'
        name: 'endpoint1'
        properties: {
          target: 'www.microsoft.com'
          endpointStatus: 'Enabled'
          endpointLocation: 'northeurope'
        }
      }
      {
        type: 'Microsoft.Network/TrafficManagerProfiles/ExternalEndpoints'
        name: 'endpoint2'
        properties: {
          target: 'docs.microsoft.com'
          endpointStatus: 'Enabled'
          endpointLocation: 'southcentralus'
        }
      }
    ]
  }
}
output name string = ExternalEndpointExample.name
output resourceGroupName string = resourceGroup().name
output resourceId string = ExternalEndpointExample.id

Jeden prostředek Azure je definovaný v souboru Bicep:

• Microsoft.Network/trafficManagerProfiles

Nasazení souboru Bicep

1. Uložte soubor Bicep jako main.bicep do místního počítače.

2. Nasaďte soubor Bicep pomocí Azure CLI nebo Azure PowerShellu.

   • Rozhraní příkazového řádku
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters uniqueDnsName=<dns-name>
   

   Nasazení souboru Bicep vytvoří profil se dvěma externími koncovými body. Koncový bod 1 používá cílový koncový bod www.microsoft.com s umístěním v severní Evropě. Koncový bod 2 používá cílový koncový bod video2.skills-academy.com s umístěním v oblasti USA – středojiž.

   Poznámka:

   Název uniqueDNSname musí být globálně jedinečný, aby se soubor Bicep úspěšně nasadil.

   Po dokončení nasazení se zobrazí zpráva, že nasazení bylo úspěšné.

Ověření nasazení

K ověření nasazení použijte Azure CLI nebo Azure PowerShell.

1. Určete název DNS profilu Traffic Manageru.

   • Rozhraní příkazového řádku
   • PowerShell

   az network traffic-manager profile show --name ExternalEndpointExample --resource-group exampleRG 
   

   Z výstupu zkopírujte hodnotu plně kvalifikovaného názvu domény . Bude v následujícím formátu: <relativeDnsName>.trafficmanager.net. Tato hodnota je také název DNS vašeho profilu Traffic Manageru.

2. Spuštěním následujícího příkazu nahraďte proměnnou {relativeDnsName} hodnotou <relativeDnsName>.trafficmanager.net.

   • Rozhraní příkazového řádku
   • PowerShell

   nslookup -type=cname {relativeDnsName}
   

   Měli byste získat kanonický název nebo www.microsoft.com video2.skills-academy.com v závislosti na tom, která oblast je k vám blíže.

3. Pokud chcete zkontrolovat, jestli se dá přeložit na druhý koncový bod, zakažte koncový bod pro cíl, který jste získali v posledním kroku. {endpointName} nahraďte koncovým bodem 1 nebo koncovým bodem 2 a zakažte cíl pro www.microsoft.com nebo video2.skills-academy.com v uvedeném pořadí.

   • Rozhraní příkazového řádku
   • PowerShell

   az network traffic-manager endpoint update --name {endpointName} --type externalEndpoints --profile-name ExternalEndpointExample --resource-group exampleRG --endpoint-status "Disabled"
   

4. Spusťte příkaz z kroku 2 znovu v Azure CLI nebo v Azure PowerShellu. Tentokrát byste měli získat druhý kanonický název/NameHost pro druhý koncový bod.

Vyčištění prostředků

Pokud už profil Traffic Manageru nepotřebujete, odstraňte skupinu prostředků pomocí webu Azure Portal, Azure CLI nebo Azure PowerShellu. Tím se odebere profil Traffic Manageru a všechny související prostředky.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Další kroky

V tomto rychlém startu jste pomocí Bicep vytvořili profil Traffic Manageru.

Další informace o směrování provozu najdete v kurzech traffic Manageru.