Lambda functions for Bicep

This article describes the lambda functions to use in Bicep. Lambda expressions (or lambda functions) are essentially blocks of code that can be passed as an argument. They can take multiple parameters, but are restricted to a single line of code. In Bicep, lambda expression is in this format:

<lambda variable> => <expression>

Limitations

Bicep lambda function has these limitations:

• Lambda expression can only be specified directly as function arguments in these functions: filter(), groupBy(), map(), mapValues(), reduce(), sort(), and toObject().
• Using lambda variables (the temporary variables used in the lambda expressions) inside resource or module array access isn't currently supported.
• Using lambda variables inside the listKeys function isn't currently supported.
• Using lambda variables inside the reference function isn't currently supported.

filter

filter(inputArray, lambda expression)

Filters an array with a custom filtering function.

Namespace: sys.

Parameters

Return value

An array.

Examples

The following examples show how to use the filter function.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Cira'
    age: 8
    interests: ['Rubs']
  }
]

output oldDogs array = filter(dogs, dog => dog.age >=5)
output dogNameIndex array = filter(dogs, (val, i) => i < 2 && substring(val.name, 0, 1) == 'C')

The outputs from the preceding example:

oldDogs lists the dogs that are five or older; dogNameIndex identifies the dogs whose index number is less than two and whose name starts with the letter "C".

var itemForLoop = [for item in range(0, 10): item]

output filteredLoop array = filter(itemForLoop, i => i > 5)
output isEven array = filter(range(0, 10), i => 0 == i % 2)

The outputs from the preceding example:

filterdLoop shows the numbers in an array that are greater than 5; and isEven shows the even numbers in the array.

groupBy

groupBy(inputArray, lambda expression)

Creates an object with array values from an array, using a grouping condition.

Namespace: sys.

Parameters

Return value

An object.

Examples

The following example shows how to use the groupBy function.

var inputArray = ['foo', 'bar', 'baz']

output outObject object = groupBy(inputArray, x => substring(x, 0, 1)) 

The output from the preceding example:

outObject shows an object that groups the array elements by their first letters.

map

map(inputArray, lambda expression)

Applies a custom mapping function to each element of an array.

Namespace: sys.

Parameters

Return value

An array.

Example

The following example shows how to use the map function.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]

output dogNames array = map(dogs, dog => dog.name)
output sayHi array = map(dogs, dog => 'Hello ${dog.name}!')
output mapArray array = map(range(0, length(dogs)), i => {
  i: i
  dog: dogs[i].name
  greeting: 'Ahoy, ${dogs[i].name}!'
})
output mapArrayIndex array = map(dogs, (x, i) => { index: i, val: x.name})

The outputs from the preceding example are:

dogNames shows the dog names from the array of objects; sayHi concatenates "Hello" and each of the dog names; mapArray and mapArrayIndex create another two arrays of objects.

mapValues

mapValues(inputObject, lambda expression)

Creates an object from an input object, using a lambda expression to map values.

Namespace: sys.

Parameters

Return value

An object.

Example

The following example shows how to use the mapValues function.

var inputObject = { foo: 'foo', bar: 'bar' }

output mapObject object = mapValues(inputObject, val => toUpper(val)) 

The output from the preceding example is:

mapObject creates another object with the values in upper case.

reduce

reduce(inputArray, initialValue, lambda expression)

Reduces an array with a custom reduce function.

Namespace: sys.

Parameters

Return value

Any.

Example

The following examples show how to use the reduce function.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]
var ages = map(dogs, dog => dog.age)
output totalAge int = reduce(ages, 0, (cur, next) => cur + next)
output totalAgeAdd1 int = reduce(ages, 1, (cur, next) => cur + next)
output oddAge int = reduce(ages, 0, (cur, next, i) => (i % 2 == 0) ? cur + next : cur)

The outputs from the preceding example are:

totalAge sums the ages of the dogs; totalAgeAdd1 has an initial value of 1, and adds all the dog ages to the initial values. oddAge sums the ages of dogs that are located at even indices, specifically 5 (Evie) and 2 (Indy).

output reduceObjectUnion object = reduce([
  { foo: 123 }
  { bar: 456 }
  { baz: 789 }
], {}, (cur, next) => union(cur, next))

The output from the preceding example is:

The union function returns a single object with all elements from the parameters. The function call unionizes the key value pairs of the objects into a new object.

sort

sort(inputArray, lambda expression)

Sorts an array with a custom sort function.

Namespace: sys.

Parameters

Return value

An array.

Example

The following example shows how to use the sort function.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]

output dogsByAge array = sort(dogs, (a, b) => a.age < b.age)

The output from the preceding example sorts the dog objects from the youngest to the oldest:

toObject

toObject(inputArray, lambda expression, [lambda expression])

Converts an array to an object with a custom key function and optional custom value function. See items about converting an object to an array.

Namespace: sys.

Parameters

Return value

An object.

Example

The following example shows how to use the toObject function with the two required parameters:

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: [ 'Ball', 'Frisbee' ]
  }
  {
    name: 'Casper'
    age: 3
    interests: [ 'Other dogs' ]
  }
  {
    name: 'Indy'
    age: 2
    interests: [ 'Butter' ]
  }
  {
    name: 'Kira'
    age: 8
    interests: [ 'Rubs' ]
  }
]

output dogsObject object = toObject(dogs, entry => entry.name)

The preceding example generates an object based on an array.

The following toObject function with the third parameter provides the same output.

output dogsObject object = toObject(dogs, entry => entry.name, entry => entry)

The following example shows how to use the toObject function with three parameters.

var dogs = [
  {
    name: 'Evie'
    properties: {
      age: 5
      interests: [ 'Ball', 'Frisbee' ]
    }
  }
  {
    name: 'Casper'
    properties: {
      age: 3
      interests: [ 'Other dogs' ]
    }
  }
  {
    name: 'Indy'
    properties: {
      age: 2
      interests: [ 'Butter' ]
    }
  }
  {
    name: 'Kira'
    properties: {
      age: 8
      interests: [ 'Rubs' ]
    }
  }
]
output dogsObject object = toObject(dogs, entry => entry.name, entry => entry.properties)

The preceding example generates an object based on an array.

Next steps

• See Bicep functions - arrays for more array-related Bicep functions.