Erfassen aus Abfrage (.set, .append, .set-or-append, .set-or-replace)

Gilt für: ✅Microsoft Fabric✅Azure Data Explorer

Diese Befehle führen eine Abfrage oder einen Verwaltungsbefehl aus und nehmen die Ergebnisse der Abfrage in eine Tabelle ein. Der Unterschied zwischen diesen Befehlen besteht darin, wie vorhandene oder nicht vorhandene Tabellen und Daten behandelt werden.

Informationen zum Abbrechen eines Abrufs aus dem Abfragebefehl finden Sie unter cancel operation.

Berechtigungen

Um unterschiedliche Aktionen für eine Tabelle auszuführen, sind bestimmte Berechtigungen erforderlich:

• Zum Hinzufügen von Zeilen zu einer vorhandenen Tabelle mit dem .append Befehl benötigen Sie mindestens die Berechtigungen "Table Ingestor".
• Um eine neue Tabelle mit den verschiedenen .set Befehlen zu erstellen, benötigen Sie mindestens berechtigungen für Datenbankbenutzer.
• Um Zeilen in einer vorhandenen Tabelle mithilfe des .set-or-replace Befehls zu ersetzen, benötigen Sie mindestens die Berechtigungen des Tabellenadministrators.

Weitere Informationen zu Berechtigungen finden Sie unter Kusto rollenbasierte Zugriffssteuerung.

Syntax

(.set.append.set-or-replace | | .set-or-append | ) [async] tableName [with( propertyName = propertyValue [, ...]] <| )queryOrCommand

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Leistungstipps

• Legen Sie die distributed Eigenschaft auf true fest, wenn die menge der von der Abfrage erzeugten Daten groß ist, 1 GB überschreitet und keine Serialisierung erfordert. Anschließend können mehrere Knoten die Ausgabe parallel erzeugen. Verwenden Sie dieses Flag nicht, wenn Abfrageergebnisse klein sind, da es möglicherweise viele kleine Datenshards ohne Weiteres generiert.
• Die Datenaufnahme ist ein ressourcenintensiver Vorgang, der sich auf gleichzeitige Aktivitäten in der Datenbank auswirken kann, einschließlich der Ausführung von Abfragen. Vermeiden Sie die gleichzeitige Ausführung zu vieler Aufnahmebefehle.
• Beschränken Sie die Daten für die Aufnahme auf weniger als 1 GB pro Aufnahmevorgang. Verwenden Sie bei Bedarf mehrere Aufnahmebefehle.

Unterstützte Erfassungseigenschaften

Schemaüberlegungen

• .set-or-replace behält das Schema bei, es sei denn, eine der extend_schema Eigenschaften für recreate_schema die Aufnahme ist auf true.
• .set-or-append und .append Befehle behalten das Schema bei, es sei denn, die extend_schema Aufnahmeeigenschaft ist auf true.
• Der Abgleich mit dem Resultsetschema der Zieltabelle basiert auf den Spaltentypen. Es erfolgt kein Abgleichen der Spaltennamen. Stellen Sie sicher, dass sich die Spalten des Abfrageergebnisschemas in der gleichen Reihenfolge wie die Tabelle befinden, andernfalls werden die Daten in die falschen Spalten aufgenommen.

Zeichenbeschränkung

Der Befehl schlägt fehl, wenn die Abfrage einen Entitätsnamen mit dem $ Zeichen generiert. Die Entitätsnamen müssen den Benennungsregeln entsprechen, sodass das $ Zeichen entfernt werden muss, damit der Aufnahmebefehl erfolgreich ausgeführt werden kann.

In der folgenden Abfrage generiert der search Operator beispielsweise eine Spalte $table. Zum Speichern der Abfrageergebnisse verwenden Sie die Projektumbenennung , um die Spalte umzubenennen.

.set Texas <| search State has 'Texas' | project-rename tableName=$table

Beispiele

Erstellen Sie eine neue Tabelle namens RecentErrors in der Datenbank, die dasselbe Schema wie LogsTable hat und alle Fehlerdatensätze der letzten Stunde enthält.

.set RecentErrors <|
   LogsTable
   | where Level == "Error" and Timestamp > now() - time(1h)

Erstellen Sie eine neue Tabelle mit dem Namen "OldExtents" in der Datenbank mit einer einzelnen Spalte, "ExtentId", und enthält die Umfangs-IDs aller Ausdehnungen in der Datenbank, die vor mehr als 30 Tagen erstellt wurden. Die Datenbank enthält eine Tabelle namens „MyExtents“. Da das Dataset voraussichtlich größer als 1 GB (mehr als ~1 Millionen Zeilen) sein soll, verwenden Sie das verteilte Flag.

.set async OldExtents with(distributed=true) <|
   MyExtents 
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Fügen Sie Daten an die vorhandene Tabelle „OldExtents“ in der aktuellen Datenbank an, die eine einzige Spalte namens „ExtentId“ hat und die Block-IDs aller Blöcke in der Datenbank enthält, die vor mehr als 30 Tagen erstellt wurden. Markieren Sie den neue Block mit den Tags tagA und tagB, basierend auf der vorhandenen Tabelle „MyExtents“.

.append OldExtents with(tags='["TagA","TagB"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Fügen Sie Daten an die Tabelle „OldExtents“ in der aktuellen Datenbank an, oder erstellen Sie die Tabelle, wenn sie noch nicht vorhanden ist. Kennzeichnen Sie den neuen Block mit ingest-by:myTag. Führen Sie diesen Schritt nur aus, wenn die Tabelle noch keinen mit ingest-by:myTag gekennzeichneten Block enthält, basierend auf der vorhandenen Tabelle „MyExtents“.

.set-or-append async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <|
   MyExtents
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Ersetzen Sie die Daten in der Tabelle „OldExtents“ in der aktuellen Datenbank an, oder erstellen Sie die Tabelle, wenn sie noch nicht vorhanden ist. Kennzeichnen Sie den neuen Block mit ingest-by:myTag.

.set-or-replace async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Fügen Sie Daten an die Tabelle "OldExtents" in der aktuellen Datenbank an, und legen Sie dabei die Erstellungszeit auf ein bestimmtes Datum in der Vergangenheit fest.

.append async OldExtents with(creationTime='2017-02-13T11:09:36.7992775Z') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId     

Zurückgegebene Ausgabe

Gibt Informationen zu den Erweiterungen zurück, die aufgrund des .set- oder .append-Befehls erstellt wurden.

Beispielausgabe