Abfragen für die FunctionAppLogs-Tabelle

  • Artikel

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Show application logs from Function Apps

Eine Liste der Anwendungsprotokolle, sortiert nach Uhrzeit (die neuesten Protokolle werden zuerst angezeigt).

FunctionAppLogs 
| project TimeGenerated, HostInstanceId, Message, _ResourceId
| sort by TimeGenerated desc

Show logs with warnings or exceptions

Eine Liste der Protokolle, die Warnungen oder Ausnahmen enthalten (neueste Protokolle werden zuerst angezeigt).

FunctionAppLogs
| where Level == "Warning" or Level == "Error"
| project TimeGenerated, HostInstanceId, Level, Message, _ResourceId
| sort by TimeGenerated desc

Error and exception count

Zeigt ein Säulendiagramm der Anzahl der Protokolle an, die Warnungen oder Fehler in der letzten Stunde pro Anwendung enthalten.

FunctionAppLogs 
| where TimeGenerated > ago(1h)
| where Level == "Warning" or Level == "Error"
| summarize count_per_app = count() by _ResourceId
| sort by count_per_app desc 
| render columnchart

Function activity over time

Liniendiagramm, das den Trend des Volumens von Funktionsanforderungen pro Funktion im Laufe der Zeit zeigt.

FunctionAppLogs
//| where _ResourceId == "MyResourceId" // Uncomment and enter a resource ID to get results for a specific resource
| where Category startswith "Function." and Message startswith "Executed "
| summarize count() by bin(TimeGenerated, 1h), FunctionName // Aggregate by hour
| render timechart

Function results

Der Aufruf einzelner Funktionen führt zu der letzten Stunde (die neuesten Protokolle werden zuerst angezeigt).

FunctionAppLogs
| where TimeGenerated > ago(1h)
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
| project TimeGenerated, FunctionName, Result, FunctionInvocationId, Duration, _ResourceId
| sort by TimeGenerated desc

Function Error rate

Zusammenfassung von Funktionen Erfolg und Fehler pro Stunde.

FunctionAppLogs
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
// | where Name == "MyFunction" // Use this to restrict to a specific function
| summarize count() by bin(TimeGenerated, 1h), Name, Result, _ResourceId
| order by TimeGenerated desc