Descripción de fórmulas para contar las apariciones de texto, caracteres y palabras en Excel
Resumen
Este artículo contiene y describe fórmulas que calculan lo siguiente:
- El número de apariciones de una cadena de texto en un rango de celdas.
- El número de apariciones de un carácter en una celda.
- El número de apariciones de un carácter en un rango de celdas.
- El número de palabras (o cadenas de texto) separadas por un carácter en una celda.
Más información
Fórmula para contar el número de apariciones de una cadena de texto en un rango
=SUM(LEN(rango)-LEN(SUBSTITUTE(rango,"texto","")))/LEN("texto")
En la que rango es el rango de celdas en cuestión y "texto" debe reemplazarse por la cadena de texto específica que desea contar.
Nota:
La fórmula anterior debe introducirse como una fórmula de matriz. Para introducir una fórmula como una matriz en Excel para Windows, presione CTRL+MAYÚS+ENTRAR. Para introducir una fórmula como una matriz en Excel para Macintosh, presione COMANDO+RETORNO.
La fórmula debe dividirse por la longitud de la cadena de texto, ya que la suma de la longitud de caracteres del rango se reduce en un múltiplo de cada aparición de la cadena de texto. Esta fórmula puede reemplazar todas las fórmulas posteriores de este artículo, excepto la fórmula para contar el número de palabras de una celda.
Ejemplo 1: Contar el número de apariciones de una cadena de texto en un rango
Inicie Excel y abra un nuevo libro.
Escriba lo siguiente en Hoja1:
A1: Fruit A2: apple,apple A3: orange A4: apple,orange A5: grape A6: orange,grape A7: grape, apple A8: =SUM(LEN(A2:A7)-LEN(SUBSTITUTE(A2:A7,"apple","")))/LEN("apple")El valor de la celda A8 es 4 porque el texto "apple" aparece cuatro veces en el rango.
Fórmula para contar el número de apariciones de un solo carácter en una celda
=LEN(cell_ref)-LEN(SUBSTITUTE(cell_ref,"a",""))
En la fórmula, cell_ref es la referencia de celda y "a" debe reemplazarse por el carácter que desee contar.
Nota:
No es necesario introducir esta fórmula como una fórmula de matriz.
Ejemplo 2: Contar el número de apariciones de un carácter en una celda
Utilice los mismos datos del ejemplo anterior; pongamos que desea contar el número de apariciones del carácter "p" en A7. Escriba la fórmula siguiente en la celda A9:
A9: =LEN(A7)-LEN(SUBSTITUTE(A7,"p",""))
El valor de la celda A9 es 3 porque el carácter "p" aparece tres veces en A7.
Fórmula para contar el número de apariciones de un solo carácter en un rango
=SUM(LEN(rango)-LEN(SUBSTITUTE(rango,"a","")))
En esta fórmula, rango es el rango de celdas en cuestión, y "a" debe reemplazarse por el carácter que desee contar.
Nota:
La fórmula anterior debe introducirse como una fórmula de matriz. Para introducir una fórmula como una fórmula de matriz en Excel, presione CTRL+MAYÚS+ENTRAR.
Ejemplo 3: Contar el número de apariciones de un carácter en un rango
Utilice los mismos datos del ejemplo anterior; pongamos que desea contar el número de apariciones del carácter "p" en A2:A7. Escriba la fórmula siguiente en la celda A10:
A10: =SUM(LEN(A2:A7)-LEN(SUBSTITUTE(A2:A7,"p","")))
Nota:
La fórmula anterior debe introducirse como una fórmula de matriz. Para introducir una fórmula como una fórmula de matriz en Excel, presione CTRL+MAYÚS+ENTRAR.
El valor de la celda A10 es 11 porque el carácter "p" aparece 11 veces en A2:A7.
Fórmula para contar el número de palabras separadas por un carácter en una celda
=IF(LEN(TRIM(cell_ref))=0,0,LEN(cell_ref)-LEN(SUBSTITUTE(cell_ref,car,""))+1)
En esta fórmula, cell_ref es la referencia de celda y car es el carácter que separa las palabras.
Nota:
La fórmula anterior no tiene espacios; se utilizan varias líneas solamente para adaptar la fórmula al documento. No incluya espacios cuando escriba la fórmula en la celda. No es necesario introducir esta fórmula como una fórmula de matriz.
Ejemplo 4: Contar el número de palabras separadas por un espacio en una celda
Para contar el número de palabras separadas por un carácter de espacio en una celda, siga estos pasos:
Inicie Excel y abra un nuevo libro.
Escriba lo siguiente en Hoja1:
A1: The car drove fast A2: =IF(LEN(TRIM(A1))=0,0,LEN(TRIM(A1))-LEN(SUBSTITUTE(A1," ",""))+1)
La fórmula de la celda A2 devuelve un valor de 4, lo que indica que la cadena contiene cuatro palabras separadas por espacios. No es un problema si las palabras están separadas por varios espacios o si comienzan o terminan en un espacio. La función TRIM quita los caracteres de espacio adicional y los caracteres de espacio inicial y final en el texto de la celda.
En Excel, también puede usar una macro para contar las apariciones de un carácter específico en una celda o rango de celdas.
Referencias
Para obtener información adicional sobre cómo contar las apariciones de un texto, haga clic en el número de artículo siguiente para verlo en Microsoft Knowledge Base:
89794 Cómo usar Visual Basic para Aplicaciones para contar las apariciones de un carácter en una selección de Excel