WMRMLicGen.Priority

WMRMLicGen.Priority

The Priority property specifies and retrieves the priority of the license.

Syntax

  WMRMLicGen
  .Priority = Long
Long = WMRMLicGen.Priority

Parameters

This property takes no parameters.

Return Values

If the property succeeds, it returns a Long containing the priority. If it fails, it returns a number in the error object.

Remarks

If the consumer has multiple licenses for a single content item, you can use the Priority property to order them. Lower numbers indicate lower priority. As a general rule, time-based licenses should be given a higher priority than count-based licenses.

Licenses are deleted after they have expired or when all rights are used. If you continually deliver new licenses with a higher priority, existing licenses might not ever be used or deleted.

The default value of this property is 0.

Example Code

' Assume that the content packager has sent encrypted content and 
' a header to a consumer. The client computer posts a challenge to 
' the license issuer. The challenge contains the header sent by the 
' content packager, actions requested by the client, and information 
' about the client computer. To issue a license, perform the 
' following steps.
'

' Declare variables and objects.

    Dim sHeader, sClientInfo, sPubKey, lResult, dwActionCnt
    Dim sLicRequest, lIndex, sRights, sKeyID, sSeed, sKey 
    Dim varCategory, varVersion, sLicense, sLicResponse
    Dim strRevinfo, ContainsRevinfo, strClientCRLs
    Dim sAction
    Dim HeaderObj
    Dim ChallengeObj
    Dim Rights Obj
    Dim LicGenObj
    Dim ResponseObj

' Create objects.

    Set HeaderObj = Server.CreateObject("Wmrmobjs.WMRMHeader")
    Set ChallengeObj = Server.CreateObject("Wmrmobjs.WMRMChallenge")
    Set RightsObj = Server.CreateObject("Wmrmobjs.WMRMRights")
    Set LicGenObj = Server.CreateObject("Wmrmobjs.WMRMLicGen")
    Set KeysObj = Server.CreateObject("Wmrmobjs.WMRMKeys")
    Set ResponseObj = Server.CreateObject("Wmrmobjs.WMRMResponse")
  
' Retrieve the license request from the client computer.

    sLicRequest = request.Form("challenge")

' Set the license request into the WMRMChallenge object.

    ChallengeObj.Challenge = sLicRequest

' Retrieve the header from the challenge.

    sHeader = ChallengeObj.Header

' Check for revocation information.

    strRevinfo = ChallengeObj.RevInfo
    ContainsRevinfo = ChallengeObj.RevInfoPresent

' Set the header into the WMRMHeader object.

    HeaderObj.Header = sHeader

' Verify the header with the public key created by the content
' packager.

    lResult = HeaderObj.Verify(sPubKey)
    if (lResult = 0) then
        ' The header has been corrupted.
    end if

' Retrieve the client information section of the challenge.

    sClientInfo = ChallengeObj.ClientInfo

' Define the additional rights to be granted to the consumer.

    RightsObj.Reset
    RightsObj.AllowBackupRestore = True
    RightsObj.AllowCopy = False
    RightsObj.BeginDate = "#20050101Z#"
    RightsObj.ExpirationDate = "#20051231Z#"
    RightsObj.DisableOnClockRollback = True
    
' Retrieve the string containing the defined rights, and set 
' the rights into the license.

    sRights = RightsObj.GetAllRights()
    LicGenObj.Rights = sRights

' Set the client information into the license.

    LicGenObj.ClientInfo = sClientInfo

' Check the individualized version of Windows Media Rights Manager
' running on the client computer.

    LicGenObj.GetClientVersion varCategory, varVersion
    Select Case varCategory
      Case 0
          ' Client is not individualized.
      case 1
          ' Client is individualized.
      Case Else
          ' Invalid client category.
    End Select

' Call the BindToPubKey property to send the client a public
' key used to verify the license. When the license contains a 
' public key, Windows Media Rights Manager on the client computer 
' verifies the license. The public key is included in the certificate
' sent to the license issuer by Windows Media License Service.

    LicGenObj.BindToPubKey = sPubKey 

' Set the name of the licensing server into the license.

    LicGenObj.Attribute("Author") = "name of the author"
    LicGenObj.Attribute("ContentDistributor") = "name of the distributor"
    LicGenObj.Attribute("ContentType") = "type of content distributed"
    LicGenObj.Attribute("Title") = "title of the content"

' Set the priority into the license. 

    LicGenObj.Priority = 10

' Retrieve the key ID from the header, and set it into the license.

    sKeyID = HeaderObj.KeyID
    LicGenObj.KeyID = sKeyID

' Use the key ID and your stored license key seed to create the 
' key, and set the key into the license. The license key seed is a
' shared secret between the content packager and the license issuer.

    KeysObj.KeyID = sKeyID
    KeysObj.Seed = sSeed
    sKey = KeysObj.GenerateKey()
    LicGenObj.SetKey("MSDRM", sKey)

' Get the certificate revocation lists that are supported by the client.
    strClientCRLs = LicGenObj.SupportedCRLS

' Create a license.

    sLicense = LicGen.GetLicenseToDeliver()

' Add this license to the license response.

    Call ResponseObj.AddLicense("2.0.0.0", sLicense)
    Call ResponseObj.AddRevocationData(strRevinfo, strClientCRLs, ContainsRevinfo)

' Retrieve a string containing the license response.

    sLicResponse = Response.GetLicenseResponse()

Requirements

Version: Windows Media Rights Manager 7 SDK or later

Reference: wmrmobjs 1.0 Type Library

Library: wmrmobjs.dll

Platform: Windows Server 2003

See Also

• WMRMLicGen Object

© 2007 Microsoft Corporation. All rights reserved.