Hinzufügen eines Time-in-State-Measures zu Ihrem Power BI-Bericht

Azure DevOps Services | Azure DevOps Server 2022 | Azure DevOps Server 2019

Die Zeit, die ein Arbeitselement in einem bestimmten Workflowzustand oder einer Reihe von Zuständen verbringt, ist ein wichtiger Aspekt für das Verständnis der Effizienz. Die Widgets "Zykluszeit" und "Vorlaufzeitanalyse " stellen einige Measures für die Zustandszeit bereit. Diese Widgets verfügen jedoch möglicherweise nicht über die gewünschte Detailebene.

Dieser Artikel enthält Rezepte mithilfe von DAX (Data Analysis Expressions), um die von Arbeitsaufgaben in einer Kombination von Zuständen aufgewendete Zeit auszuwerten. Insbesondere erfahren Sie, wie Sie Die folgenden Measure- und berechneten Spalten zu Ihren Power BI-Berichten hinzufügen und zum Generieren verschiedener Trenddiagramme verwenden. Alle Felder sind berechnete Spalten mit Ausnahme der ersten aufgeführten.

Voraussetzungen

• Access: Mitglied eines Projekts mit mindestens standardem Zugriff sein.
• Berechtigungen: Standardmäßig verfügen Projektmitglieder über die Berechtigung zum Abfragen von Analysen und Erstellen von Ansichten.
• Weitere Informationen zu anderen Voraussetzungen für die Dienst- und Featureaktivierung sowie allgemeine Datenverfolgungsaktivitäten finden Sie unter Berechtigungen und Voraussetzungen für den Zugriff auf Analytics.

Hinzufügen eines Measures für die Anzahl von Arbeitselementen

Um die schnelle Generierung von Berichten zu vereinfachen, haben wir Analyseansichten so konzipiert, dass sie mit Standardaggregationen in Power BI funktionieren. Um den Unterschied zwischen einer Standardaggregation und einem Measure zu veranschaulichen, beginnen wir mit einem einfachen Measure für die Anzahl von Arbeitselementen.

1. Laden Sie Ihre Analyseansicht in Power BI Desktop. Weitere Informationen finden Sie unter Verbinden mit Power BI-Datenconnector, Herstellen einer Verbindung mit einer Analyseansicht.

2. Wählen Sie die Datentabelle aus, und wählen Sie dann im Menüband auf der Registerkarte Tabellentools im Abschnitt Berechnungen die Option Neues Measure aus.

   

3. Ersetzen Sie den Standardtext durch den folgenden Code, und aktivieren Sie dann das Häkchen.

   Work Items Count=CALCULATE(COUNTROWS ('View Name'),LASTDATE ('View Name'[Date]))
   

   Das Measure Anzahl der Arbeitselemente verwendet die CALCULATEDAX-Funktionen , COUNTROWSund LASTDATE die weiter unten in diesem Artikel ausführlicher beschrieben werden.

   Hinweis

   Denken Sie daran, Ansichtsname durch den Tabellennamen für die Analyseansicht zu ersetzen. Hier ersetzen wir beispielsweise Ansichtsname durch Aktive Fehler.

   

Wie unterscheidet sich ein Measure von einer berechneten Spalte?

Ein Measure wertet immer die gesamte Tabelle aus, wobei eine berechnete Spalte spezifisch für eine einzelne Zeile ist. Weitere Informationen finden Sie unter Berechnete Spalten und Measures in DAX.

Vergleichen Sie das Measure Anzahl der Arbeitselemente mit der Standardanzahlaggregation basierend auf der Arbeitselement-ID. Die folgende Abbildung wird erstellt, indem der ersten Karte das Visual Card und das Measure Für die Anzahl der Arbeitselemente und die Eigenschaft Arbeitselement-ID zur zweiten Karte hinzugefügt werden.

Um die richtige Anzahl mithilfe einer Standardaggregation zu erhalten, wenden Sie den Filter "Ist Aktuell " gleich "True" an. Dieses Muster zum Anwenden von Filtern auf eine Standardaggregation ist die Grundlage für viele der in diesem Artikel bereitgestellten Beispiele.

Statussortierreihenfolge hinzufügen

Standardmäßig zeigt Power BI in einer Visualisierung alphabetisch sortierte Zustände an. Es kann irreführend sein, wenn Sie die Zeit im Zustand visualisieren möchten und Der Vorschlag nach In Bearbeitung angezeigt wird. Die folgenden Schritte helfen, dieses Problem zu beheben.

1. Überprüfen Sie, ob das Feld Statuskategorie in der Analyseansicht enthalten ist. Dieses Feld ist in allen freigegebenen Standardansichten enthalten.

2. Wählen Sie die Datentabelle aus, und wählen Sie dann im Menüband auf der Registerkarte Tabellentools im Abschnitt Berechnungen die Option Neue Spalte aus.

   

3. Ersetzen Sie den Standardtext durch den folgenden Code, und aktivieren Sie dann das Häkchen.

   State Sort Order =  
   SWITCH (  
       'View Name'[State Category],  
       "Proposed", 1,  
       "InProgress", 2,  
       "Resolved", 3,  
       4  
   )  
   

   Sehen Sie sich folgendes Beispiel an:

   

   Hinweis

   Möglicherweise müssen Sie die Definition überarbeiten, wenn Sie mehr Granularität benötigen, als Die Statuskategorie bietet. Zustandskategorie ermöglicht die korrekte Sortierung aller Arbeitselementtypen, unabhängig von Statusanpassungen .

4. Öffnen Sie die Datenansicht, und wählen Sie die Spalte Status aus.

5. Wählen Sie auf der Registerkarte Spaltentoolsdie Option Nach Spalte sortieren aus, und wählen Sie dann das Feld Zustandssortierreihenfolge aus.

   

Datum "Vorheriges Hinzufügen"

Der nächste Schritt zum Berechnen der Zustandszeit erfordert die Zuordnung des vorherigen Intervalls (Tag, Woche, Monat) für jede Datenzeile im Dataset. Dies ist eine einfache Berechnung mit einer berechneten Spalte. In der Regel würden Sie diese Spalte wie gezeigt definieren.

Date Previous  = 
PREVIOUSDAY ( 'View Name'[Date] )

Dieser Ansatz hat jedoch zwei Hauptprobleme:

• Es funktioniert nur für tägliche Zeiträume.
• Es behandelt keine Lücken in den Daten. Beispielsweise, wenn ein Arbeitselement zwischen Projekten verschoben wird.

Um diese Probleme zu beheben, sollte die berechnete Spalte den vorherigen Tag finden, indem das Feld Datum gescannt wird.

Um die berechnete Spalte Datum Vorheriger hinzuzufügen, wählen Sie auf der Registerkarte Tabellentoolsdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

Date Previous =
CALCULATE (
    MAX ( 'View Name'[Date] ),
        ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
        'View Name'[Date] < EARLIER ( 'View Name'[Date] )
)

Die berechnete Spalte Date Previous verwendet die drei DAX-Funktionen MAX, ALLEXCEPTund EARLIER, die weiter unten in diesem Artikel ausführlicher beschrieben werden. Da die Spalte berechnet wird, wird sie für jede Zeile in der Tabelle ausgeführt, und jedes Mal, wenn sie ausgeführt wird, weist sie den Kontext dieser bestimmten Zeile auf.

Hinzufügen von Datumsunterschieden in Tagen

Date Previous berechnet die Differenz zwischen dem vorherigen und dem aktuellen Datum für jede Zeile. Bei Datumsunterschieden in Tagen berechnen wir eine Anzahl von Tagen zwischen jedem dieser Zeiträume. Für die meisten Zeilen in einer täglichen Momentaufnahme entspricht der Wert 1. Für viele Arbeitselemente, die Lücken im Dataset aufweisen, ist der Wert jedoch größer als 1.

Es ist wichtig, den ersten Tag des Datasets zu berücksichtigen, an dem Datum vorheriger Wert leer ist. In diesem Beispiel geben wir dieser Zeile den Standardwert 1, um die Berechnung konsistent zu halten.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

Date Diff in Days =
IF (
    ISBLANK ( 'View Name'[Date Previous] ),
    1,
    DATEDIFF (
        'View Name'[Date Previous],
        'View Name'[Date],
        DAY
    )
)

Für diese berechnete Spalte werden die DAX-Funktionen und DATEDIFF verwendet, die ISBLANKweiter unten in diesem Artikel beschrieben werden.

Add Is Last Day in State

In diesem nächsten Schritt wird berechnet, ob eine angegebene Zeile den letzten Tag darstellt, an dem sich ein bestimmtes Arbeitselement in einem Zustand befand. Es unterstützt Standardaggregationen in Power BI, die wir im nächsten Abschnitt hinzufügen, in dem wir die Spalte Zustandszeit in Tagen hinzufügen.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

Is Last Day in State = 
ISBLANK (CALCULATE (
    COUNTROWS ( 'View Name' ),
        ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
        'View Name'[Date] > EARLIER ( 'View Name'[Date] ),
        'View Name'[State] = EARLIER ( 'View Name'[State] )
))

Hinzufügen der Zustandszeit in Tagen

Die Zeit, die ein Arbeitselement in einem bestimmten Zustand verbracht hat, kann jetzt berechnet werden, indem der Datumsunterschied in Tagen für jedes Arbeitselement summiert wird. Diese Berechnung umfasst alle in einem bestimmten Zustand aufgewendeten Zeit, auch wenn sie mehrmals zwischen Zuständen gewechselt wurde. Es ist möglich, jede Zeile mit Datum oder den neuesten Informationen als Trend zu bewerten, indem Sie Den letzten Tag im Zustand verwenden.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Time in Days = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State] = EARLIER ( 'View Name'[State] )
) + 0

Erstellen von Trenddiagrammen für gestapelte Spalten basierend auf der Zustandszeit in Tagen

Um die Spalte Zustandszeit in Tagen zu veranschaulichen, werden die folgenden gestapelten Säulendiagramme erstellt. Das erste Diagramm zeigt die Anzahl der Arbeitselemente in jedem Zustand im Zeitverlauf an.

Das zweite Diagramm veranschaulicht den Trend der durchschnittlichen Tage, an denen sich die aktiven Arbeitselemente in einem bestimmten Zustand befinden.

Hinzufügen der Zustandszeit in Tagen – Latest (Ist letzter Tag im Zustand)

Verwenden Sie beim Auswerten des Zustands für jedes Arbeitselement in einer Tabelle oder beim Filtern nach einem Feld wie Bereichspfad nicht die Spalte Zustandszeit in Tagen in einer Aggregation. Die Aggregation verwendet den Wert für jeden Tag, an dem sich das Arbeitselement im Zustand befand. Wenn z. B. eine Arbeitsaufgabe am Montag in Bearbeitung war und am Donnerstag in "Abgeschlossen" verschoben wurde, beträgt der Zeit-in-Zustand drei Tage, die Summe der Spalte "State Time in Days" ist jedoch sechs Tage, 1+2+3was falsch ist.

Um dieses Problem zu beheben, verwenden Sie "State Time in Days ", und wenden Sie den Filter "Letzter Tag im Zustand " auf "True" an. Es eliminiert alle verlaufsbezogenen Daten, die für einen Trend erforderlich sind, und konzentriert sich stattdessen nur auf den neuesten Wert für jeden Zustand.

Hinzufügen der Zustandszeit in Tagen – In Bearbeitung

In den vorherigen Beispielen wird die Statuszeit in Tagen für eine bestimmte Arbeitsaufgabe nur gezählt, wenn sich die Arbeitsaufgabe in diesem bestimmten Zustand befand. Wenn Ihr Ziel darin besteht, die Anzahl der Zeit im Zustand eines bestimmten Arbeitselements kontinuierlich in Richtung eines Durchschnitts zu erreichen, müssen Sie die Berechnung ändern. Wenn wir beispielsweise den Status "In Bearbeitung" nachverfolgen möchten, fügen wir die berechnete Spalte State Time in Days - In Progress hinzu.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Time in Days - In Progress = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
   'View Name'[Date] <= EARLIER('View Name'[Date]),
   'View Name'[State] = "In Progress"
) + 0

Die folgende Abbildung zeigt den Effekt der Berücksichtigung aller Zeit im Zustand für jedes vorhandene Arbeitselement (links dargestellt) im Vergleich zu den Arbeitselementen in einem bestimmten Zustand an einem bestimmten Tag (rechts dargestellt).

Zustandszeit in Tagen Trend mehrerer Zustände

Die Analyse der Leistung über mehrere Zustände hinweg ist auch mithilfe des Musters "Fortlaufend" möglich. Dieser Ansatz funktioniert jedoch nur mit einem Trenddiagramm.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Time in Days - Working States = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
   'View Name'[Date] <= EARLIER('View Name'[Date]),
   'View Name'[State] IN { "Committed", "In Progress" }
) + 0

Das Diagramm auf der linken Seite zeigt den kombinierten Durchschnitt, während auf der rechten Seite jeder einzelne Zustand angezeigt wird.

Abrufen der Zustandszeit in Tagen – Neueste für mehrere Zustände

Beim Erstellen eines Trends verwenden Sie die berechnete Spalte State Time in Days – Latest . Mit einem Filter nach den Zuständen bietet die Spalte "State Time in Days " und "Is Last Day in State " eine einfache Möglichkeit zum Abrufen der Gesamtzeit aller Arbeitsaufgaben, die in einer Reihe von Zuständen verbracht wurden.

Hinzufügen des Zustands "Zurück"

Die berechnete Spalte Date Previous kann auch verwendet werden, um vergangene Werte wie den vorherigen Zustand für jedes Arbeitselement nachzuschlagen.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Previous =
LOOKUPVALUE (
    'View Name'[State],
    'View Name'[Work Item Id], 'View Name'[Work Item Id],
    'View Name'[Date], 'View Name'[Date Previous]
)

Diese berechnete Spalte verwendet die , die LOOKUPVALUEweiter unten in diesem Artikel beschrieben wird.

Der erste LOOKUPVALUE Parameter , gibt an, 'View Name'[State]um den Wert von [State] zurückzugeben.

Der nächste Parameter gibt an, 'View Name'[Work Item Id], 'View Name'[Work Item Id]dass nur Zeilen mit einer übereinstimmenden Arbeitselement-ID als aktuelle Zeile berücksichtigt werden sollen.

Der letzte Parameter gibt an, 'View Name'[Date], 'View Name'[Date Previous]dass das Datum der zurückgegebenen Zeile ein [Datum] aufweisen muss, das dem [Vorherigen Datum] der aktuellen Zeile entspricht. In einer Momentaufnahme kann nur eine Zeile dieses Kriterium erfüllen.

Status geändert hinzufügen

Mithilfe der Spalte State Previous (Zustand zurück) können wir die Zeilen für jedes Arbeitselement kennzeichnen, in dem ein Zustandsübergang stattgefunden hat. Die berechnete Spalte Stage Changed weist zwei besondere Aspekte auf:

• Leere Werte von *State Previous, die wir auf das Erstellungsdatum der Arbeitsaufgabe festlegen
• Die Erstellung eines Arbeitselements wird als Zustandsübergang betrachtet.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Changed =
IF (
    ISBLANK ( 'View Name'[State Previous] ),
    'View Name'[Created Date].[Date] = 'View Name'[Date],
    'View Name'[State Previous] <> 'View Name'[State]
)

Die berechnete Spalte ist ein boolescher Wert, der angibt, ob die Zeile ein Zustandsübergang ist. Mithilfe des Not Equal To -Operators können Sie Zeilen ordnungsgemäß abfangen, bei denen der vorherige Zustand nicht mit dem aktuellen Zustand übereinstimmt. Das bedeutet, dass der Vergleich wie erwartet True zurückgibt.

Zustandsfluss hinzufügen

Mit den berechneten Spalten State Previous und State Changed können Sie eine Spalte erstellen, die den Zustandsfluss für ein bestimmtes Arbeitselement veranschaulicht. Das Erstellen dieser Spalte ist für die Zwecke dieses Artikels optional.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Flow = 
IF([State Changed], [State Previous], [State]) & " => " & [State]

Anzahl von Zustandsänderungen hinzufügen

Wenn wir mit den komplizierteren Measures fortfahren, benötigen wir eine Darstellung der Gesamtzahl der Zustandsänderungen, um die Zeilen einer Daten für ein bestimmtes Arbeitselement zu vergleichen. Die Darstellung wird durch Hinzufügen einer berechneten Spalte State Change Count abgerufen.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Change Count = 
CALCULATE (
    COUNTROWS ( 'View Name' ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State Changed]
) + 0

Hinzufügen der Anzahl von Zustandsänderungen – Letzte vorgeschlagene Und Zustandsneustartzeit in Tagen

Die Zustandsneustartzeit in Tagen ist eine ziemlich komplexe Berechnung. Der erste Schritt besteht darin, den zeitpunkt zu ermitteln, zu dem sich ein Arbeitselement zuletzt in einem vorgeschlagenen Zustand befunden hat. Fügen Sie die berechnete Spalte State Change Count – Last Proposed (State Change Count – Last Proposed) hinzu.

Wählen Sie auf der Registerkarte "Modellieren " die Option "Neue Spalte " aus, und ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Change Count - Last Proposed = 
CALCULATE (
    MAX ( 'View Name'[State Change Count] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State] = "Proposed"
)

Schauen Sie dann weiter zurück in die Vergangenheit und sehen Sie, ob es vor diesem vorgeschlagenen Zustand einige aktive Zustände gab. Summieren Sie schließlich alle Tage, an dem sich das Arbeitselement vor dem letzten Vorschlag im aktiven Zustand befand.

Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

State Restart Time in Days = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State Change Count] < EARLIER('View Name'[State Change Count - Last Proposed] ),
    'View Name'[State] <"Proposed"
) + 0

Da die Zustandsneustartzeit in Tagen für jede Datenzeile aktualisiert wird, können Sie entweder einen Trend erstellen, um die Nacharbeit über bestimmte Sprints hinweg auszuwerten, oder die Nacharbeit für einzelne Arbeitselemente mithilfe von Is Current untersuchen.

Hinzufügen der Zustandsreworkzeit in Tagen

Ähnlich wie die Zustandsneustartzeit in Tagen sucht die Statusumarbeitszeit in Tagen nach dem ersten Mal, wenn sich eine Arbeitsaufgabe in der Kategorie "Abgeschlossen" befand. Danach zählt jeder Tag, den ein Arbeitselement in einem anderen Zustand als Abgeschlossen verbringt, als Nacharbeit.

1. Erstellen Sie die Spalte "State Change Count - First Completed". Diese Spalte verfolgt die Anzahl der Übergänge eines Arbeitselements in den Status "Abgeschlossen" aus einem anderen Zustand.

   State Change Count - First Completed =
   VAR CompletedState = "Completed"
   RETURN
   CALCULATE(
      COUNTROWS('YourTable'),
      FILTER(
          'YourTable',
          'YourTable'[State] = CompletedState
          && 'YourTable'[State Change Date] = MIN('YourTable'[State Change Date])
      )
   )
   

2. Wählen Sie auf der Registerkarte Modellierungdie Option Neue Spalte aus, ersetzen Sie dann den Standardtext durch den folgenden Code, und aktivieren Sie das Häkchen.

   State Rework Time in Days = 
   IF (
       ISBLANK ( 'View Name'[State Change Count - First Completed] ),
       0,
       CALCULATE (
           SUM ( 'View Name'[Date Diff in Days] ),
           ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
           'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
           'View Name'[State Change Count] <= EARLIER ( 'View Name'[State Change Count - First Completed] ),
           'View Name'[State] IN {"Completed", "Closed", "Cut" } = FALSE()
       ) + 0
   )
   

   Hinweis

   Möglicherweise müssen Sie die vorherige Definition basierend auf den workflowzuständen, die von Ihrem Projekt verwendet werden, überarbeiten. Wenn Ihr Projekt z. B. "Erledigt" anstelle von "Geschlossen" verwendet, usw.

DAX-Funktionen

Weitere Informationen finden Sie in diesem Abschnitt für die DAX-Funktionen, die zum Erstellen der berechneten Spalten und des Measures verwendet werden, die in diesem Artikel hinzugefügt wurden. Siehe auch DAX, Zeitintelligenzfunktionen.

Verwandte Artikel

• Informationen zur Power BI-Integration
• Erstellen von Analyseansichten
• Erste Schritte mit Power BI Desktop
• Entwerfen von Datasets für den Power BI-Connector
• Grundlegendes zu Workflowzuständen und Statuskategorien
• Erkunden des Datenmodells für Analytics