Procedimiento para consultar un objeto ArrayList con LINQ (Visual Basic)

  • Artículo

Cuando use LINQ para consultar colecciones no genéricas IEnumerable como ArrayList, debe declarar explícitamente el tipo de variable de rango para reflejar el tipo específico de los objetos de la colección. Por ejemplo, si tiene una ArrayList de objetos Student, la cláusula from debe tener un aspecto similar a este:

Dim query = From student As Student In arrList
'...

Al especificar el tipo de la variable de rango, se convierte cada elemento de la ArrayList en un Student.

El uso de una variable de rango con tipo explícito en una expresión de consulta es equivalente a llamar al método Cast. Cast genera una excepción si la conversión especificada no puede realizarse. Cast y OfType son los dos métodos de operador de consulta estándar que funcionan en tipos IEnumerable no genéricos. En Visual Basic, debe llamar explícitamente al método Cast en el origen de datos para garantizar un tipo de variable de rango específico. Para más información, consulte Relaciones entre tipos en operaciones de consulta (Visual Basic).

Ejemplo

En el siguiente ejemplo se muestra una consulta simple sobre un ArrayList. Tenga en cuenta que en este ejemplo se usan inicializadores de objeto cuando el código llama al método Add, pero esto no es un requisito.

Imports System.Collections
Imports System.Linq

Module Module1

    Public Class Student
        Public Property FirstName As String
        Public Property LastName As String
        Public Property Scores As Integer()
    End Class

    Sub Main()

        Dim student1 As New Student With {.FirstName = "Svetlana",
                                     .LastName = "Omelchenko",
                                     .Scores = New Integer() {98, 92, 81, 60}}
        Dim student2 As New Student With {.FirstName = "Claire",
                                    .LastName = "O'Donnell",
                                    .Scores = New Integer() {75, 84, 91, 39}}
        Dim student3 As New Student With {.FirstName = "Cesar",
                                    .LastName = "Garcia",
                                    .Scores = New Integer() {97, 89, 85, 82}}
        Dim student4 As New Student With {.FirstName = "Sven",
                                    .LastName = "Mortensen",
                                    .Scores = New Integer() {88, 94, 65, 91}}

        Dim arrList As New ArrayList()
        arrList.Add(student1)
        arrList.Add(student2)
        arrList.Add(student3)
        arrList.Add(student4)

        ' Use an explicit type for non-generic collections
        Dim query = From student As Student In arrList
                    Where student.Scores(0) > 95
                    Select student

        For Each student As Student In query
            Console.WriteLine(student.LastName & ": " & student.Scores(0))
        Next
        ' Keep the console window open in debug mode.
        Console.WriteLine("Press any key to exit.")
        Console.ReadKey()
    End Sub

End Module
' Output:
'   Omelchenko: 98
'   Garcia: 97

Vea también