Vorgehensweise: Zugreifen auf Dienste mit einem Duplexvertrag

Eine Funktion von Windows Communication Foundation (WCF) besteht in der Fähigkeit, einen Dienst zu erstellen, der ein Duplexnachrichtenmuster verwendet. Anhand dieses Musters kann ein Dienst mit dem Client über einen Rückruf kommunizieren Dieses Thema beschreibt die Schritte, mit denen Sie einen WCF-Client in einer Client-Klasse, die die Rückrufschnittstelle implementiert, erstellen können.

Eine Dualbindung macht die IP-Adresse des Clients für den Dienst verfügbar. Der Client sollte Sicherheit eingestellt haben, um sicherzustellen, dass nur Verbindungen zu vertrauensvollen Diensten hergestellt werden.

Ein Lernprogramm zum Erstellen eines grundlegenden WCF-Dienstes und - Clients finden Sie im Lernprogramm "Erste Schritte".

So greifen Sie auf einen Duplexdienst zu

1. Erstellen Sie einen Dienst, der zwei Schnittstellen enthält. Die erste Schnittstelle ist dem Dienst vorbehalten, die zweite Schnittstelle wird für den Rückruf verwendet. Weitere Informationen über zum Erstellen eines Duplexdienstes finden Sie unter Vorgehensweise: Erstellen eines Duplexvertrags.

2. Führen Sie den Dienst aus.

3. Verwenden Sie das ServiceModel Metadata Utility-Tool (Svcutil.exe), um die Verträge (Schnittstellen) für den Client zu generieren. Weitere Informationen dazu finden Sie unter Gewusst wie: Erstellen eines Windows Communication Foundation-Clients.

4. Implementieren Sie die Rückrufschnittstelle in der Client-Klasse, wie im nachfolgenden Beispiel dargestellt.

   public class CallbackHandler : ICalculatorDuplexCallback
   {
       public void Result(double result)
       {
           Console.WriteLine("Result ({0})", result);
       }
       public void Equation(string equation)
       {
           Console.WriteLine("Equation({0})", equation);
       }
   }
   

   Public Class CallbackHandler 
   Implements ICalculatorDuplexCallback
      Public Sub Result (ByVal result As Double)
         Console.WriteLine("Result ({0})", result)
      End Sub
       Public Sub Equation(ByVal equation As String)
           Console.Writeline("Equation({0})", equation)
       End Sub
   End Class
   

5. Erstellen Sie eine Instanz der InstanceContext-Klasse. Der Konstruktor benötigt eine Instanz der Client-Klasse.

   InstanceContext site = new InstanceContext(new CallbackHandler());
   

   Dim site As InstanceContext = New InstanceContext(new CallbackHandler())
   

6. Erstellen Sie eine Instanz des WCF-Clients mit dem Konstruktor, für den ein InstanceContext-Objekt erforderlich ist. Der zweite Parameter des Konstruktors ist der Name eines Endpunkts in der Konfigurationsdatei.

   CalculatorDuplexClient wcfClient = 
   new CalculatorDuplexClient(site, "default")
   

   Dim wcfClient As New CalculatorDuplexClient(site, "default")
   

7. Rufen Sie die Methoden des WCF-Clients wie erforderlich auf.

Beispiel

Im folgenden Codebeispiel wird das Erstellen einer Client-Klasse veranschaulicht, die auf einen Duplexvertrag zugreift.

Imports System
Imports System.ServiceModel

Namespace Microsoft.ServiceModel.Samples

    ' The service contract is defined in generatedClient.vb, generated from the service by the svcutil tool.

    ' Define class which implements callback interface of duplex contract
    Public Class CallbackHandler
        Implements ICalculatorDuplexCallback

        Public Sub Result(ByVal result As Double) Implements ICalculatorDuplexCallback.Result
            Console.WriteLine("Result({0})", result)
        End Sub

        Public Sub Equation(ByVal eqn As String) Implements ICalculatorDuplexCallback.Equation
            Console.WriteLine("Equation({0})", eqn)
        End Sub
    End Class

    Class Client
        Public Shared Sub Main()

            ' Construct InstanceContext to handle messages on callback interface
            Dim instanceContext As New InstanceContext(New CallbackHandler())

            ' Create a client
            Dim wcfClient As New CalculatorDuplexClient(instanceContext)
            Console.WriteLine("Press <ENTER> to terminate client once the output is displayed.")
            Console.WriteLine()

            Try
                ' Call the AddTo service operation.
                Dim value As Double = 100
                wcfClient.AddTo(value)

                ' Call the SubtractFrom service operation.
                value = 50
                wcfClient.SubtractFrom(value)

                ' Call the MultiplyBy service operation.
                value = 17.65
                wcfClient.MultiplyBy(value)

                ' Call the DivideBy service operation.
                value = 2
                wcfClient.DivideBy(value)

                ' Complete equation
                wcfClient.Clear()

                Console.ReadLine()

                'Closing the client gracefully closes the connection and cleans up resources
                wcfClient.Close()

            Catch timeout As TimeoutException
                Console.WriteLine(timeout.Message)
                wcfClient.Abort()
            Catch commException As CommunicationException
                Console.WriteLine(commException.Message)
                wcfClient.Abort()
            End Try
        End Sub

    End Class

End Namespace

Sicherheit

Siehe auch

Aufgaben

Vorgehensweise: Erstellen eines Duplexvertrags
Gewusst wie: Erstellen eines Windows Communication Foundation-Clients
Vorgehensweise: Verwenden der ChannelFactory

Konzepte

ServiceModel Metadata Utility-Tool (Svcutil.exe)

Weitere Ressourcen

Lernprogramm "Erste Schritte"