CREATE SYNONYM (Transact-SQL)

Syntax

CREATE SYNONYM [ schema_name_1. ] synonym_name FOR < object >

< object > :: =
{
    [ server_name.[ database_name ] . [ schema_name_2 ].| database_name . [ schema_name_2 ].| schema_name_2. ] object_name
}

Argumente

• schema_name_1
  Gibt das Schema an, in dem das Synonym erstellt wird. Wenn schema nicht angegeben ist, verwendet SQL Server das Standardschema des aktuellen Benutzers.

• synonym_name
  Der Name des neuen Synonyms.

• server_name
  Der Name des Servers, auf dem sich das Basisobjekt befindet.

• database_name
  Der Name der Datenbank, auf der sich das Basisobjekt befindet. Wenn database_name nicht angegeben ist, wird der Name der aktuellen Datenbank verwendet.

• schema_name_2
  Der Name des Schemas des Basisobjekts. Wenn schema_name nicht angegeben ist, wird das Standardschema des aktuellen Benutzers verwendet.

• object_name
  Der Name des Basisobjekts, auf das das Synonym verweist.

Hinweise

Das Basisobjekt muss zur Erstellungszeit des Synonyms nicht notwendigerweise vorhanden sein. SQL Server überprüft das Vorhandensein des Basisobjekts zur Laufzeit.

Synonyme können für die folgenden Objekttypen erstellt werden:

1 Enthält lokale und globale temporäre Tabellen

Vierteilige Namen für Funktionsbasisobjekte werden nicht unterstützt.

In dynamischem SQL können Synonyme erstellt und gelöscht werden. Außerdem kann auf sie verwiesen werden.

Berechtigungen

Zum Erstellen eines Synonyms in einem Schema muss ein Benutzer über die CREATE SYNONYM-Berechtigung verfügen und entweder der Besitzer des Schemas sein oder über die ALTER SCHEMA-Berechtigung verfügen.

Die CREATE SYNONYM-Berechtigung ist eine erteilbare Berechtigung.

Hinweis
Sie benötigen keine Berechtigung für das Basisobjekt, um die CREATE SYNONYM-Anweisung erfolgreich auszuführen, da alle Berechtigungsüberprüfungen für das Basisobjekt bis zur Laufzeit verzögert werden.

Beispiele

A. Erstellen eines Synonyms für ein lokales Objekt

USE tempdb;
GO
-- Create a synonym for the Product table in AdventureWorks.
CREATE SYNONYM MyProduct
FOR AdventureWorks.Production.Product;
GO

-- Query the Product table by using the synonym.
USE tempdb;
GO
SELECT ProductID, Name 
FROM MyProduct
WHERE ProductID < 5;
GO

B. Erstellen eines Synonyms zu einem Remoteobjekt

EXEC sp_addlinkedserver Server_Remote;
GO
USE tempdb;
GO
CREATE SYNONYM MyEmployee FOR Server_Remote.AdventureWorks.HumanResources.Employee;
GO

C. Erstellen eines Synonyms für eine benutzerdefinierte Funktion

-- Creating the dbo.OrderDozen function
CREATE FUNCTION dbo.OrderDozen (@OrderAmt int)
RETURNS int
WITH EXECUTE AS CALLER
AS
BEGIN
IF @OrderAmt % 12 <> 0
BEGIN
    SET @OrderAmt +=  12 - (@OrderAmt % 12)
END
RETURN(@OrderAmt);
END;
GO

-- Using the dbo.OrderDozen function
DECLARE @Amt int
SET @Amt = 15
SELECT @Amt AS OriginalOrder, dbo.OrderDozen(@Amt) AS ModifiedOrder

-- Create a synonym dbo.CorrectOrder for the dbo.OrderDozen function.
CREATE SYNONYM dbo.CorrectOrder
FOR dbo.OrderDozen;
GO

-- Using the dbo.CorrectOrder synonym.
DECLARE @Amt int
SET @Amt = 15
SELECT @Amt AS OriginalOrder, dbo.CorrectOrder(@Amt) AS ModifiedOrder

Siehe auch

Verweis

Konzepte