Abfragen für die WVDConnectionNetworkData-Tabelle

Artikel
11/05/2024

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Durchschnittliche Roundtripzeit im Laufe der Zeit

Zeigt ein Diagramm der Roundtripzeit (in Millisekunden) über alle Verbindungen in 10 Min. Intervallen am 10., 50. und 90. Quantil an.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Durchschnittliche BW über alle Verbindungen

Zeigt ein Diagramm der Bandbreite (in Kilobyte pro Sekunde) über alle Verbindungen über 10 Min. Intervalle am 10., 50. und 90. Quantil an.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Top 10 Benutzer mit der höchsten Roundtripzeit

Gibt eine Liste der top 10 Benutzer mit der höchsten durchschnittliche Roundtripzeit (in Millisekunden) zurück.

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

Top 10 Benutzer mit niedrigster Bandbreite

Gibt eine Liste der top 10 Benutzer mit der niedrigsten durchschnittliche Bandbreite (in Kilobyte pro Sekunde) zurück.

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Zusammenfassung der Roundtripzeit und Bandbreite

Gibt die 90. Quantile für Roundtripzeit (in Millisekunden) und Bandbreite (in Kilobyte) für jede Verbindung zusammen mit zusätzlichen Verbindungsdetails zurück.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Freigeben über