UserControl Click Event Problem

Question

Hello,
I have a problem with a custom button that I am trying to make in visual basic using a usercontrol. It consists of a picturebox and a label. I want to call the click event from my main form, but the picturebox and the label don't do anything when I click them. Only the background area of the usercontrol does what I want it to do. Any ideas?

Thanks in advance!

Accepted Answer

I did a quick test with a Delegate and it works normally, I receive the click from the PictureBox =>
(MyUserControl1 added from Designer)

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

    End Sub

    Private Sub PicClick() Handles MyUserControl1.PictureBoxClick
        Console.Beep(8000, 10)
    End Sub

End Class


Public Class MyUserControl
    Inherits System.Windows.Forms.UserControl

    Private label1 As System.Windows.Forms.Label
    Private WithEvents pictureBox1 As System.Windows.Forms.PictureBox

    Private components As System.ComponentModel.IContainer

    Public Delegate Sub PictureBoxClickHandler()
    Public Event PictureBoxClick As PictureBoxClickHandler

    Public Sub New()
        InitializeComponent()
    End Sub

    Public Sub InitializeComponent()
        components = New System.ComponentModel.Container()
        label1 = New System.Windows.Forms.Label()
        pictureBox1 = New System.Windows.Forms.PictureBox()

        pictureBox1.Name = "PictureBox1"
        pictureBox1.BorderStyle = System.Windows.Forms.BorderStyle.FixedSingle
        pictureBox1.Location = New System.Drawing.Point(10, 10)
        pictureBox1.Size = New System.Drawing.Size(90, 75)

        label1.Text = "Label"
        label1.Location = New System.Drawing.Point(10, 95)
        label1.Size = New System.Drawing.Size(200, 20)

        Controls.AddRange(New System.Windows.Forms.Control() {label1, pictureBox1})

        Size = New System.Drawing.Size(300, 250)
    End Sub

    Private Sub PictureBox1_Click(sender As Object, e As EventArgs) Handles pictureBox1.Click
        OnPictureBoxClick()
    End Sub

    Protected Overridable Sub OnPictureBoxClick()
        RaiseEvent PictureBoxClick()
    End Sub
End Class

Answer

Hello,

The easy way is to set the modifier property of the button in the user control from friend to public then call PerformClick on the button. Otherwise create a public procedure that does what the button would do then call the sub.

Base example (I realize there is a picture box but for this I use a label, the concept is how to access a click event)

Public Class UserControl1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ChangeLabel()
    End Sub
    Public Sub ChangeLabel()
        Label1.Text = Now.ToShortTimeString()
    End Sub
End Class

In the above code if the modifier for the button is friend than call ChangeLabel e.g. as shown in Button1_Click while if the button modifier is button is public call PerformClick.

Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        MyUserControl.ChangeLabel()
    End Sub

    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        MyUserControl.Button1.PerformClick()
    End Sub
End Class

Full source

https://github.com/karenpayneoregon/forum-questions/tree/master/UserControlDemo

Answer

If you really want to allow clicking the free area of User Control, and also accept clicking on picturebox and label, then try adding this
code to User Control:

Private Sub UserControl1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

   AddHandler PictureBox1.Click, Sub(s, a)
      OnClick(Nothing)
   End Sub

   AddHandler Label1.Click, Sub(s, a)
      OnClick(Nothing)
   End Sub

End Sub

(Adjust the names according to your controls).

If only picturebox and label should be clickable, then the solution is different.

Share via

UserControl Click Event Problem

2 additional answers

Full source

Your answer