Übung: Hinzufügen von Parametern und Decorators

• 8 Minuten

Im Rahmen der Migration der Anwendung der Personalabteilung erstellen Sie eine Bicep-Vorlage zum Bereitstellen von Azure-Ressourcen. In dieser Übung erstellen Sie ein Speicherkonto, einen Azure App Service-Plan und eine App Service-App. Sie wenden Decorators auf jeden Parameter an, um sicherzustellen, dass sie immer die von Ihnen erwarteten Werte enthalten.

Während des Prozesses führen Sie die folgenden Aufgaben aus:

In dieser Übung wird die Bicep-Erweiterung für Visual Studio Code verwendet. Sie müssen diese Erweiterung in Visual Studio Code installieren.

Erstellen einer Bicep-Vorlage mit Parametern

1. Öffnen Sie Visual Studio Code.

2. Erstellen Sie eine neue Datei namens main.bicep.

3. Speichern Sie die leere Datei, damit Visual Studio Code die Bicep-Tools lädt.

   Sie können entweder Datei>Speichern unter oder STRG+S unter Windows (⌘+S unter macOS) auswählen. Merken Sie sich unbedingt den Speicherort der Datei. Sie können dazu beispielsweise einen Ordner scripts (Skripts) erstellen und sie darin speichern.

4. Fügen Sie in der Datei folgenden Code ein. Sie werden die Vorlage in Kürze bereitstellen. Geben Sie den Inhalt selbst ein, anstatt ihn zu kopieren und einzufügen, damit Sie sehen können, wie die Tools Sie beim Schreiben Ihrer Bicep-Dateien unterstützen.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   Sie erstellen hier mehrere Parameter, die eine Mischung aus Typen verwenden. Sie definieren Standardwerte für jeden Parameter. Einige der Standardwerte umfassen Zeichenfolgeninterpolation und die uniqueString()-Funktion.

   Tipp

   Die uniqueString()-Funktion ist nützlich, um global eindeutige Ressourcennamen zu erstellen. Sie gibt eine Zeichenfolge zurück, die bei jeder Bereitstellung in derselben Ressourcengruppe identisch ist, sich jedoch bei der Bereitstellung in anderen Ressourcengruppen oder Abonnements unterscheidet.

   Sie definieren auch Variablen, die die Namen des Azure App Service-Plans und der App Service-App erzeugen. Deren Werte enthalten einige der Parameter, die Sie angegeben haben. Parameterwerte können vom Benutzer außer Kraft gesetzt werden, der die Bereitstellung ausgeführt, aber die Werte der Variablen können nicht außer Kraft gesetzt werden.

   Tipp

   Sie geben an, dass der location-Parameter auf westus3 festgelegt werden soll. Normalerweise würden Sie Ressourcen am gleichen Standort wie die Ressourcengruppe erstellen, indem Sie die resourceGroup().location-Eigenschaft verwenden. Wenn Sie jedoch mit der Microsoft Learn Sandbox arbeiten, müssen Sie bestimmte Azure-Regionen verwenden, die nicht mit dem Standort der Ressourcengruppe übereinstimmen.

5. Fügen Sie in Visual Studio Code am Ende der Datei main.bicep den folgenden Code hinzu:

   resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   Beachten Sie, dass die Ressourcen die Werte der von Ihnen definierten Parameter verwenden.

6. Speichern Sie die Änderungen in der Datei.

Hinzufügen von Parameterbeschreibungen

1. Fügen Sie in der Datei main.bicep in Visual Studio Code den Decorator @description direkt über jedem Parameter hinzu, den Sie in der vorherigen Aufgabe erstellt haben. Die Parameter sollte dem folgenden Beispiel ähneln:

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. Speichern Sie die Änderungen in der Datei.

Begrenzen von Eingabewerten

Ihr Spielzeugunternehmen stellt die Anwendung der Personalabteilung in drei Umgebungen bereit: dev, test und prod. Sie beschränken den environmentName-Parameter so, dass nur diese drei Werte zulässig sind.

1. Suchen Sie in der Datei main.bicep in Visual Studio Code den Parameter environmentName. Fügen Sie einen Decorator @allowed unterhalb des Decorators @description ein. Nachdem Sie fertig sind, sollte der Parameter wie im folgenden Beispiel aussehen:

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   Beachten Sie, dass Sie den Parameterwert für den Parameter environmentName auf dev, test und prod beschränken. Wenn in Zukunft weitere Umgebungen hinzugefügt werden, müssen Sie diese Liste aktualisieren.

2. Speichern Sie die Änderungen in der Datei.

Begrenzen von Eingabelängen

Ihr Parameter solutionName wird verwendet, um die Namen von Ressourcen zu generieren. Sie möchten eine Mindestlänge von 5 Zeichen und eine maximale Länge von 30 Zeichen erzwingen.

1. Suchen Sie in der Datei main.bicep in Visual Studio Code den Parameter solutionName. Fügen Sie die Decorators @minLength und @maxLength unterhalb des Decorators @description hinzu. Nachdem Sie fertig sind, sollte der Parameter wie im folgenden Beispiel aussehen:

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. Speichern Sie die Änderungen in der Datei.

Begrenzen numerischer Werte

Als Nächstes stellen Sie sicher, dass der Parameter appServicePlanInstanceCount nur Werte zwischen 1 und 10 zulässt.

1. Suchen Sie in der Datei main.bicep in Visual Studio Code den Parameter appServicePlanInstanceCount. Fügen Sie die Decorators @minValue und @maxValue unterhalb des Decorators @description hinzu. Nachdem Sie fertig sind, sollte der Parameter wie im folgenden Beispiel aussehen:

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. Speichern Sie die Änderungen in der Datei.

Überprüfen Ihrer Bicep-Datei

Nachdem Sie alle oben genannten Änderungen durchgeführt haben, sollte Ihre Bicep-Datei wie im folgenden Beispiel aussehen:

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

Andernfalls kopieren Sie das Beispiel, oder passen Sie Ihre Vorlage an das Beispiel an.

Bereitstellen der Bicep-Vorlage in Azure

az bicep install && az bicep upgrade

az configure --defaults group="<rgn>[sandbox resource group name]</rgn>"

az deployment group create --template-file main.bicep

Set-AzDefault -ResourceGroupName <rgn>[sandbox resource group name]</rgn>

New-AzResourceGroupDeployment -TemplateFile main.bicep

Überprüfen Ihrer Bereitstellung

1. Navigieren Sie zum Azure-Portal, und stellen Sie sicher, dass Sie sich im Sandboxabonnement befinden:

   1. Wählen Sie dazu Ihren Avatar in der rechten oberen Ecke der Seite aus.
   2. Klicken Sie dann auf Verzeichnis wechseln. Wählen Sie in der Liste das Verzeichnis Microsoft Learn Sandbox aus.

2. Wählen Sie im linken Bereich Ressourcengruppen aus.

3. Wählen Sie [Name der Sandboxressourcengruppe] aus.

4. In der Übersicht wird angezeigt, dass eine Bereitstellung erfolgreich war.

   

5. Wählen Sie 1 Succeeded (1 erfolgreich) aus, um die Details der Bereitstellung anzuzeigen.

   

6. Wählen Sie die Bereitstellung mit dem Namen main aus, um anzuzeigen, welche Ressourcen bereitgestellt wurden. Wählen Sie dann Bereitstellungsdetails aus, um sie zu erweitern. In diesem Fall gibt es einen App Service-Plan und eine App.

   

7. Wählen Sie im linken Menü Eingaben aus.

   

8. Beachten Sie, dass die Parameter und ihre Werte aufgelistet sind.

   

9. Lassen Sie die Seite in Ihrem Browser geöffnet. Sie werden die Bereitstellungen später erneut überprüfen.