Inicio rápido: Creación e implementación del primer archivo de Bicep con recursos de Microsoft Graph

En este inicio rápido, creará un archivo de Bicep que declara un grupo de seguridad de Microsoft Entra y una identidad de servicio administrada (MSI), que representa un recurso de Microsoft Graph y un recurso de Azure, respectivamente. A continuación, agregue el MSI como propietario del grupo. También aprenderá cómo la extensión de Bicep simplifica el desarrollo al proporcionar seguridad de tipos, validación de sintaxis y autocompletar. Por último, implemente el archivo de Bicep mediante un usuario que ha iniciado sesión.

Requisitos previos

• Tener una suscripción de Azure válida : si no posee una suscripción de Azure, cree una cuenta gratuita antes de comenzar.

• Instale las herramientas de Bicep para crear e implementar. En este inicio rápido se usa VS Code con la extensión de Bicep para la creación y la CLI de Azure para la implementación. También se proporcionan ejemplos para Azure PowerShell. La versión mínima necesaria de Bicep es v0.30.3.

• Tener un rol de Microsoft Entra que le asigne permisos para crear un grupo de seguridad. Los usuarios tienen este permiso de forma predeterminada. Sin embargo, los administradores pueden desactivar este valor predeterminado en cuyo caso es necesario asignar al menos el rol Administrador de grupos.

Adición de un grupo de aplicaciones de Microsoft Graph

Inicie VS Code y cree dos nuevos archivos, main.bicep y bicepconfig.json en la misma carpeta.

A continuación, para poder declarar recursos de Microsoft Graph en un archivo de Bicep, debe habilitar la característica de vista previa de Bicep y especificar las versiones de tipo de Bicep de Microsoft Graph mediante la configuración de bicepconfig.json.

En este ejemplo se usan los recursos v1.0 y se declara un nombre de extensión descriptivo "microsoftGraphV1_0" para hacer referencia a la versión de br:mcr.microsoft.com/bicep/extensions/microsoftgraph/v1.0:0.1.8-preview tipo en el Registro de artefactos Microsoft.

{
    "experimentalFeaturesEnabled": {
        "extensibility": true
    },
    // specify an alias for the version of the v1.0 dynamic types package you want to use
    "extensions": {
      "microsoftGraphV1_0": "br:mcr.microsoft.com/bicep/extensions/microsoftgraph/v1.0:0.1.8-preview"
    }
}

También puede declarar recursos de Microsoft Graph desde la versión beta y v1.0 en el mismo archivo de Bicep agregando otra referencia a una versión de tipo beta de la Registro de artefactos Microsoft.

En main.bicep, escriba extension microsoftGraphV1_0, donde microsoftGraphV1_0 es el nombre descriptivo para hacer referencia al paquete de tipos dinámicos en el Registro de artefactos Microsoft. La extension instrucción permite al compilador de Bicep saber que incluye los tipos de Microsoft Graph definidos en bicepconfig.json. En la línea siguiente, defina un recurso mediante la resource palabra clave . Escriba resource exampleGroup y agregue un espacio.

extension microsoftGraphV1_0

resource exampleGroup

Al agregar un espacio después del nombre simbólico, se muestra una lista de tipos de recursos. Continúe escribiendo grupo hasta que pueda seleccionar Microsoft.Graph/Groups en las opciones disponibles.

Después de seleccionar Microsoft.Graph/Groups, se le muestran las versiones de API disponibles: beta o v1.0. Seleccione siempre la versión 1.0 a menos que no esté disponible o las propiedades de recursos que necesita solo estén disponibles en la versión beta. Para este inicio rápido, use v1.0.

Después de la comilla simple del tipo de recurso, agregue = y un espacio. Se mostrarán las opciones para agregar propiedades al recurso. Seleccione required-properties.

Esta opción agrega todas las propiedades del tipo de recurso que son obligatorias para la implementación. Después de seleccionar esta opción, el grupo tiene las siguientes propiedades:

resource exampleGroup 'Microsoft.Graph/groups@v1.0' = {
  displayName: 
  mailEnabled: 
  mailNickname: 
  securityEnabled: 
  uniqueName: 
}

Proporcione valores para esas propiedades, estableciendo mailEnabled en false y securityEnabled en true. uniqueName representa una clave proporcionada por el cliente inmutable para este recurso de grupo.

Adición de un recurso de identidad administrada

VS Code con la extensión de Bicep simplifica el desarrollo proporcionando fragmentos predefinidos, como un fragmento de código que crea una identidad administrada. En main.bicep, escriba man y seleccione res-managed-identity en la lista y presione [TAB] o [ENTRAR].

Nota: Actualmente no se admiten fragmentos de recursos para recursos extensibles , como los recursos de Microsoft Graph.

El archivo Bicep ahora contiene el código siguiente:

resource managedIdentity 'Microsoft.ManagedIdentity/userAssignedIdentities@2018-11-30' = {
  name: 'name'
  location: location
}

Puede corregir el error de definición de parámetro que falta agregando una definición de parámetro para location. En la definición de extensión, agregue param location string = resourceGroup().location. Para obtener más información sobre la función que se usa aquí, consulte resourceGroup(). Cambie el nombre de la identidad administrada de name a exampleManagedIdentity.

Convertir la identidad administrada en propietario del recurso de grupo

En el exampleGroup recurso, cree una nueva línea en uniqueName, escriba ow, que muestra a los propietarios como la única opción de propiedad coincidente y, a continuación, presione [TAB] o [ENTRAR].

La propiedad owners es una matriz, por lo que agregue [] y haga referencia ahora al identificador de entidad de seguridad de la identidad administrada mediante intellisense, escribiendo m y seleccionando managedIdentity (el nombre simbólico de la identidad administrada), escribiendo una propiedad . y seleccionando otras propiedades . y picking principalId.

Su archivo main.bicep debería tener ahora un aspecto similar al siguiente:

extension microsoftGraphV1_0

param location string = resourceGroup().location

resource exampleGroup 'Microsoft.Graph/groups@v1.0' = {
  displayName: 'My example group'
  mailEnabled: false
  mailNickname: 'my-example-group'
  securityEnabled: true
  uniqueName: 'myExampleGroup'
  owners: [managedIdentity.properties.principalId]
}

resource managedIdentity 'Microsoft.ManagedIdentity/userAssignedIdentities@2018-11-30' = {
  name: 'exampleManagedIdentity'
  location: location
}

Implementación del archivo de Bicep mediante un usuario que ha iniciado sesión

Implemente el archivo bicep iniciando sesión en la CLI de Azure o Azure PowerShell con los ejemplos siguientes. En los ejemplos de la CLI de Azure de esta documentación se usa la consola de Bash.

## Sign in to Azure CLI
az login

## Create a resource group
az group create --name exampleRG --location eastus

## Deploy the Bicep file
az deployment group create --resource-group exampleRG --template-file main.bicep

# Sign in to Azure
Connect-AzAccount

New-AzResourceGroup -Name exampleRG -Location eastus

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep

Una vez finalizada la implementación, debería mostrarse un mensaje indicando que la implementación se realizó correctamente.

Limpieza de recursos

Cuando los recursos de Azure dejen de ser necesarios, use la CLI de Azure o el módulo de Azure PowerShell para eliminar el grupo de recursos y el recurso del servidor del inicio rápido.

En los ejemplos siguientes se muestran comandos para eliminar primero el recurso de Azure y el recurso de Microsoft Graph mediante la CLI de Azure y Azure PowerShell.

## Delete the resource group
az group delete --name exampleRG

## Delete the Microsoft Graph group
az rest --method delete --url 'https://graph.microsoft.com/v1.0/groups%28uniqueName=%27myExampleGroup%27%29'

Remove-AzResourceGroup -Name exampleRG

$uri = 'https://graph.microsoft.com/v1.0/groups%28uniqueName=%27myExampleGroup%27%29'
Invoke-AzRestMethod -Uri $Uri -Method Delete

Paso siguiente