SystemRestoreConfig-Klasse

Stellt Eigenschaften zum Steuern der Häufigkeit der Erstellung geplanter Wiederherstellungspunkte und der Menge des auf jedem Laufwerk verbrauchten Speicherplatzes bereit.

Syntax

class SystemRestoreConfig
{
  uint32 RPSessionInterval;
  uint32 RPGlobalInterval;
  uint32 RPLifeInterval;
  uint32 DiskPercent;
};

Member

Die SystemRestoreConfig-Klasse weist folgende Typen von Mitgliedern auf:

• Eigenschaften

Eigenschaften

Die SystemRestoreConfig-Klasse verfügt über diese Eigenschaften.

DiskPercent

Datentyp: uint32

Zugriffstyp: Schreibgeschützt

Der maximale Speicherplatz auf jedem Laufwerk, das von der Systemwiederherstellung verwendet werden kann. Dieser Wert wird als Prozentsatz des gesamten Laufwerkspeicherplatzes angegeben. Der Standardwert beträgt 12 Prozent.

Windows Vista: Empfängt einen Wert vom Volumeschattenkopie-Dienst (Volume Shadow Copy Service, VSS). Das ist der maximale Speicherplatz auf jedem Laufwerk, das von der Systemwiederherstellung verwendet werden kann. Der Standardwert beträgt 15 Prozent des gesamten Laufwerksspeicherplatzes oder 30 Prozent des verfügbaren freien Speicherplatzes, je nachdem, welcher Wert kleiner ist.

RPGlobalInterval

Datentyp: uint32

Zugriffstyp: Schreibgeschützt

Das absolute Zeitintervall (in Sekunden), in dem geplante Systemprüfpunkte erstellt werden. Der Standardwert ist 86.400 (24 Stunden).

Windows Vista: Empfängt einen Wert von der Aufgabenplanung für die Systemwiederherstellung. Null, wenn die Aufgabe deaktiviert ist.

RPLifeInterval

Datentyp: uint32

Zugriffstyp: Schreibgeschützt

Das Zeitintervall (in Sekunden), in dem Wiederherstellungspunkte beibehalten werden. Wenn ein Wiederherstellungspunkt älter als dieses angegebene Intervall wird, wird er gelöscht. Die standardmäßige Altersgrenze beträgt 90 Tage.

Windows Vista: Empfängt einen Wert von UINTMAX.

RPSessionInterval

Datentyp: uint32

Zugriffstyp: Schreibgeschützt

Das Zeitintervall (in Sekunden), in dem geplante Systemprüfpunkte während der Sitzung erstellt werden. Der Standardwert ist Null. Dieser gibt an, dass das Feature deaktiviert ist.

Windows Vista: Empfängt Null, wenn die Systemwiederherstellung deaktiviert ist.

Beispiele

Der folgende Beispielcode wird nicht unterstützt. Verwenden Sie das Befehlszeilentool „Vssadmin.exe“, um die Größe des reservierten Speicherplatzes zu ändern.

Windows XP: Dieses Beispiel wird unterstützt.

'The SystemRestoreConfig class provides properties for controlling the frequency of 
'scheduled restore point creation and the amount of disk space consumed on each drive.

Set Args = wscript.Arguments
Set regSR = GetObject("winmgmts:{impersonationLevel=impersonate}!root/default:SystemRestoreConfig='SR'")

If Args.Count() = 0 Then
    Wscript.Echo "Usage: RegSR [RP{Session|Global|Life}Interval[=value]] [DiskPercent[=value]]"
Else    
For i = 0 To Args.Count() - 1
    Myarg = Args.Item(i)
    Pos = InStr(Myarg, "=")
    If Pos <> 0 Then
        Myarray = Split(Myarg, "=", -1, 1)
        myoption = Myarray(0)
        value = Myarray(1)
    Else 
        myoption = Myarg
    End If    
    If myoption = "RPSessionInterval" Then
        If Pos = 0 Then
            Wscript.Echo "RPSessionInterval = " & regSR.RPSessionInterval
        Else    
            regSR.RPSessionInterval = value
            regSR.Put_
        End If
    ElseIf myoption = "RPGlobalInterval" Then
        If Pos = 0 Then
            Wscript.Echo "RPGlobalInterval = " & regSR.RPGlobalInterval
        Else    
            regSR.RPGlobalInterval = value
            regSR.Put_
        End If
    ElseIf myoption = "RPLifeInterval" Then
        If Pos = 0 Then
            Wscript.Echo "RPLifeInterval = " & regSR.RPLifeInterval
        Else    
            regSR.RPLifeInterval = value
            regSR.Put_
        End If
    ElseIf myoption = "DiskPercent" Then
        If Pos = 0 Then
            Wscript.Echo "DiskPercent = " & regSR.DiskPercent
        Else    
            regSR.DiskPercent = value
            regSR.Put_
        End If
    End If
Next
End If

Anforderungen

Siehe auch

Wiederherstellungspunkte

Windows-Verwaltungsinstrumentation