Inicio rápido: Creación de una instancia de Azure API Management mediante Terraform

SE APLICA A: Desarrollador | Estándar | Premium

En este artículo se muestra cómo usar Terraform para crear una instancia de API Management en Azure. También puede usar Terraform para tareas comunes de administración, como importar API en la instancia de API Management.

Azure API Management ayuda a las organizaciones a publicar API para desarrolladores externos, asociados e internos para liberar el potencial de sus datos y servicios. API Management proporciona las competencias esenciales para garantizar un programa de API de éxito mediante compromisos con desarrolladores, información detallada empresarial, análisis, seguridad y protección. Con API Management, cree y administre puertas de enlace de API modernas para los servicios back-end existentes hospedados en cualquier lugar.

Terraform habilita la definición, vista previa e implementación de la infraestructura en la nube. Con Terraform, se crean archivos de configuración mediante la sintaxis de HCL. La sintaxis de HCL permite especificar el proveedor de la nube, como Azure, y los elementos que componen la infraestructura de la nube. Después de crear los archivos de configuración, se crea un plan de ejecución que permite obtener una vista previa de los cambios de infraestructura antes de implementarlos. Una vez que compruebe los cambios, aplique el plan de ejecución para implementar la infraestructura.

En este artículo aprenderá a:

Requisitos previos

• Si no tiene una suscripción a Azure, cree una cuenta gratuita antes de empezar.

• Instalación y configuración de Terraform

• Para la CLI de Azure:

  • Use el entorno de Bash en Azure Cloud Shell. Para más información, consulte Inicio rápido para Bash en Azure Cloud Shell.

    

  • Si prefiere ejecutar comandos de referencia de la CLI localmente, instale la CLI de Azure. Si utiliza Windows o macOS, considere la posibilidad de ejecutar la CLI de Azure en un contenedor Docker. Para más información, vea Ejecución de la CLI de Azure en un contenedor de Docker.

    • Si usa una instalación local, inicie sesión en la CLI de Azure mediante el comando az login. Siga los pasos que se muestran en el terminal para completar el proceso de autenticación. Para ver otras opciones de inicio de sesión, consulte Inicio de sesión con la CLI de Azure.

    • En caso de que se le solicite, instale las extensiones de la CLI de Azure la primera vez que la use. Para más información sobre las extensiones, consulte Uso de extensiones con la CLI de Azure.

    • Ejecute az version para buscar cuál es la versión y las bibliotecas dependientes que están instaladas. Para realizar la actualización a la versión más reciente, ejecute az upgrade.

• Para Azure PowerShell:

  • Si opta por usar Azure PowerShell en un entorno local:
    • Instale la versión más reciente del módulo Az de PowerShell.
    • Conéctese a su cuenta de Azure mediante el cmdlet Connect-AzAccount.
  • Si decide usar Azure Cloud Shell:
    • Para más información, consulte Introducción a Azure Cloud Shell.

Implementación del código de Terraform

1. Cree un directorio en el que probar y ejecutar el código de ejemplo de Terraform y conviértalo en el directorio actual.

2. Cree un archivo denominado main.tf e inserte el siguiente código:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_api_management_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_api_management" "api" {
     name                = "apiservice${random_string.azurerm_api_management_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     publisher_email     = var.publisher_email
     publisher_name      = var.publisher_name
     sku_name            = "${var.sku}_${var.sku_count}"
   }
   

3. Cree un archivo denominado outputs.tf e inserte el siguiente código:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "api_management_service_name" {
     value = azurerm_api_management.api.name
   }
   

4. Cree un archivo denominado providers.tf e inserte el siguiente código:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Cree un archivo denominado variables.tf e inserte el siguiente código:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "publisher_email" {
     default     = "test@contoso.com"
     description = "The email address of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_email) > 0
       error_message = "The publisher_email must contain at least one character."
     }
   }
   
   variable "publisher_name" {
     default     = "publisher"
     description = "The name of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_name) > 0
       error_message = "The publisher_name must contain at least one character."
     }
   }
   
   variable "sku" {
     description = "The pricing tier of this API Management service"
     default     = "Developer"
     type        = string
     validation {
       condition     = contains(["Developer", "Standard", "Premium"], var.sku)
       error_message = "The sku must be one of the following: Developer, Standard, Premium."
     }
   }
   
   variable "sku_count" {
     description = "The instance size of this API Management service."
     default     = 1
     type        = number
     validation {
       condition     = contains([1, 2], var.sku_count)
       error_message = "The sku_count must be one of the following: 1, 2."
     }
   }
   

Inicialización de Terraform

Para inicializar la implementación de Terraform, ejecute terraform init. Este comando descarga el proveedor de Azure necesario para administrar los recursos de Azure.

terraform init -upgrade

Puntos clave:

• El parámetro -upgrade actualiza los complementos de proveedor necesarios a la versión más reciente que cumpla con las restricciones de versión de la configuración.

Creación de un plan de ejecución de Terraform

Ejecute terraform plan para crear un plan de ejecución.

terraform plan -out main.tfplan

Puntos clave:

• El comando terraform plan crea un plan de ejecución, pero no lo ejecuta. En su lugar, determina qué acciones son necesarias para crear la configuración especificada en los archivos de configuración. Este patrón le permite comprobar si el plan de ejecución coincide con sus expectativas antes de realizar cambios en los recursos reales.
• El parámetro -out opcional permite especificar un archivo de salida para el plan. El uso del parámetro -out garantiza que el plan que ha revisado es exactamente lo que se aplica.

Aplicación de un plan de ejecución de Terraform

Ejecute terraform apply para aplicar el plan de ejecución a su infraestructura en la nube.

terraform apply main.tfplan

Puntos clave:

• El comando terraform apply de ejemplo asume que ejecutó terraform plan -out main.tfplan previamente.
• Si especificó un nombre de archivo diferente para el parámetro -out, use ese mismo nombre de archivo en la llamada a terraform apply.
• Si no ha utilizado el parámetro -out, llame a terraform apply sin ningún parámetro.

Verificación de los resultados

Limpieza de recursos

Cuando ya no necesite los recursos creados a través de Terraform, realice los pasos siguientes:

1. Ejecute el comando terraform plan y especifique la marca destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Puntos clave:

   • El comando terraform plan crea un plan de ejecución, pero no lo ejecuta. En su lugar, determina qué acciones son necesarias para crear la configuración especificada en los archivos de configuración. Este patrón le permite comprobar si el plan de ejecución coincide con sus expectativas antes de realizar cambios en los recursos reales.
   • El parámetro -out opcional permite especificar un archivo de salida para el plan. El uso del parámetro -out garantiza que el plan que ha revisado es exactamente lo que se aplica.

2. Ejecute terraform apply para aplicar el plan de ejecución.

   terraform apply main.destroy.tfplan
   

Solución de problemas de Terraform en Azure

Solución de problemas comunes al usar Terraform en Azure

Pasos siguientes