ProxySettings object

The ProxySettings object represents the configuration settings of a proxy server for the AD RMS installation. AD RMS clusters use proxy servers to connect to external networks such as the Internet or another forest. The properties you can specify include the name of the proxy server, the port number through which the proxy can communicate, whether a proxy is required, whether the proxy can be bypassed, and the proxy authentication credentials. You can retrieve this object by calling the ProxySettings property on the Enterprise object.

Members

The ProxySettings object has these types of members:

• Methods
• Properties

Methods

The ProxySettings object has these methods.

Properties

The ProxySettings object has these properties.

Examples

DIM config_manager
DIM admin_role

' *******************************************************************
' Create and initialize a ConfigurationManager object.

SUB InitObject()

  CALL WScript.Echo( "Create ConfigurationManager object...")
  SET config_manager = CreateObject _
    ("Microsoft.RightsManagementServices.Admin.ConfigurationManager")      
  CheckError()
    
  CALL WScript.Echo( "Initialize...")
  admin_role=config_manager.Initialize(false,"localhost",80,"","","")
  CheckError()

END SUB

' *******************************************************************
' Retrieve and set proxy settings.

SUB Proxy()

  DIM proxySettings

  ' Retrieve the ProxySettings object.
  SET proxySettings = config_manager.Enterprise.ProxySettings
  CheckError()

  ' Refresh the settings.
  proxySettings.Refresh()
  CheckError()

  ' Display the current settings.
  WScript.Echo("required: " _
               & proxySettings.Required)
  WScript.Echo("server : " _
               & proxySettings.Server)
  WScript.Echo("Port   : " _
               & proxySettings.Port)
  WScript.Echo("ByPass : " _
               & proxySettings.Bypass)
  WScript.Echo("ByPassFilter : " _
               & proxySettings.BypassFilter)
  WScript.Echo("Auth : ")
  WScript.Echo("Required : " _
               & proxySettings.Authentication.Required)
  WScript.Echo("Scheme : " _
                & proxySettings.Authentication.Scheme)
  WScript.Echo("Domain : " _
                & proxySettings.Authentication.UserAccount.Domain)
  WScript.Echo("UserID : " _
               & proxySettings.Authentication.UserAccount.UserId)
  WScript.Echo("Passwd : " _
               & proxySettings.Authentication.UserAccount.Password)

  ' Specify new settings.
  proxySettings.Required = TRUE
  proxySettings.Server = "NetProxy"
  proxySettings.Port = 80
  proxySettings.Bypass = TRUE
  proxySettings.BypassFilter = "http://www.widgets.microsoft.com/"
  proxySettings.Authentication.Required = TRUE
  proxySettings.Authentication.Scheme = 3
  proxySettings.Authentication.UserAccount.Domain = "user_Domain"
  proxySettings.Authentication.UserAccount.UserId = "user_ID"
  proxySettings.Authentication.UserAccount.Password = "user_Psswd"

  ' Update the proxy settings on the server.
  proxySettings.Update()
  CheckError()

END SUB

' *******************************************************************
' Error checking function.

FUNCTION CheckError()
  CheckError = Err.number
  IF Err.number <> 0 THEN
    CALL WScript.Echo( vbTab & "*****Error Number: " _
                       & Err.number _
                       & " Desc:" _
                       & Err.Description _
                       & "*****")
    WScript.StdErr.Write(Err.Description)
    WScript.Quit( Err.number )
  END IF
END FUNCTION

Requirements

See also

Active Directory Rights Management Services Scripting API Reference