MS Word Hyperlink tag removed after field unlink

Question

MS Word Hyperlink tag removed after field unlink

Zhu, Ligong 260

Hi, We use VBA code to populate many docvariables at runtime. Recently we added a "Hyperlink" tag to a static url link in our document for 508 compliance purpose. During VBA field update, we realize that this VBA line ("Unlink") actually would delete this hyperlink tag from generated Word document:

ActiveDocument.Fields.Update

ActiveDocument.Fields.Unlink

All other regular docvariable fields are populated correctly.

Without this Unlink line, the generated document will contain hidden docvariables, which we don't want to have.

You can see a sample document image containing a hyperlink tag, which will be deleted after Unlink code.

Is there anything we can do to keep Hyperlink tag while still populate docvariable correctly?

Thanks.

Screenshot 2025-06-06 142201

2 answers

Your answer

Answer 1

Jay Freedman 201 Volunteer Moderator

To avoid removing the HYPERLINK keyword, you'll have to loop through the ActiveDocument.Fields collection and test each field's Type property. If it's wdFieldHyperlink, then don't execute the Unlink for that field:

Dim fld As Field
For Each fld In ActiveDocument.Fields
If Not fld.Type = wdFieldHyperlink Then
fld.Unlink
End If
Next fld

If your documents could contain hyperlinks in storyranges other than the main one, you'll have to code for those ranges (headers, footers, footnotes, endnotes, textboxes/shapes) separately.

Zhu, Ligong 260 Reputation points

2025-06-10T14:46:34.1166667+00:00

Thank you very much for your reply. Your code works great for hyperlinks if it is included directly in the document. However if it is included in an autotext field then it is not working. The loop you provided for each field can detect "wdFieldHyperlink" if it is not inside an autotext entry but it won't see it inside any autotext field so field unlink call will erase its hyperlink tag. Is there anything that can be done so that a hyperlink inside autotext entry can be detected/skipped so that it can keep its hyperlink tag?
Zhu, Ligong 260 Reputation points

2025-06-11T10:06:36.8766667+00:00

Same problem if a hyperlink is inside a "IF" condition, The loop for all fields can detect "wdFieldIf" field but can't detect hyperlink field inside it so it will be deleted by unlink.
Jay Freedman 201 Reputation points Volunteer Moderator

2025-06-12T11:43:16.1333333+00:00

Please show samples of the field codes of Autotext and IF fields that have hyperlinks embedded inside them. There will be a (somewhat complicated) way to detect those fields, but I need to know where the hyperlinks appear in the field codes so the detection works properly. Screenshots of existing field codes, displayed by pressing Alt+F9, will be sufficient.
Zhu, Ligong 260 Reputation points

2025-06-12T12:05:28.0666667+00:00

Thank you very much for helping us.

In this sample snippet document above, first hyperlink works correctly but the second one doesn't since it is inside "IF" condition and third one (not showing but it is inside autotext "SLAnyQuestion") also doesn't work.
Jay Freedman 201 Reputation points Volunteer Moderator

2025-06-12T19:14:11.3833333+00:00

Revised code in the second answer...

Answer 2

Sub UnlinkFieldsExceptHyperlinks()
    Dim fld As Field
    Dim rgInner As Range
    Dim fldInner As Field
    
    For Each fld In ActiveDocument.Fields
        Select Case fld.Type
            Case wdFieldHyperlink
                'skip it
                GoTo SkipHyper
            
            ' in the next Case statement you can add other
            ' field types that could hide a hyperlink,
            ' such as wdFieldQuote, separated by commas
            Case wdFieldAutoText, wdFieldIf
                Set rgInner = fld.Code
                For Each fldInner In rgInner.Fields
                    If fldInner.Result.Hyperlinks.Count = 0 Then fldInner.Unlink
                Next fldInner
            
            ' unlink any other kind of field
            Case Else
                fld.Unlink
SkipHyper:
            ' give Windows control to avoid "not responding" state
            DoEvents
        End Select
    Next fld
    
    ' release the local object
    Set rgInner = Nothing
End Sub

Share via

MS Word Hyperlink tag removed after field unlink

2 answers

Your answer