Anzeigen von XML-Inhalten in Anpassungsdateien des Office-Anpassungstools

Übersicht über Windows Script Host

Verwenden Sie zum Ausführen des Skripts Microsoft Windows Script Host (WSH), einen sprachenunabhängigen Skripthost für Windows Script-kompatible Skriptmodule. WSH unterstützt die Ausführung von Skripts sowohl vom Windows-Desktop als auch von der Eingabeaufforderung.

Zum Ausführen von Skripts von Windows stellt WScript.exe ein Windows-basiertes Dialogfeld zum Festlegen von Skripteigenschaften bereit. Zum Ausführen von Skripts von der Eingabeaufforderung stellt CScript.exe Befehlszeilenoptionen zum Festlegen von Skripteigenschaften zur Verfügung.

WSH bietet Drag & Drop-Unterstützung für Skripts. Das bedeutet, dass Sie Dateien auf ein WSH-Skript ziehen können. Die Dateinamen werden an der Befehlszeile in Argumente übersetzt.

Weitere Informationen zu WSH finden Sie in den folgenden Ressourcen auf der MSDN-Website:

• Grundlagen zu Windows Script Host (in englischer Sprache) (https://go.microsoft.com/fwlink/?linkid=100317\&clcid=0x407)

• Ausführen von Skripts (in englischer Sprache) (https://go.microsoft.com/fwlink/?linkid=100319\&clcid=0x407)

Beispielskript "ExtractOctXml.vbs"

In den folgenden Abschnitten finden Sie das Visual Basic-Beispielskript ExtractOctXml.vbs und Anweisungen zur Verwendung des Skripts zum Extrahieren von XML-Metadaten aus MSP-Anpassungsdateien des OAT.

Zum Speichern des Beispielskripts öffnen Sie einen Text-Editor, z. B. Microsoft Editor. Kopieren Sie den Skriptcode in diesem Abschnitt, und fügen Sie ihn in eine Datei ein. Speichern Sie die Skriptdatei unter ExtractOctXml.vbs.

' Utility to extract the metadata from an Office 2007 customization patch 
' For use with Windows Scripting Host, CScript.exe or WScript.exe
' Copyright (c) Microsoft Corporation. All rights reserved.
'
Option Explicit

Const msiOpenDatabaseModePatchFile = 32
Const msiOpenDatabaseModeReadOnly     = 0
Const msiReadStreamBytes = 1

Const ForWriting = 2
Const TristateTrue = -1

Dim pathOCT_Patch 'As String
Dim pathMetadataXml 'As String
Dim sMetadata 'As String
Dim wshShell 'As Wscript.Shell
Dim fso 'As FileSystemObject
Dim fileOutput 'As File
Dim sErrSection ' As String


sErrSection = "ArgCheck"
' Check arg count, and display help if argument not present or contains ?
Dim argCount:argCount = Wscript.Arguments.Count
If argCount > 0 Then If InStr(1, Wscript.Arguments(0), "?", vbTextCompare) > 0 Then argCount = 0
If (argCount = 0) Then
    Wscript.Echo "Office 2007 OCT Metadata Extract utility" & _
        vbNewLine & " You must supply the location of the Office 2007 customization patch " & _
        vbNewLine & _
        vbNewLine & "Copyright (C) Microsoft Corporation.  All rights reserved."
    Wscript.Quit 1
Else
    pathOCT_Patch = Trim(Wscript.Arguments(0))
End If


sErrSection = "FSO"
' Create FileSystemObject and verify file exists
Set fso = CreateObject("Scripting.FileSystemObject") : CheckError
If Not fso.FileExists(pathOCT_Patch) Then Err = 2 : CheckError


sErrSection = "WI"
' Connect to Windows Installer object
On Error Resume Next
Dim wi : Set wi = Nothing
Set wi = Wscript.CreateObject("WindowsInstaller.Installer") : CheckError


sErrSection = "Read Metadata"
' Open OCT patch and read the metadata stream
Dim wiStorage, vw, rec
Set wiStorage = wi.OpenDatabase(pathOCT_Patch, msiOpenDatabaseModePatchFile) : CheckError
Set vw = wiStorage.OpenView("SELECT * FROM _Streams WHERE `Name`='metadata' ") : CheckError
vw.Execute
Set rec = vw.Fetch
If Not rec Is Nothing Then
    sMetadata = rec.ReadStream(2, rec.DataSize(2), msiReadStreamBytes)
Else
    Wscript.Echo "No Metadata stream was found in this file: " & pathOCT_Patch
    Wscript.Quit 2
End If

Set wiStorage = Nothing
Set rec = Nothing: Set vw = Nothing
Set wi = Nothing


sErrSection = "Write Metadata"
' Write the metadata stream to a temp file
Set wshShell = CreateObject("WScript.Shell") : CheckError
pathMetadataXml = wshShell.ExpandEnvironmentStrings("%temp%") & "\" & fso.GetFileName(pathOCT_Patch) & ".xml"
Set fileOutput = fso.OpenTextFile(pathMetadataXml, ForWriting, True, -1) : CheckError
fileOutput.WriteLine sMetadata 
fileOutput.Close

Set fileOutput = Nothing: Set fso = Nothing

sErrSection = "Show Metadata"
' Launch Metadata in IE
wshShell.Run "iexplore.exe " & pathMetadataXml 

    
    
Sub CheckError
Dim sMsg, errRec
    If Err = 0 Then Exit Sub
    sMsg = sErrSection & vbNewLine & Err.Source & " " & Hex(Err) & ": " & Err.Description
    If Not wi Is Nothing Then
    Set errRec = wi.LastErrorRecord
        If Not errRec Is Nothing Then sMsg = sMsg & vbNewLine & errRec.FormatText
    End If
    Wscript.Echo sMsg
    Wscript.Quit 2
End Sub

Sub NoMetadata
End Sub

Siehe auch

Konzepte

Office-Anpassungstool im 2007 Office System