ENABLE TRIGGER (Transact-SQL)

Syntax

ENABLE TRIGGER { [ schema_name . ] trigger_name [ ,...n ] | ALL }
ON { object_name | DATABASE | ALL SERVER } [ ; ]

Argumente

• schema_name
  Der Name des Schemas, zu dem der Trigger gehört. schema_name kann für DDL- oder LOGON-Trigger nicht angegeben werden.

• trigger_name
  Der Name des Triggers, der aktiviert werden soll.

• ALL
  Gibt an, dass alle im Bereich der ON-Klausel definierten Trigger aktiviert sind.

• object_name
  Der Name der Tabelle oder Sicht, in der der DML-Trigger trigger_name zur Ausführung erstellt wurde.

• DATABASE
  Für einen DDL-Trigger wird dadurch angegeben, dass trigger_name zur Ausführung mit dem Datenbankbereich erstellt oder geändert wurde.

• ALL SERVER
  Für einen DDL-Trigger wird hiermit angegeben, dass trigger_name zur Ausführung mit dem Serverbereich erstellt oder geändert wurde. ALL SERVER gilt auch für LOGON-Trigger.

Hinweise

Durch das Aktivieren eines Triggers wird dieser nicht neu erstellt. Ein deaktivierter Trigger ist weiterhin als Objekt in der aktuellen Datenbank vorhanden, wird aber nicht ausgelöst. Durch das Aktivieren eines Triggers wird dieser ausgelöst, wenn eine beliebige Transact-SQL-Anweisung ausgeführt wird, für die er ursprünglich programmiert wurde.Trigger werden mit DISABLE TRIGGER deaktiviert. Für Tabellen definierte DML-Trigger können auch mithilfe von ALTER TABLE deaktiviert und aktiviert werden.

Berechtigungen

Zum Aktivieren eines DML-Triggers benötigt der Benutzer mindestens die ALTER-Berechtigung für die Tabelle oder Sicht, in der der Trigger erstellt wurde.

Zum Aktivieren eines DDL-Triggers mit Serverbereich (ON ALL SERVER) oder eines LOGON-Triggers benötigt der Benutzer die CONTROL SERVER-Berechtigung auf dem Server.Zum Aktivieren eines DDL-Triggers mit Datenbankbereich (ON DATABASE) benötigt der Benutzer mindestens die ALTER ANY DATABASE DDL TRIGGER-Berechtigung in der aktuellen Datenbank.

Beispiele

A. Aktivieren eines DML-Triggers für eine Tabelle

USE AdventureWorks;
GO
DISABLE TRIGGER Person.uAddress ON Person.Address;
GO
ENABLE Trigger Person.uAddress ON Person.Address;
GO

B. Aktivieren eines DDL-Triggers

IF EXISTS (SELECT * FROM sys.triggers
    WHERE parent_class = 0 AND name = 'safety')
DROP TRIGGER safety ON DATABASE;
GO
CREATE TRIGGER safety 
ON DATABASE 
FOR DROP_TABLE, ALTER_TABLE 
AS 
   PRINT 'You must disable Trigger "safety" to drop or alter tables!' 
   ROLLBACK;
GO
DISABLE TRIGGER safety ON DATABASE;
GO
ENABLE TRIGGER safety ON DATABASE;
GO

C. Aktivieren aller Trigger, die mit dem gleichen Bereich definiert wurden

USE AdventureWorks;
GO
ENABLE Trigger ALL ON ALL SERVER;
GO

Siehe auch

Verweis