Gewusst wie: Definieren eines Konvertierungsoperators (Visual Basic)

  • Artikel

Wenn Sie eine Klasse oder Struktur definiert haben, können Sie einen Typkonvertierungsoperator zwischen dem Typ Ihrer Klasse oder Struktur und einem anderen Datentyp (z Integer. B. , Doubleoder String) definieren.

Definieren Sie die Typkonvertierung als CType Function-Prozedur innerhalb der Klasse oder Struktur. Alle Konvertierungsverfahren müssen sein Public Shared, und jede muss entweder Erweitern oder Einschränken angeben.

Das Definieren eines Operators für eine Klasse oder Struktur wird auch als Überladen des Operators bezeichnet.

Beispiel

Im folgenden Beispiel werden Konvertierungsoperatoren zwischen einer Struktur namens digit und definiert Byte.

Public Structure digit
Private dig As Byte
    Public Sub New(ByVal b As Byte)
        If (b < 0 OrElse b > 9) Then Throw New System.ArgumentException(
            "Argument outside range for Byte")
        Me.dig = b
    End Sub
    Public Shared Widening Operator CType(ByVal d As digit) As Byte
        Return d.dig
    End Operator
    Public Shared Narrowing Operator CType(ByVal b As Byte) As digit
        Return New digit(b)
    End Operator
End Structure

Sie können die Struktur digit mit dem folgenden Code testen.

Public Sub consumeDigit()
    Dim d1 As New digit(4)
    Dim d2 As New digit(7)
    Dim d3 As digit = CType(CByte(3), digit)
    Dim s As String = "Initial 4 generates " & CStr(CType(d1, Byte)) &
          vbCrLf & "Initial 7 generates " & CStr(CType(d2, Byte)) &
          vbCrLf & "Converted 3 generates " & CStr(CType(d3, Byte))
    Try
        Dim d4 As digit
        d4 = CType(CType(d1, Byte) + CType(d2, Byte), digit)
    Catch e4 As System.Exception
        s &= vbCrLf & "4 + 7 generates " & """" & e4.Message & """"
    End Try
    Try
        Dim d5 As digit = CType(CByte(10), digit)
    Catch e5 As System.Exception
        s &= vbCrLf & "Initial 10 generates " & """" & e5.Message & """"
    End Try
    MsgBox(s)
End Sub

Siehe auch