GetXmlNamespace-Operator (Visual Basic)

Artikel
02/26/2013

Ruft das XNamespace-Objekt ab, das dem angegebenen XML-Namespacepräfix entspricht.

GetXmlNamespace(xmlNamespacePrefix)

Teile

xmlNamespacePrefix
Optional.Die Zeichenfolge, die das XML-Namespacepräfix identifiziert.Falls angegeben, muss diese Zeichenfolge ein gültiger XML-Bezeichner sein.Weitere Informationen finden Sie unter Namen von deklarierten XML-Elementen und Attributen (Visual Basic).Wenn kein Präfix angegeben ist, wird der Standardnamespace zurückgegeben.Wenn kein Standardnamespace angegeben ist, wird ein leerer Namespace zurückgegeben.

Rückgabewert

Das XNamespace-Objekt, das dem XML-Namespacepräfix entspricht.

Hinweise

Der Operator GetXmlNamespace ruft das XNamespace-Objekt ab, das dem XML-Namespacepräfix xmlNamespacePrefix entspricht.

XML-Namespacepräfixe können in XML-Literalen und XML-Achseneigenschaften direkt verwendet werden.Bevor es im Code verwendet werden kann, muss jedoch das Namespacepräfix mit dem Operator GetXmlNamespace in ein XNamespace-Objekt konvertiert werden.Ein nicht qualifizierter Elementname kann an ein XNamespace-Objekt angehängt werden, um ein vollqualifiziertes XName-Objekt zu erhalten, das für viele LINQ to XML-Methoden erforderlich ist.

Beispiel

Im folgenden Beispiel wird ns als ein XML-Namespacepräfix importiert.Anschließend wird das Namespacepräfix verwendet, um ein XML-Literal zu erstellen und auf den ersten untergeordneten Knoten mit dem qualifizierten Namen ns:phone zuzugreifen.Anschließend wird dieser untergeordnete Knoten an die ShowName-Unterroutine übergeben, die einen qualifizierten Namen erstellt, indem der Operator GetXmlNamespace verwendet wird.Die ShowName-Unterroutine übergibt dann den qualifizierten Namen an die Ancestors-Methode, um den übergeordneten ns:contact-Knoten zu erhalten.

' Place Imports statements at the top of your program.  
Imports <xmlns:ns="http://SomeNamespace">

Module GetXmlNamespaceSample

    Sub RunSample()

        ' Create test by using a global XML namespace prefix. 

        Dim contact = 
            <ns:contact>
                <ns:name>Patrick Hines</ns:name>
                <ns:phone ns:type="home">206-555-0144</ns:phone>
                <ns:phone ns:type="work">425-555-0145</ns:phone>
            </ns:contact>

        ShowName(contact.<ns:phone>(0))
    End Sub

    Sub ShowName(ByVal phone As XElement)
        Dim qualifiedName = GetXmlNamespace(ns) + "contact"
        Dim contact = phone.Ancestors(qualifiedName)(0)
        Console.WriteLine("Name: " & contact.<ns:name>.Value)
    End Sub

End Module

Wenn TestGetXmlNamespace.RunSample() aufgerufen wird, wird ein Meldungsfeld mit dem folgenden Text angezeigt:

Name: Patrick Hines

Siehe auch

Referenz

Imports-Anweisung (XML-Namespace)

Weitere Ressourcen

Zugreifen auf XML in Visual Basic

Freigeben über