Tabellen zur Versionsgeschichte von Arbeitsaufgaben

Artikel
07/20/2011

Verlaufsdaten zu Fehlern, Aufgaben und anderen Typen von Arbeitsaufgaben können Sie mit FactWorkItemHistory und den zugeordneten Dimensionstabellen abfragen, wie die folgende Abbildung zeigt. Verlaufsdaten enthalten Informationen über den Status einer Arbeitsaufgabe bzw. den Wert eines Felds einer Arbeitsaufgabe, und wie dieser sich im Lauf der Zeit geändert hat. Status- und Burndowndiagramme sind Beispiele für Berichte, die aus Tabellen zur Versionsgeschichte von Arbeitsaufgaben erstellt werden. Die Daten werden mit ausgleichenden Datensätzen gespeichert. Weitere Informationen zu ausgleichenden Datensätzen finden Sie unter Neues in der Berichterstellung für Visual Studio ALM.

Faktentabelle für die Versionsgeschichte der Arbeitsaufgaben

"FactWorkItemHistory" ist "FactCurrentWorkItem" und den folgenden Dimensionstabellen zugeordnet:

DimArea
DimIteration
DimPerson
DimTeamProject

Sie können den historischen Arbeitsauslastungstrend mithilfe der folgenden Beispielabfrage für den Zeitraum zwischen 2009-09-21 und 2009-09-30 für bestimmte Benutzertextabschnitte suchen. Diese Abfrage gibt für jeden Benutzertextabschnitt im Teamprojekt Informationen zum gesamten abgeschlossenen Werk zurück, die ursprüngliche geschätzte Arbeit, die verbleibende Arbeit und die gesamten Textabschnittspunkte für jeden Tag an diesem Zeitraum. Weitere Informationen über User Stories finden Sie unter User Story (Agile).

Tipp

Diese Abfrage geht davon aus, dass ein Benutzertextabschnitt durch untergeordnete Links mit anderen Arbeitsaufgaben verknüpft wird.

declare @TeamProjectNodeSK int
select @TeamProjectNodeSK = ProjectNodeSK from GetProjectNodeInfoFromReportFolder(N'/TfsReports/VSTSDF/ProcessDev10')
-- This table value function returns the ProjectNodeSK: the Surrogate Key of a team project under a certain area path.

declare @TeamProjectCollectionGuid nvarchar(36)
select @TeamProjectCollectionGuid = pc.ProjectNodeGUID from DimTeamProject p inner join DimTeamProject pc on p.ParentNodeSK = pc.ProjectNodeSK where p.ProjectNodeSK = @TeamProjectNodeSK
-- This query finds the team project collection GUID by joining TeamProject.ParentNodeSK to TeamProject.ProjectNodeSK

select 
    d.DateSK
    ,wi.System_Title
    ,wi.System_Id
    ,coalesce(sum(wih_child.Microsoft_VSTS_Scheduling_CompletedWork),   0) as Total_CompletedWork, -- Finds the total number of hours of completed work.
    coalesce(sum(wih_child.Microsoft_VSTS_Scheduling_OriginalEstimate), 0) as Total_OriginalEstimate --Finds the total number of hours of original estimate.
    ,coalesce(sum(wih_child.Microsoft_VSTS_Scheduling_RemainingWork), 0) as Total_RemainingWork--Finds the total number of hours of remaining work.
    ,coalesce(sum(wih_child.Microsoft_VSTS_Scheduling_StoryPoints), 0) as Total_StoryPoints --Finds the total story points.
from
    DimDate d
cross apply
    DimWorkItem wi
cross apply
    GetWorkItemsTree(@TeamProjectCollectionGuid, wi.System_Id,      
N'Child', d.DateSK) wit 
left join          
    FactWorkItemHistory wih_child   
        on wih_child.WorkItemSK = wit.ChildWorkItemSK
where
    d.DateSK >= N'2009-09-21 00:00:00.000' 
    and d.DateSK <= N'2009-9-30 00:00:00.000'
    and wi.TeamProjectSK = @TeamProjectNodeSK 
    and wi.System_WorkItemType = N'User Story' 
    and wi.System_ChangedDate <= d.DateSK
    and wi.System_RevisedDate > d.DateSK
    and wi.System_State = N'Active'
    and (wih_child.RecordCount != -1 or wih_child.RecordCount is null)
group by d.DateSK, wi.System_Id, wi.System_Title