Abrufen von Analysen zu Ihrer Wissensdatenbank

QnA Maker speichert alle Chatprotokolle und anderen Telemetriedaten, wenn Sie Application Insights bei der Erstellung Ihres QnA Maker-Diensts aktiviert haben. Führen Sie die Beispielabfragen aus, um Ihre Chatprotokolle aus Application Insights abzurufen.

1. Wechseln Sie zu Ihrer Application Insights-Ressource.

   

2. Wählen Sie Protokoll (Analytics) aus. Daraufhin wird ein neues Fenster geöffnet, in dem Sie QnA Maker-Telemetriedaten abfragen können.

3. Fügen Sie die folgende Abfrage ein, und führen Sie sie aus.

   requests
   | where url endswith "generateAnswer"
   | project timestamp, id, url, resultCode, duration, performanceBucket
   | parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
   | join kind= inner (
   traces | extend id = operation_ParentId
   ) on id
   | where message == "QnAMaker GenerateAnswer"
   | extend question = tostring(customDimensions['Question'])
   | extend answer = tostring(customDimensions['Answer'])
   | extend score = tostring(customDimensions['Score'])
   | project timestamp, resultCode, duration, id, question, answer, score, performanceBucket,KbId
   

   Klicken Sie auf Ausführen, um die Abfrage auszuführen.

   

Ausführen von Abfragen für andere Analysen zu Ihrer QnA Maker-Wissensdatenbank

Gesamter Datenverkehr von 90 Tagen

//Total Traffic
requests
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| summarize ChatCount=count() by bin(timestamp, 1d), KbId

Gesamter Fragendatenverkehr in einem bestimmten Zeitraum

//Total Question Traffic in a given time period
let startDate = todatetime('2019-01-01');
let endDate = todatetime('2020-12-31');
requests
| where timestamp <= endDate and timestamp >=startDate
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| summarize ChatCount=count() by KbId

Benutzerdatenverkehr

//User Traffic
requests
| where url endswith "generateAnswer"
| project timestamp, id, url, resultCode, duration
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| join kind= inner (
traces | extend id = operation_ParentId
) on id
| extend UserId = tostring(customDimensions['UserId'])
| summarize ChatCount=count() by bin(timestamp, 1d), UserId, KbId

Latenzverteilung von Fragen

//Latency distribution of questions
requests
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| project timestamp, id, name, resultCode, performanceBucket, KbId
| summarize count() by performanceBucket, KbId

Unbeantwortete Fragen

// Unanswered questions
requests
| where url endswith "generateAnswer"
| project timestamp, id, url
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| join kind= inner (
traces | extend id = operation_ParentId
) on id
| extend question = tostring(customDimensions['Question'])
| extend answer = tostring(customDimensions['Answer'])
| extend score = tostring(customDimensions['Score'])
| where  score  == "0" and message == "QnAMaker GenerateAnswer"
| project timestamp, KbId, question, answer, score
| order  by timestamp  desc

HINWEIS
Wenn Sie das Protokoll mithilfe von Application Insights nicht ordnungsgemäß erhalten können, bestätigen Sie die Application Insights-Einstellungen auf der App Service-Ressource. Öffnen Sie die App Service-Ressource, und wechseln Sie zu Application Insights. Überprüfen Sie dann, ob Application Insights aktiviert oder deaktiviert ist. Wenn das Feature deaktiviert ist, aktivieren Sie es, und wenden Sie es dann dort an.

Nächste Schritte