How to patch Windows Server 2008 Core using WSUS

  • Article

Using the script from here, I can patch my Core box. I've added some code (bold) so I don't have to look up the return codes (which can be found here).

Dim myResultCode(5)
myResultCode(0) = "Not started"
myResultCode(1) = "In Progress"
myResultCode(2) = "Succeeded"
myResultCode(3) = "Succeeded, but with errors"
myResultCode(4) = "Failed"
myResultCode(5) = "Aborted"

Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateupdateSearcher()

WScript.Echo "Searching for updates..." & vbCRLF

Set searchResult = _
updateSearcher.Search("IsInstalled=0 and Type='Software'")

WScript.Echo "List of applicable items on the machine:"

For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> " & update.Title
Next

If searchResult.Updates.Count = 0 Then
 WScript.Echo "There are no applicable updates."
 WScript.Quit
End If

WScript.Echo vbCRLF & "Creating collection of updates to download:"

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 to searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> adding: " & update.Title
    updatesToDownload.Add(update)
Next

WScript.Echo vbCRLF & "Downloading updates..."

Set downloader = updateSession.CreateUpdateDownloader()
downloader.Updates = updatesToDownload
downloader.Download()

WScript.Echo  vbCRLF & "List of downloaded updates:"

For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    If update.IsDownloaded Then
       WScript.Echo I + 1 & "> " & update.Title
    End If
Next

Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")

WScript.Echo  vbCRLF & _
"Creating collection of downloaded updates to install:"

For I = 0 To searchResult.Updates.Count-1
    set update = searchResult.Updates.Item(I)
    If update.IsDownloaded = true Then
       WScript.Echo I + 1 & "> adding:  " & update.Title
       updatesToInstall.Add(update) 
    End If
Next

WScript.Echo  vbCRLF & "Would you like to install updates now? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo

If (strInput = "N" or strInput = "n") Then
 WScript.Quit
ElseIf (strInput = "Y" or strInput = "y") Then
 WScript.Echo "Installing updates..."
 Set installer = updateSession.CreateUpdateInstaller()
 installer.Updates = updatesToInstall
 Set installationResult = installer.Install()
 
 'Output results of install
 RetCode = installationResult.ResultCode
 WScript.Echo "Installation Result: " & _
 RetCode & " (" & myResultCode(RetCode) & ")"
 WScript.Echo "Reboot Required: " & _
 installationResult.RebootRequired & vbCRLF
 WScript.Echo "Listing of updates installed " & _
  "and individual installation results:"
 
 For I = 0 to updatesToInstall.Count - 1
  RetCode = installationResult.GetUpdateResult(i).ResultCode
  WScript.Echo I + 1 & "> " & _
  updatesToInstall.Item(i).Title & _
  ": " & RetCode & " (" & myResultCode(RetCode ) & ")"   
 Next

End If

Copy the content, save it to "c:\tools\wu.vbs" on your core box and run it: "cscript c:\tools\wu.vbs":

Comments

  • Anonymous
    January 01, 2003
    The comment has been removed