Tutorial: Subprocesamiento múltiple

Actualización: Julio de 2008

En este tutorial se muestra cómo crear aplicaciones multiproceso que buscan en archivos de texto las apariciones de palabras. Explica cómo:

• Definir una clase con un método al que puede llamar el componente BackgroundWorker.

• Controlar eventos iniciados por el componente BackgroundWorker.

• Iniciar un componente BackgroundWorker para ejecutar un método.

• Implementar un botón Cancel que detiene el componente BackgroundWorker.

Para generar el ejemplo de código para este tema

1. Abra un nuevo proyecto de aplicación para Windows de Visual Basic y cree un formulario llamado Form1.

2. Agregue dos botones y cuatro cuadros de texto a Form1.

3. Dé nombre a los objetos como se muestra en la tabla siguiente.

   Objeto	Propiedad	Valor
   Primer botón	Name, Text	Start, Start
   Segundo botón	Name, Text	Cancel, Cancel
   Primer cuadro de texto	Name, Text	SourceFile, ""
   Segundo cuadro de texto	Name, Text	CompareString, ""
   Tercer cuadro de texto	Name, Text	WordsCounted, "0"
   Cuarto cuadro de texto	Name, Text	LinesCounted, "0"

4. Agregue una etiqueta a cada cuadro de texto. Establezca la propiedad Text de cada etiqueta como se muestra en la tabla siguiente.

   Objeto	Propiedad	Valor
   Primera etiqueta	Text	Source File
   Segunda etiqueta	Text	Compare String
   Tercera etiqueta	Text	Matching Words
   Cuarta etiqueta	Text	Lines Counted

5. Agregue a su formulario un componente BackgroundWorker desde la sección Componentes del Cuadro de herramientas. Aparecerá en la bandeja de componentes del formulario.

6. Establezca las siguientes propiedades para el objeto BackgroundWorker1.

   Propiedad	Valor
   WorkerReportsProgress	True
   WorkerSupportsCancellation	True

Para definir el método que se ejecutará en un subproceso aparte

1. En el menú Proyecto, elija Agregar clase para agregar una clase al proyecto. Se abrirá el cuadro de diálogo Agregar nuevo elemento.

2. En la ventana de plantillas, seleccione Clase y escriba Words.vb en el campo de nombre.

3. Haga clic en Agregar. Se muestra la clase Words.

4. Agregue una instrucción Option Compare al principio de la clase Words, encima de la instrucción Class:

   Option Compare Text ' Case insensitive search.
   ' Use Option Compare Binary for case sensitive search.
   

5. Agregue el código siguiente a la clase Words:

   Public Class Words
       ' Object to store the current state, for passing to the caller.
       Public Class CurrentState
           Public LinesCounted As Integer
           Public WordsMatched As Integer
       End Class
   
       Public SourceFile As String
       Public CompareString As String
       Private WordCount As Integer = 0
       Private LinesCounted As Integer = 0
   
       Public Sub CountWords( _
           ByVal worker As System.ComponentModel.BackgroundWorker, _
           ByVal e As System.ComponentModel.DoWorkEventArgs _
       )
           ' Initialize the variables.
           Dim state As New CurrentState
           Dim myStream As System.IO.StreamReader = Nothing
           Dim line = ""
           Dim elapsedTime = 20
           Dim lastReportDateTime = Now
   
           If CompareString Is Nothing Or _
                   CompareString = System.String.Empty Then
               Throw New Exception("CompareString not specified.")
           End If
   
           Try
               ' Open a new stream.
               myStream = My.Computer.FileSystem.OpenTextFileReader(SourceFile)
               ' Do while there are lines remaining in the file to be read.
               Do While Not myStream.EndOfStream
                   If worker.CancellationPending Then
                       e.Cancel = True
                       Exit Do
                   Else
                       line = myStream.ReadLine
                       WordCount += CountInString(line, CompareString)
                       LinesCounted += 1
   
                       ' Raise an event so the form can monitor progress.
                       If Now > lastReportDateTime.AddMilliseconds(elapsedTime) Then
                           state.LinesCounted = LinesCounted
                           state.WordsMatched = WordCount
                           worker.ReportProgress(0, state)
                           lastReportDateTime = Now.AddMilliseconds(elapsedTime)
                       End If
                   End If
               Loop
   
               ' Report the final count values.
               state.LinesCounted = LinesCounted
               state.WordsMatched = WordCount
               worker.ReportProgress(0, state)
           Finally
               If myStream IsNot Nothing Then
                   ' Close the file.
                   myStream.Close()
               End If
           End Try
       End Sub
   
       Private Function CountInString( _
           ByVal SourceString As String, _
           ByVal CompareString As String _
       ) As Integer
           ' This function counts the number of times
           ' a word is found in a line.
           If SourceString Is Nothing Then
               Return 0
           End If
   
           Dim regex As New System.Text.RegularExpressions.Regex( _
               System.Text.RegularExpressions.Regex.Escape(CompareString))
           Dim matches As System.Text.RegularExpressions.MatchCollection
           matches = regex.Matches(SourceString)
           Return matches.Count
       End Function
   End Class
   

Para tratar eventos desde el subproceso

• Agregue los controladores de eventos siguientes a su formulario principal.

  Private Sub BackgroundWorker1_RunWorkerCompleted( _
      ByVal sender As Object, _
      ByVal e As System.ComponentModel.RunWorkerCompletedEventArgs) _
      Handles BackgroundWorker1.RunWorkerCompleted
  
      ' This event handler is called when the background thread finishes.
      ' This method runs on the main thread.
  
      If e.Error IsNot Nothing Then
          MsgBox("Error: " & e.Error.Message)
      ElseIf e.Cancelled Then
          MsgBox("Word counting canceled.")
      Else
          MsgBox("Finished counting words.")
      End If
  End Sub
  
  Private Sub BackgroundWorker1_ProgressChanged( _
      ByVal sender As Object, _
      ByVal e As System.ComponentModel.ProgressChangedEventArgs) _
      Handles BackgroundWorker1.ProgressChanged
  
      ' This event handler is called after the background thread
      ' reads a line from the source file.
      ' This method runs on the main thread.
  
      Dim state As Words.CurrentState = _
          CType(e.UserState, Words.CurrentState)
      Me.LinesCounted.Text = state.LinesCounted.ToString
      Me.WordsCounted.Text = state.WordsMatched.ToString
  End Sub
  

Para iniciar y llamar a un nuevo subproceso que ejecuta el método WordCount

1. Agregue a su programa el procedimiento siguiente:

   Private Sub BackgroundWorker1_DoWork( _
       ByVal sender As Object, _
       ByVal e As System.ComponentModel.DoWorkEventArgs) _
       Handles BackgroundWorker1.DoWork
   
       ' This event handler is where the actual work is done.
       ' This method runs on the background thread.
   
       ' Get the BackgroundWorker object that raised this event.
       Dim worker As System.ComponentModel.BackgroundWorker
       worker = CType(sender, System.ComponentModel.BackgroundWorker)
   
       ' Get the Works object and call the main method.
       Dim WC As Words = CType(e.Argument, Words)
       WC.CountWords(worker, e)
   End Sub
   
   Sub StartThread()
       ' This method runs on the main thread.
   
       Me.WordsCounted.Text = "0"
   
       ' Initialize the object that the background worker calls.
       Dim WC As New Words
       WC.CompareString = Me.CompareString.Text
       WC.SourceFile = Me.SourceFile.Text
   
       ' Start the asynchronous operation.
       BackgroundWorker1.RunWorkerAsync(WC)
   End Sub
   

2. Llame al método StartThread desde el botón Start del formulario:

   Private Sub Start_Click( _
       ByVal sender As System.Object, _
       ByVal e As System.EventArgs) _
       Handles Start.Click
   
       StartThread()
   End Sub
   

Para implementar el botón Cancel que detiene el subproceso

• Llame al procedimiento StopThread desde el controlador de evento Click para el botón Cancel.

  Private Sub Cancel_Click( _
      ByVal sender As System.Object, _
      ByVal e As System.EventArgs) _
      Handles Cancel.Click
  
      ' Cancel the asynchronous operation.
      Me.BackgroundWorker1.CancelAsync()
  End Sub
  

Pruebas

Ahora puede probar la aplicación para asegurarse de que funciona correctamente.

Para probar la aplicación

1. Presione F5 para ejecutar la aplicación.

2. Cuando se muestre el formulario, escriba la ruta de acceso al archivo que desea probar en el cuadro sourceFile. Por ejemplo, suponiendo que el nombre del archivo de prueba es Prueba.txt, escriba C:\Prueba.txt.

3. En el segundo cuadro de texto, escriba una palabra o frase para que la aplicación la busque en el archivo de texto.

4. Haga clic en el botón Start. El botón LinesCounted empezará a incrementar inmediatamente. La aplicación mostrará el mensaje "Finished Counting" cuando termine.

Para comprobar el botón Cancel

1. Presione F5 para iniciar la aplicación y escriba el nombre de archivo y la palabra de búsqueda como se describe en el procedimiento anterior. Asegúrese de que el archivo que elige es lo suficientemente grande para que le dé tiempo a cancelar el procedimiento antes de que termine.

2. Haga clic en el botón Start para iniciar la aplicación.

3. Haga clic en el botón Cancel. La aplicación parará de contar inmediatamente.

Pasos siguientes

Esta aplicación contiene algunos ejemplos de control básico de errores. Detecta las cadenas de búsqueda en blanco. Puede ampliar este programa tratando otros errores, como la superación del número máximo de palabras o líneas que se pueden contabilizar.

Vea también

Tareas

Tutorial: Crear un componente sencillo con múltiples procesos en Visual Basic

Otros recursos

Subprocesamiento múltiple en Visual Basic

Historial de cambios