How to Modify a Configuration Manager Object by Using WMI

Article
05/03/2011

Applies To: System Center Configuration Manager 2007, System Center Configuration Manager 2007 R2, System Center Configuration Manager 2007 R3, System Center Configuration Manager 2007 SP1, System Center Configuration Manager 2007 SP2

You modify a Configuration Manager object, in Microsoft System Center Configuration Manager 2007, by using the object's SWbemObject object to change its properties.

To modify a Configuration Manager object

Set up a connection to the SMS Provider. For more information, see How to Connect to an SMS Provider in Configuration Manager by Using WMI.
Using the SWbemServices object you obtain from step one, call the Get method and specify the class and key information for the object you want. This returns a SWbemObject representing object.
Using the SWbemObject, update the object properties.
Call Put to update the object in the SMS Provider.

Example

The following VBScript code example gets a package (SMS_Package) object, changes the package description, and then commits the changes back to the SMS Provider. In this example, the package is retrieved through a call to the SWbemServices object Get. You can also retrieve the package by using a query. For more information, see How to Perform a Synchronous Configuration Manager Query by Using WMI.

For information about calling the sample code, see Calling Configuration Manager Code Snippets.

Sub ModifyPackageDescription (connection, packageID, description)
    
    On Error Resume Next 
    Dim package

    ' Get the package.
    Set package = connection.Get("SMS_Package.PackageID='" & packageID & "'")
    If Err.Number<>0 Then
        Wscript.Echo "Couldn't get package " + packageID
        Exit Sub
    End If
    
    Wscript.Echo "Package Name: " + package.Name
    Wscript.Echo "Current Description: " + package.Description
    
    ' Update and commit the package.
    package.Description = description
    
    package.Put_
    If Err.Number<>0 Then
        WScript.Echo "Couldn't commit the package"
        Exit Sub
    End If

    Wscript.Echo "New Description: " + package.Description
End Sub

This example method has the following parameters:

Parameter	Type	Description
connection	SWbemServices	A valid connection to the SMS Provider.
packageID	String	The package identifier. This is available from the SMS_Package class PackageID identifier.
Description	String	A new description for the object.

Other Resources

https://go.microsoft.com/fwlink/?LinkId=43950

Share via

How to Modify a Configuration Manager Object by Using WMI

To modify a Configuration Manager object

Example

See Also

Concepts

Other Resources

Additional resources