Zeittriggerbeispiel (Skripterstellung)

  • Artikel

In diesem Skriptbeispiel wird gezeigt, wie Sie eine Aufgabe erstellen, die Editor zu einem bestimmten Zeitpunkt ausführt. Die Aufgabe enthält einen zeitbasierten Trigger, der eine Startgrenze zum Aktivieren der Aufgabe angibt, eine ausführbare Aktion, die Editor ausführt, und eine Endgrenze, die den Task deaktiviert.

Im folgenden Verfahren wird beschrieben, wie Sie einen Task zum Starten einer ausführbaren Datei zu einem bestimmten Zeitpunkt planen.

So planen Sie den Editor für den Start zu einem bestimmten Zeitpunkt

  1. Erstellen Sie ein TaskService-Objekt . Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
  2. Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder-Methode , um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask-Methode , um das TaskDefinition-Objekt zu erstellen, das den Task darstellt.
  3. Definieren Sie Informationen zum Task mithilfe des TaskDefinition-Objekts . Verwenden Sie die TaskDefinition.Settings-Eigenschaft , um die Einstellungen zu definieren, die bestimmen, wie der Taskplaner-Dienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo-Eigenschaft , um die Informationen zu definieren, die den Vorgang beschreiben.
  4. Erstellen Sie mithilfe der TaskDefinition.Triggers-Eigenschaft einen zeitbasierten Trigger. Diese Eigenschaft bietet Zugriff auf das TriggerCollection-Objekt . Verwenden Sie die TriggerCollection.Create-Methode (geben Sie den Typ des Triggers an, den Sie erstellen möchten), um einen zeitbasierten Trigger zu erstellen. Legen Sie beim Erstellen des Triggers die Start- und Endgrenze des Triggers fest, um den Trigger zu aktivieren und zu deaktivieren. Die Startgrenze gibt an, wann die Aktion des Tasks ausgeführt wird.
  5. Erstellen Sie mithilfe der TaskDefinition.Actions-Eigenschaft eine Aktion für die auszuführende Aufgabe. Diese Eigenschaft ermöglicht den Zugriff auf das ActionCollection-Objekt . Verwenden Sie die ActionCollection.Create-Methode , um den Typ der Aktion anzugeben, die Sie erstellen möchten. In diesem Beispiel wird ein ExecAction-Objekt verwendet, das eine Aktion darstellt, die einen Befehlszeilenvorgang ausführt.
  6. Registrieren Sie den Task mithilfe der TaskFolder.RegisterTaskDefinition-Methode . In diesem Beispiel startet die Aufgabe Editor zum aktuellen Zeitpunkt plus 30 Sekunden.

Das folgende VBScript-Beispiel zeigt, wie Sie eine Aufgabe so planen, dass Editor 30 Sekunden nach der Registrierung des Vorgangs ausgeführt wird.

'------------------------------------------------------------------
' This sample schedules a task to start notepad.exe 30 seconds
' from the time the task is registered.
'------------------------------------------------------------------

' A constant that specifies a time-based trigger.
const TriggerTypeTime = 1
' A constant that specifies an executable action.
const ActionTypeExec = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at a certain time"
regInfo.Author = "Author Name"

'********************************************************
' Set the principal for the task
Dim principal
Set principal = taskDefinition.Principal

' Set the logon type to interactive logon
principal.LogonType = 3


' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a time-based trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeTime)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime

Dim time
time = DateAdd("s", 30, Now)  'start time = 30 seconds from now
startTime = XmlTime(time)

time = DateAdd("n", 5, Now) 'end time = 5 minutes from now
endTime = XmlTime(time)

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "TimeTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test TimeTrigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."



'------------------------------------------------------------------
' Used to get the time for the trigger 
' startBoundary and endBoundary.
' Return the time in the correct format: 
' YYYY-MM-DDTHH:MM:SS. 
'------------------------------------------------------------------
Function XmlTime(t)
    Dim cSecond, cMinute, CHour, cDay, cMonth, cYear
    Dim tTime, tDate

    cSecond = "0" & Second(t)
    cMinute = "0" & Minute(t)
    cHour = "0" & Hour(t)
    cDay = "0" & Day(t)
    cMonth = "0" & Month(t)
    cYear = Year(t)

    tTime = Right(cHour, 2) & ":" & Right(cMinute, 2) & _
        ":" & Right(cSecond, 2)
    tDate = cYear & "-" & Right(cMonth, 2) & "-" & Right(cDay, 2)
    XmlTime = tDate & "T" & tTime 
End Function

Verwenden des Aufgabenplanungsmoduls