Abfragen für die Tabelle ACSCallAutomationIncomingOperations

  • Artikel

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Anrufautomatisierungs-Vorgänge

Gibt alle unterschiedlichen Kombinationen von Anrufautomatisierungs-Vorgängen und Versionspaaren zurück.

ACSCallAutomationIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Berechnen von Quantilen des Anrufautomatisierungs-Vorgangs

Berechnet die 90., 95. und 99. Quantile der Laufzeit in Millisekunden für jeden Anrufautomatisierungs-Vorgang. Sie kann für einen einzelnen Vorgang oder für andere Quantile angepasst werden.

ACSCallAutomationIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

Top 5 IP-Adressen pro Anrufautomatisierungs-Vorgang

Rufen Sie für jeden Anrufautomatisierungs-Vorgang die fünf IP-Adressen ab, die diesen Vorgang am häufigsten aufgerufen haben.

ACSCallAutomationIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Betriebsfehler bei der Anrufautomatisierung

Listet jeden Anrufautomatisierungsfehler auf, der nach Reency sortiert ist.

ACSCallAutomationIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

Ergebnisanzahl des Anrufautomatisierungs-Vorgangs

Zählen Sie für jeden Anrufautomatisierungs-Vorgang die Typen der zurückgegebenen Ergebnisse.

ACSCallAutomationIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Anrufautomatisierungsprotokolle für Anrufverbindungs-ID

Abfragen der Anrufautomatisierungsprotokolle für eine bestimmte Anrufverbindungs-ID.

ACSCallAutomationIncomingOperations
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| limit 100

Aufrufen von API-Vorgängen für einen Aufruf

Gibt alle Aufrufautomatisierungs-API-Vorgänge und Versionspaare für einen bestimmten Aufruf (Korrelations-ID) zurück.

ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| project CorrelationId, OperationName, OperationVersion
| limit 100

CallDiagnostics-Protokoll für CallAutomation-API-Aufruf

Fragt das Diagnoseprotokoll für einen Aufruf ab, mit dem die Anrufautomatisierungs-API mithilfe der Korrelations-ID interagiert wurde.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallDiagnostics)
    on CorrelationId
| limit 100

CallSummary-Protokoll für CallAutomation-API-Aufruf

Fragt das Zusammenfassungsprotokoll für einen Aufruf ab, mit dem die Anrufautomatisierungs-API mithilfe der Korrelations-ID interagiert wurde.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallSummary)
    on CorrelationId
| limit 100