Odpojení a odstranění prostředků ze zásobníku nasazení

• 7 min

Změny budou pokračovat v aplikaci pro vklady. Tým se rozhodl odebrat prostředky z aplikace. Některé prostředky musí v Azure nadále existovat, zatímco jiné jsou bezpečné odstranit. Potřebujete se dozvědět více o tom, jak Azure zpracovává prostředky, které už zásobník nasazení nespravuje.

V této lekci se naučíte používat řízení, jak Azure zpracovává prostředky odpojené od zásobníku nasazení pomocí akce u nespravovaného parametru.

Akce s nespravovanými revisitami

Při použití zásobníků nasazení se akce na nespravovaný parametr používá k řízení způsobu, jakým Azure zpracovává odpojené prostředky, skupiny prostředků a skupiny pro správu. Akci u nespravujícího parametru můžete nastavit při vytváření, úpravách nebo odstraňování zásobníku nasazení. Všechny tři operace mají možnost nastavit chování akce u nespravovaných parametrů. Mějte na paměti, že poslední sada hodnot má přednost.

Odpojení spravovaného prostředku

Odpojený prostředek, označovaný také jako nespravovaný prostředek, je prostředek, který už není sledován nebo spravován zásobníkem nasazení, ale prostředek stále existuje v Azure. Výchozím chováním zásobníků nasazení je odpojit prostředky místo odstranění. Můžete například potřebovat zachovat prostředek, abyste ho mohli použít v jiném zásobníku nasazení v budoucnu, nebo budete muset ručně ověřit, jestli jsou jejich data bezpečná k odstranění.

Existují dvě hodnoty akce u nespravovaných parametrů, které nastavují prostředky, skupiny prostředků a skupiny pro správu, aby se odpojily, když je už zásobník nasazení nespravuje.

Podívejme se na náš soubor Bicep z poslední lekce. Soubor šablony definuje plán služby App Service, webovou aplikaci, server Azure SQL a databázi, pracovní prostor služby Log Analytics a instanci Application Insights. Řekněme, že potřebujeme odebrat pracovní prostor služby Log Analytics a instanci Application Insights, kterou jsme vytvořili v poslední lekci. Upravíme soubor Bicep a odebereme zvýrazněný kód, který odkazuje na naši webovou aplikaci.

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the SQL database.')
param sqlDatabaseName string = 'sqldb-${uniqueString(resourceGroup().id)}'

@description('The password of the admin user.')
param sqlServerAdminUserName string

@description('The name of the admin user.')
@secure()
param sqlServerAdminPassword string

@description('The name of the SQL server.')
param sqlServerName string = 'sql-${uniqueString(resourceGroup().id)}'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the Application Insights instance.')
var applicationInsightsName = 'appinsights-deposits'

@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

@description('The name of the Log Analytics Workspace.')
var logAnalyticsWorkspaceName = 'log-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'S1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    siteConfig: {
      appSettings: [
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }     
      ]
    }    
  }
}

// Resource - SQL Server
resource sqlServer 'Microsoft.Sql/servers@2021-11-01' ={
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlServerAdminUserName
    administratorLoginPassword: sqlServerAdminPassword
  }
}

// Resource - SQL Database
resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2021-11-01' = {
  parent: sqlServer
  name: sqlDatabaseName
  location: location
  sku: {
    name: 'Standard'
    tier: 'Standard'
  }
}

// Resource - Log Analytics Workspace
resource logAnalyticsWorkspace 'Microsoft.OperationalInsights/workspaces@2023-09-01' = {
  name: logAnalyticsWorkspaceName
  location: location
  properties: {
    retentionInDays: 30
    sku: {
      name: 'PerGB2018'
    }
  }
}

// Resource - Application Insights
resource applicationInsights 'Microsoft.Insights/components@2020-02-02' = {
  name: applicationInsightsName
  location: location
  kind: 'web'
  properties: {
    Application_Type: 'web'
    WorkspaceResourceId: logAnalyticsWorkspace.id
  }
}

az stack group create \
    --name stack-deposits \
    --resource-group rg-depositsApplication \
    --template-file ./main.bicep \
    --action-on-unmanage detachAll \
    --deny-settings-mode none

Set-AzResourceGroupDeploymentStack `
    -Name stack-deposits `
    -ResourceGroupName rg-depositsApplication `
    -TemplateFile ./main.bicep `
    -ActionOnUnmanage DetachAll `
    -DenySettingsMode None

Odstranění spravovaného prostředku

Zásobníky nasazení poskytují spolehlivé vyčištění prostředků. Při aktualizaci nebo odstranění zásobníku nasazení můžete také odstranit spravované prostředky, skupiny prostředků a skupiny pro správu. Existují dvě hodnoty akce u nespravovaných parametrů, které nastaví prostředky, skupiny prostředků a skupiny pro správu, které se mají odstranit, když je už zásobník nasazení nespravuje.

Pojďme se podívat na náš soubor Bicep z předchozí části. Soubor šablony definuje plán služby App Service, webovou aplikaci a server a databázi Azure SQL. Řekněme, že potřebujeme odebrat server a databázi Azure SQL. Upravíme soubor Bicep a odebereme zvýrazněný kód, který odkazuje na naši webovou aplikaci.

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the SQL database.')
param sqlDatabaseName string = 'sqldb-${uniqueString(resourceGroup().id)}'

@description('The password of the admin user.')
param sqlServerAdminUserName string

@description('The name of the admin user.')
@secure()
param sqlServerAdminPassword string

@description('The name of the SQL server.')
param sqlServerName string = 'sql-${uniqueString(resourceGroup().id)}'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'F1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id  
  }
}

// Resource - SQL Server
resource sqlServer 'Microsoft.Sql/servers@2021-11-01' ={
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlServerAdminUserName
    administratorLoginPassword: sqlServerAdminPassword
  }
}

// Resource - SQL Database
resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2021-11-01' = {
  parent: sqlServer
  name: sqlDatabaseName
  location: location
  sku: {
    name: 'Standard'
    tier: 'Standard'
  }
}

V našem souboru zůstaneme s následujícím kódem:

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'F1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id  
  }
}

az stack group create \
    --name stack-deposits \
    --resource-group rg-depositsApplication \
    --template-file ./main.bicep \
    --action-on-unmanage deleteAll \
    --deny-settings-mode none

Set-AzResourceGroupDeploymentStack `
    -Name stack-deposits `
    -ResourceGroupName rg-depositsApplication `
    -TemplateFile ./main.bicep `
    -ActionOnUnmanage DeleteAll `
    -DenySettingsMode None