Registrierungstriggerbeispiel (Skripterstellung)

In diesem Skriptbeispiel wird gezeigt, wie Sie eine Aufgabe erstellen, die für die Ausführung von Editor geplant ist, wenn eine Aufgabe registriert ist. Der Task enthält einen Registrierungstrigger, der eine Startgrenze und eine Endgrenze für den Task angibt. Die Startgrenze gibt an, wann der Trigger aktiviert wird. Der Task enthält auch eine Aktion, die den Task angibt, um Editor auszuführen.

Im folgenden Verfahren wird beschrieben, wie eine ausführbare Datei wie Editor beim Registrieren einer Aufgabe gestartet wird.

So planen Sie den Start von Editor, wenn eine Aufgabe registriert wird

1. Erstellen Sie ein TaskService-Objekt . Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
2. Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder-Methode , um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask-Methode , um das TaskDefinition-Objekt zu erstellen, das den Task darstellt.
3. Definieren Sie Informationen zum Task mithilfe des TaskDefinition-Objekts . Verwenden Sie die TaskDefinition.Settings-Eigenschaft , um die Einstellungen zu definieren, die bestimmen, wie der Taskplanerdienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo-Eigenschaft , um die Informationen zu definieren, die die Aufgabe beschreiben.
4. Erstellen Sie einen Registrierungstrigger mithilfe der TaskDefinition.Triggers-Eigenschaft . Diese Eigenschaft ermöglicht den Zugriff auf das TriggerCollection-Objekt . Verwenden Sie die TriggerCollection.Create-Methode (geben Sie den Typ des Triggers an, den Sie erstellen möchten), um einen Registrierungstrigger zu erstellen.
5. Erstellen Sie mithilfe der TaskDefinition.Actions-Eigenschaft eine Aktion für die auszuführende Aufgabe. Diese Eigenschaft ermöglicht den Zugriff auf das ActionCollection-Objekt . Verwenden Sie die ActionCollection.Create-Methode , um den Typ der Aktion anzugeben, die Sie erstellen möchten. In diesem Beispiel wird ein ExecAction-Objekt verwendet, das eine Aktion darstellt, die eine ausführbare Datei startet.
6. Registrieren Sie den Task mithilfe der TaskFolder.RegisterTaskDefinition-Methode .

Das folgende VBScript-Beispiel zeigt, wie Sie einen Task erstellen, der die Ausführung von Editor beim Registrieren des Tasks plant.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when
' the task is registered.
'---------------------------------------------------------

' A constant that specifies a registration trigger.
const TriggerTypeRegistration = 7
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad when the task is registered."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a registration trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeRegistration)

trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "RegistrationTriggerId"   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes Notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Registration Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Zugehörige Themen

Verwenden des Aufgabenplaners