Nasazení Microsoft Defender for Endpoint v Linuxu pomocí Puppetu

Chcete používat Defender pro Endpoint? Zaregistrujte se a získejte bezplatnou zkušební verzi,

Tento článek popisuje, jak nasadit Defender for Endpoint v Linuxu pomocí Puppetu. Úspěšné nasazení vyžaduje dokončení všech následujících úloh:

• Stažení balíčku pro onboarding
• Vytvoření manifestu Puppet
• Nasazení
• Kontrola stavu onboardingu

Požadavky a požadavky na systém

Popis požadavků a systémových požadavků pro aktuální verzi softwaru najdete na hlavní stránce Defenderu for Endpoint v Linuxu.

Kromě toho pro nasazení Puppetu musíte znát úlohy správy Puppetu, mít puppet nakonfigurovaný a vědět, jak nasazovat balíčky. Puppet má mnoho způsobů, jak dokončit stejný úkol. Tyto pokyny předpokládají dostupnost podporovaných modulů Puppet, například apt , které vám pomůžou s nasazením balíčku. Vaše organizace může použít jiný pracovní postup. Podrobnosti najdete v dokumentaci puppetu.

Stažení balíčku pro onboarding

Stáhněte balíček pro onboarding z portálu Microsoft Defender.

1. Na portálu Microsoft Defender přejděte na Nastavení>Koncové body>Onboardingsprávy> zařízení.

2. V první rozevírací nabídce vyberte jako operační systém Linux Server . V druhé rozevírací nabídce vyberte jako metodu nasazení Váš preferovaný nástroj pro správu konfigurace Linuxu .

3. Vyberte Stáhnout onboardingový balíček. Uložte soubor jako WindowsDefenderATPOnboardingPackage.zip.

   

4. Na příkazovém řádku ověřte, že soubor máte.

   ls -l
   

   total 8
   -rw-r--r-- 1 test  staff  4984 Feb 18 11:22 WindowsDefenderATPOnboardingPackage.zip
   

5. Extrahujte obsah archivu.

   unzip WindowsDefenderATPOnboardingPackage.zip
   

   Archive:  WindowsDefenderATPOnboardingPackage.zip
   inflating: mdatp_onboard.json
   

Vytvoření manifestu Puppet

Potřebujete vytvořit manifest Puppetu pro nasazení Defenderu for Endpoint v Linuxu do zařízení spravovaných serverem Puppet. Tento příklad využívá apt moduly a yumrepo dostupné z puppetlabs a předpokládá, že moduly byly nainstalovány na vašem serveru Puppet.

1. Vytvořte složky install_mdatp/files a install_mdatp/manifests ve složce modules vaší instalace Puppetu. Tato složka se obvykle nachází na /etc/puppetlabs/code/environments/production/modules vašem serveru Puppet.

2. mdatp_onboard.json Zkopírujte soubor vytvořený dříve do install_mdatp/files složky.

3. init.pp Vytvořte soubor, který obsahuje pokyny k nasazení:

   pwd
   

   /etc/puppetlabs/code/environments/production/modules
   

   tree install_mdatp
   

   install_mdatp
   ├── files
   │   └── mdatp_onboard.json
   └── manifests
       └── init.pp
   

Obsah install_mdatp/manifests/init.pp

Defender for Endpoint v Linuxu je možné nasadit z jednoho z následujících kanálů:

• insiders-fast, označeno jako [channel]
• účastníci programu insider-slow, označeno jako [channel]
• prod, označeno jako [channel] používající název verze (viz Linux Software Repository for Microsoft Products).

Každý kanál odpovídá úložišti softwaru v Linuxu.

Volba kanálu určuje typ a frekvenci aktualizací nabízených vašemu zařízení. Zařízení v rychlém okruhu insiderů jsou první, která obdrží aktualizace a nové funkce, za nimiž budou později následovat pomalí účastníci programu Insider a nakonec prod.

Pokud chcete získat náhled nových funkcí a poskytnout včasnou zpětnou vazbu, doporučujeme nakonfigurovat některá zařízení ve vašem podniku tak, aby používala buď rychlé účastníkyprogramu Insider, nebo pomalé účastníky programu Insider.

Poznamenejte si svoji distribuci a verzi a v části https://packages.microsoft.com/config/[distro]/identifikujte nejbližší položku.

V následujících příkazech nahraďte [distribuce] a [version] informacemi, které jste identifikovali:

# Puppet manifest to install Microsoft Defender for Endpoint on Linux.
# @param channel The release channel based on your environment, insider-fast or prod.
# @param distro The Linux distribution in lowercase. In case of RedHat, Oracle Linux, Amazon Linux 2, and CentOS 8, the distro variable should be 'rhel'.
# @param version The Linux distribution release number, e.g. 7.4.

class install_mdatp (
  $channel = 'insiders-fast',
  $distro = undef,
  $version = undef
) {
  case $facts['os']['family'] {
    'Debian' : {
      $release = $channel ? {
        'prod'  => $facts['os']['distro']['codename'],
        default => $channel
      }
      apt::source { 'microsoftpackages' :
        location => "https://packages.microsoft.com/${distro}/${version}/prod",
        release  => $release,
        repos    => 'main',
        key      => {
          'id'     => 'BC528686B50D79E339D3721CEB3E94ADBE1229CF',
          'server' => 'keyserver.ubuntu.com',
        },
      }
    }
    'RedHat' : {
      yumrepo { 'microsoftpackages' :
        baseurl  => "https://packages.microsoft.com/${distro}/${version}/${channel}",
        descr    => "packages-microsoft-com-prod-${channel}",
        enabled  => 1,
        gpgcheck => 1,
        gpgkey   => 'https://packages.microsoft.com/keys/microsoft.asc',
      }
    }
    default : { fail("${facts['os']['family']} is currently not supported.") }
  }

  case $facts['os']['family'] {
    /(Debian|RedHat)/: {
      file { ['/etc/opt', '/etc/opt/microsoft', '/etc/opt/microsoft/mdatp']:
        ensure => directory,
        owner  => root,
        group  => root,
        mode   => '0755',
      }

      file { '/etc/opt/microsoft/mdatp/mdatp_onboard.json':
        source  => 'puppet:///modules/install_mdatp/mdatp_onboard.json',
        owner   => root,
        group   => root,
        mode    => '0600',
        require => File['/etc/opt/microsoft/mdatp'],
      }

      package { 'mdatp':
        ensure  => 'installed',
        require => File['/etc/opt/microsoft/mdatp/mdatp_onboard.json'],
      }
    }
    default : { fail("${facts['os']['family']} is currently not supported.") }
  }
}

Nasazení

Do souboru zahrňte site.pp výše uvedený manifest:

cat /etc/puppetlabs/code/environments/production/manifests/site.pp

node "default" {
    include install_mdatp
}

Zaregistrovaná zařízení agenta se pravidelně dotazují na Puppet Server a instalují nové konfigurační profily a zásady, jakmile jsou zjištěny.

Monitorování nasazení Puppetu

Na zařízení agenta můžete také zkontrolovat stav onboardingu spuštěním příkazu:

mdatp health

...
licensed                                : true
org_id                                  : "[your organization identifier]"
...

• licencované: Tím potvrdíte, že je zařízení svázané s vaší organizací.

• orgId: Toto je identifikátor organizace defenderu for Endpoint.

Kontrola stavu onboardingu

Správnou registraci zařízení můžete zkontrolovat vytvořením skriptu. Následující skript například zkontroluje stav onboardingu zaregistrovaných zařízení:

mdatp health --field healthy

Výše uvedený příkaz se vytiskne 1 , pokud je produkt nasazený a funguje podle očekávání.

Pokud produkt není v pořádku, ukončovací kód (který je možné zkontrolovat) echo $?označuje problém:

• 1 pokud zařízení ještě není onboardované.
• 3 pokud nelze navázat připojení k procesu démon.

Problémy s instalací protokolu

Další informace o tom, jak najít automaticky vygenerovaný protokol vytvořený instalačním programem při výskytu chyby, najdete v tématu Problémy s instalací protokolu.

Upgrady operačního systému

Při upgradu operačního systému na novou hlavní verzi musíte nejprve odinstalovat Defender for Endpoint v Linuxu, nainstalovat upgrade a nakonec překonfigurovat Defender for Endpoint v Linuxu na vašem zařízení.

Odinstalace

Vytvořte modul remove_mdatp podobný install_mdatp modulu s následujícím obsahem v init.pp souboru:

class remove_mdatp {
    package { 'mdatp':
        ensure => 'purged',
    }
}