Cvičení – vizualizace dat pomocí operátoru vykreslování

• 6 min

Použili jsme meteorologickou datovou sadu k agregaci a porovnání počtu určitých druhů událostí bouře v různých státech USA za rok 2007. Tady tyto výsledky vizualizujete pomocí časového intervalu grafů.

Použití operátoru render

Vzpomeňte si, že jste pomocí operátoru summarize seskupili události podle společného pole, jako je Například Stát. V předchozí lekci jste použili různé verze operátoru count k porovnání počtu a typů událostí podle stavu. Vizualizace těchto výsledků může být užitečnou pomůckou při porovnávání aktivit napříč státy.

K vizualizaci výsledků použijete render operátor. Tento operátor přichází na konec dotazu. V rámci operátoru render určíte, jaký typ vizualizace se má použít, například columnchart, barchart, , piechartscatterchart, , pivotcharta další. Volitelně můžete také definovat různé vlastnosti vizualizace, například osu x nebo osu y.

V tomto příkladu vizualizujete předchozí dotaz pomocí pruhového grafu.

1. Spusťte následující dotaz.

   Spuštění dotazu

   StormEvents
   | summarize count(),
       EventsWithDamageToCrops = countif(DamageCrops > 0),
       dcount(EventType) by State
   | sort by count_
   | render barchart
   

   Měli byste získat výsledky, které vypadají jako na následujícím obrázku:

   

2. Všimněte si legendy napravo od pruhového grafu. Každá hodnota v legendě představuje jiný sloupec dat, která jsou sumarizována podle state v dotazu. Zkuste vybrat jednu z hodnot, například count_, a přepnout tak zobrazení těchto dat v pruhovém grafu. Přepnutím count_ odeberete celkový počet událostí a ponecháte celkový počet událostí, které způsobily poškození a jedinečný počet událostí. Měli byste získat graf, který vypadá jako na následujícím obrázku:

   

3. Podívejte se na výsledný pruhový graf. Jaké poznatky z toho můžete získat? Můžete si například všimnout, že Texas měl nejvíce individuálních událostí bouře, ale Iowa měla nejvyšší výskyt škodlivých událostí bouře.

Seskupení hodnot pomocí bin() funkce

Doteď jste k seskupení událostí podle stavu použili agregační funkce. Teď se podíváme na rozdělení bouřek v průběhu roku seskupením dat podle času. Časové hodnoty, které máme v každém záznamu, jsou počáteční a koncový čas. Pojďme seskupit časy zahájení události podle týdne, abychom viděli, kolik bouří se stalo každý týden v roce 2007.

Použijete bin() funkci, která seskupuje hodnoty do nastavených intervalů. Můžete mít například data z každého dne v roce a chcete je seskupit podle týdne. Nebo chcete seskupit data o populaci podle intervalů věku. Syntaxe tohoto operátoru je:

bin(hodnota,roundTo)

Hodnota přihrádky může být číslo, datum nebo časový rozsah. Pomocí funkce agregujete počet bin() událostí za týden. Hodnota, kterou chcete seskupit, je StartTime události storm s velikostí intervalu roundTo 7days nebo 7d na krátkou dobu. Nakonec vykreslujte data jako sloupcový graf a vytvořte histogram.

1. Spusťte tento dotaz:

   Spuštění dotazu

   StormEvents
   | summarize count() by bin(StartTime, 7d)
   | render columnchart
   

   Měli byste získat výsledky, které vypadají jako na následujícím obrázku:

   

2. Podívejte se na výsledný histogram. Když najedete myší na jeden z pruhů, zobrazí se počáteční čas intervalu (hodnota x) a počet událostí (hodnota y).

Použití operátoru sum

V předchozím dotazu jste se podívali na počet událostí storm v průběhu času. Teď se podíváme na škody způsobené těmito bouřemi. K tomu použijete sum agregační funkci, protože chcete zobrazit celkovou částku poškození způsobenou v každém časovém intervalu. Datová sada, se kterou pracujete, má dva sloupce související s poškozením: DamageProperty a DamageCrops.

V následujícím dotazu nejprve vytvoříte počítaný sloupec, který tyto dva zdroje poškození sečte dohromady. Pak vytvoříte agregaci celkového poškození rozloženou po týdnu. Nakonec vykreslíte sloupcový graf představující týdenní poškození způsobené všemi bouřemi.

1. Spusťte tento dotaz:

   Spuštění dotazu

   StormEvents
   | extend damage = DamageProperty + DamageCrops
   | summarize sum(damage) by bin(StartTime, 7d)
   | render columnchart
   

   Měli byste získat výsledky, které vypadají jako na následujícím obrázku:

   

2. Předchozí dotaz ukazuje poškození jako funkci času. Dalším způsobem, jak porovnat poškození, je podle typu události. Spuštěním následujícího dotazu použijte výsečový graf k porovnání škod způsobených různými typy událostí.

   Spuštění dotazu

   StormEvents
   | extend damage = DamageProperty + DamageCrops
   | summarize sum(damage) by EventType
   | render piechart
   

   Měli byste získat výsledky, které vypadají jako na následujícím obrázku:

   

3. Najeďte myší na jeden z výsečů výsečového grafu. Měli byste vidět absolutní hodnotu (celkové poškození způsobené tímto typem události) a odpovídající procento celkové škody.