Session.Put method

Updates a resource.

Syntax

Session.Put( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

Parameters

resourceUri [in]

The identifier of the resource to be updated.

This parameter can contain one of elements contained in the following list:

• URI with or without selectors. When calling the Put method to obtain a WMI resource, use the key property or properties of the object. For example, in the following Visual Basic Scripting Edition (VBScript) code example, the key is specified by Win32_Service?Name=winmgmt.

  strResourceUri = "http://schemas.microsoft.com/" & _ 
    "wbem/wsman/1/wmi/root/cimv2/Win32_Service?Name=winmgmt"
  

• ResourceLocator object which may contain selectors, fragments, or options.

• WS-Addressing endpoint reference as described in the WS-Management Protocol standard. For more information about the public specification for WS-Management protocol, see Management Specifications Index Page.

resource [in]

The updated resource content.

flags [in, optional]

Reserved. Must be set to 0.

Return value

The XML that contains the updated resource content.

Examples

The following VBScript code example writes data to the Win32_WMISetting object. You must include all non-array properties of the object in the XML of the Resource parameter. The order of the properties is not significant.

'Create a WSMan object.
Set objWsman = CreateObject( "WSMAN.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

'Create a Session object.
Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

'Change the property value by putting
'the new XML content into the resource.
Dim strResourceUri, strReturnedResourceUri, newXmlContent
strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
  & "wmi/root/cimv2/Win32_WMISetting"
newXmlContent = _
  "<p:Win32_WMISetting xmlns:p=""http://schemas.microsoft.com/" & _
  "wbem/wsman/1/wmi/root/cimv2/Win32_WMISetting"">" & _
  "<p:LoggingLevel>2</p:LoggingLevel></p:Win32_WMISetting>" 

On Error Resume Next
strReturnedResourceUri = objSession.Put(reourceUri, newXmlContent)
WScript.Echo "Returned resource Uri:" & Chr(10) & _
  strReturnedResourceUri
If Err.Number <> 0 Then
    DisplayErrorInfo
End If
On Error Goto 0

Sub DisplayErrorInfo()
    WScript.Echo "An error has occurred."     
    WScript.Echo
    WScript.Echo "Error Info"
    WScript.Echo "-----------"
    WScript.Echo "Number      : 0x" & hex(Err.number)
    WScript.Echo "Description : " & Err.Description
    WScript.Echo "Source      : " & Err.Source
    WScript.Echo "HelpFile    : " & Err.helpfile
    WScript.Echo "HelpContext : " & Err.HelpContext    
    WScript.Echo Err.Clear    
End Sub

Requirements

See also

Session