Anmeldetriggerbeispiel (Skripterstellung)

  • Artikel

In diesem Skriptbeispiel wird gezeigt, wie Sie eine Aufgabe erstellen, die für die Ausführung von Editor geplant ist, wenn sich ein Benutzer anmeldet. Der Task enthält einen Anmeldetrigger, der eine Startgrenze für den zu startenden Task und einen Benutzerbezeichner angibt, der den Benutzer angibt. Der Task wird mithilfe der Gruppe Administratoren als Sicherheitskontext zum Ausführen der Aufgabe registriert.

Im folgenden Verfahren wird beschrieben, wie Sie planen, dass eine ausführbare Datei wie Editor gestartet wird, wenn sich ein angegebener Benutzer anmeldet.

So planen Sie den Start von Editor, wenn sich ein Benutzer anmeldet

  1. Erstellen Sie ein TaskService-Objekt . Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
  2. Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder-Methode , um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask-Methode , um das TaskDefinition-Objekt zu erstellen, das den Task darstellt.
  3. Definieren Sie Informationen zum Task mithilfe des TaskDefinition-Objekts . Verwenden Sie die TaskDefinition.Settings-Eigenschaft , um die Einstellungen zu definieren, die bestimmen, wie der Taskplanerdienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo-Eigenschaft , um die Informationen zu definieren, die die Aufgabe beschreiben.
  4. Erstellen Sie mithilfe der TaskDefinition.Triggers-Eigenschaft einen Anmeldetrigger. Diese Eigenschaft ermöglicht den Zugriff auf das TriggerCollection-Objekt . Verwenden Sie die TriggerCollection.Create-Methode (geben Sie den Typ des Triggers an, den Sie erstellen möchten), um einen Anmeldetrigger zu erstellen. Legen Sie beim Erstellen des Triggers die Start- und Endgrenze des Triggers fest, um den Trigger zu aktivieren und zu deaktivieren. Sie müssen die UserId-Eigenschaft für den Trigger festlegen, damit die Aktionen des Tasks ausgeführt werden, wenn sich der angegebene Benutzer nach der Startgrenze anmeldet.
  5. Erstellen Sie mithilfe der TaskDefinition.Actions-Eigenschaft eine Aktion für die auszuführende Aufgabe. Diese Eigenschaft ermöglicht den Zugriff auf das ActionCollection-Objekt . Verwenden Sie die ActionCollection.Create-Methode , um den Typ der Aktion anzugeben, die Sie erstellen möchten. In diesem Beispiel wird ein ExecAction-Objekt verwendet, das eine Aktion darstellt, die eine ausführbare Datei startet.
  6. Registrieren Sie den Task mithilfe der TaskFolder.RegisterTaskDefinition-Methode . In diesem Beispiel wird die Aufgabe registriert, sodass die Gruppe Administratoren als Sicherheitskontext zum Ausführen der Aufgabe verwendet wird.

Das folgende VBScript-Beispiel zeigt, wie sie eine Aufgabe für die Ausführung von Editor planen, wenn sich ein Benutzer anmeldet.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when a user logs on.
'---------------------------------------------------------

' A constant that specifies a logon trigger.
const TriggerTypeLogon = 9
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when a " & _
    "specified user logs on."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a logon trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeLogon)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2006-05-02T10:49:02"
endTime = "2006-05-02T10:52:02"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "LogonTriggerId"
trigger.UserId = "DOMAIN\UserName"   ' Must be a valid user account   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
    "Test Logon Trigger", taskDefinition, createOrUpdateTask, _
    "Builtin\Administrators", , 4)

WScript.Echo "Task submitted."

Verwenden des Aufgabenplaners