Azure Notification Hub Property at path properties.pnsCredentials cannot be changed

@Tommy Le Thanks for posting your question in Microsoft Q&A, apologize for any inconvenience caused on this.

Could you please let us know if you are still facing the issue. If you are still facing the issue, please do help us with bicep template that you are trying to deploy the notification hub.

I've worked it out. The issue that I've found is when using the 2023-10-01-preview to provision the notification namespace it doesn't like it. Originally, I was using 2017-04-01 without issues. Even with the 2023-09-01 version was giving the same error. The bicep below is what is working for me. I can provision the hub using 2023-10-01-preview, but for the namespace, I had to use 2017-04-01. Anything later will fail. This was following the documentation and it just didn't work.

param notificationHubName string
param namespaceName string
param location string
param tags object = {}
param replicationRegion string = 'None'
param zoneRedundancy string = 'Disabled'
param namespaceType string = 'NotificationHub'

@allowed([
  'Free'
  'Basic'
  'Standard'
])
@description('Sku')
param sku string = 'Free'

@secure()
param fcmPrivateKey string = ''

@secure()
param fcmClientEmail string = ''

@secure()
param fcmProjectId string = ''

@secure()
param appleToken string = ''

@secure()
@description('App Id prefix (Team ID)')
param appleAppId string = ''

@secure()
@description('Bundle ID')
param appleAppName string = ''

@secure()
@description('A 10-character key identifier (kid) key, obtained from your developer account. Specify if using Token Authentication Mode')
param appleKeyId string = ''

@secure()
param apnsEndpoint string = ''

var fcmCredentialProperties = !empty(fcmPrivateKey)
  ? {
      fcmV1Credential: {
        properties: {
          clientEmail: fcmClientEmail
          privateKey: fcmPrivateKey
          projectId: fcmProjectId
        }
      }
    }
  : {}

var appleHubProperties = !empty(appleToken)
  ? {
      apnsCredential: {
        properties: {
          appId: appleAppId
          appName: appleAppName
          keyId: appleKeyId
          token: appleToken
          endpoint: apnsEndpoint
        }
      }
    }
  : {}

resource namespace 'Microsoft.NotificationHubs/namespaces@2017-04-01' = {
  name: namespaceName
  location: location
  tags: tags
  sku: {
    name: sku
  }
  properties: {
    namespaceType: namespaceType
  }
}

resource notificationHub 'Microsoft.NotificationHubs/namespaces/notificationHubs@2023-10-01-preview' = {
  name: notificationHubName
  location: location
  tags: tags
  parent: namespace
  properties: {
    apnsCredential: empty(appleHubProperties) ? null : appleHubProperties.apnsCredential
    fcmV1Credential: empty(fcmCredentialProperties) ? null : fcmCredentialProperties.fcmV1Credential
  }
}

 output namespaceId string = namespace.id
 output notificationHubId string = notificationHub.id