Beispiel für wöchentlichen Trigger (Skripterstellung)
In diesem Skriptbeispiel wird gezeigt, wie Sie jeden Montag jeder Woche um 8:00 Uhr eine Aufgabe erstellen, die Editor ausführt. Die Aufgabe enthält einen täglichen Trigger, der angibt, wann der Task ausgeführt wird, und eine ausführbare Aktion, die Editor ausführt.
Im folgenden Verfahren wird beschrieben, wie Sie eine Aufgabe so planen, dass eine ausführbare Datei am Montag jeder Woche um 8:00 Uhr gestartet wird.
So planen Sie, dass Editor am Montag jeder Woche um 8:00 Uhr beginnt
Erstellen Sie ein TaskService-Objekt . Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder-Methode , um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask-Methode , um das TaskDefinition-Objekt zu erstellen, das den Task darstellt.
Definieren Sie Informationen zum Task mithilfe des TaskDefinition-Objekts . Verwenden Sie die TaskDefinition.Settings-Eigenschaft , um die Einstellungen zu definieren, die bestimmen, wie der Taskplaner-Dienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo-Eigenschaft , um die Informationen zu definieren, die den Vorgang beschreiben.
Erstellen Sie einen wöchentlichen Trigger mit der TaskDefinition.Triggers-Eigenschaft . Diese Eigenschaft bietet Zugriff auf das TriggerCollection-Objekt , das zum Erstellen des Triggers verwendet wird.
Verwenden Sie die TriggerCollection.Create-Methode (geben Sie den Typ des Triggers an, den Sie erstellen möchten), um einen wöchentlichen Trigger zu erstellen.
Legen Sie die WeeklyTrigger.StartBoundary-Eigenschaft fest, um anzugeben, wann der Trigger aktiviert wird und wann der Task ausgeführt wird. In diesem Beispiel wird der Trigger am 1. Januar 2005 aktiviert, und der Task wird um 8:00 Uhr ausgeführt.
Legen Sie die WeeklyTrigger.EndBoundary-Eigenschaftfest, um anzugeben, wann der Trigger deaktiviert wird. In diesem Beispiel wird der Trigger am 1. Januar 2015 deaktiviert.
Legen Sie die WeeklyTrigger.DaysOfWeek-Eigenschaft fest, um die Wochentage anzugeben, an denen der Task ausgeführt wird. In diesem Beispiel wird die Aufgabe am Montag ausgeführt.
Legen Sie die WeeklyTrigger.WeeksInterval-Eigenschaftfest, um das Intervall zwischen den Wochen im Zeitplan anzugeben. In diesem Beispiel wird der Task jede Woche ausgeführt.
Erstellen Sie mithilfe der TaskDefinition.Actions-Eigenschaft eine Aktion für die auszuführende Aufgabe. Diese Eigenschaft bietet Zugriff auf das ActionCollection-Objekt , das zum Erstellen der Aktion verwendet wird. Verwenden Sie die ActionCollection.Create-Methode , um den Typ der Aktion anzugeben, die Sie erstellen möchten. In diesem Beispiel wird ein ExecAction-Objekt verwendet, das eine Aktion darstellt, die einen Befehlszeilenvorgang ausführt.
Registrieren Sie den Task mithilfe der TaskFolder.RegisterTaskDefinition-Methode . In diesem Beispiel wird der Editor am Montag jeder Woche um 8:00 Uhr gestartet.
Das folgende VBScript-Beispiel zeigt, wie Sie eine Aufgabe so planen, dass Editor täglich um 8:00 Uhr ausgeführt wird.
'------------------------------------------------------------------
' This sample schedules a task to start on a weekly basis.
'------------------------------------------------------------------
' A constant that specifies a weekly trigger.
const TriggerTypeWeekly = 3
' A constant that specifies an executable action.
const ActionTypeExec = 0
'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()
'********************************************************
' Get a folder to create a task definition in.
Dim rootFolder
Set rootFolder = service.GetFolder("\")
' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0)
'********************************************************
' Define information about the task.
' Set the registration info for the task by
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad weekly."
regInfo.Author = "Administrator"
' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False
'********************************************************
' Create a weekly trigger. Note that the start boundary
' specifies the time of day that the task starts, the
' day-of-week specfies on what day of the week the task
' runs, and the interval specifies what weeks the task runs.
Dim triggers
Set triggers = taskDefinition.Triggers
Dim trigger
Set trigger = triggers.Create(TriggerTypeWeekly)
' Trigger variables that define when the trigger is active
' and the time of day that the task is run. The format of
' this tims is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime
Dim time
startTime = "2006-05-02T08:00:00" 'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"
WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime
trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysOfWeek = 1
trigger.WeeksInterval = 1 'Task runs every week.
trigger.Id = "WeeklyTriggerId"
trigger.Enabled = True
'***********************************************************
' Create the action for the task to execute.
' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"
WScript.Echo "Task definition created. About to submit the task..."
'***********************************************************
' Register (create) the task.
call rootFolder.RegisterTaskDefinition( _
"Test Weekly Trigger", taskDefinition, 6, , , 3)
WScript.Echo "Task submitted."
Zugehörige Themen