Type.Attributes Property

Property Value

Type: System.Reflection.TypeAttributes
A TypeAttributes object representing the attribute set of the Type, unless the Type represents a generic type parameter, in which case the value is unspecified.

Imports System.Reflection

Friend Structure S
    Public X As Integer
End Structure

Public MustInherit Class Example

    Protected NotInheritable Class NestedClass
    End Class

    Public Interface INested
    End Interface

    Private Shared outputBlock As System.Windows.Controls.TextBlock

    Public Shared Sub Demo(ByVal outputBlock As System.Windows.Controls.TextBlock)

        Example.outputBlock = outputBlock

        DisplayAttributes(GetType(Example))
        DisplayAttributes(GetType(NestedClass))
        DisplayAttributes(GetType(INested))
        DisplayAttributes(GetType(S))

    End Sub

    Private Shared Sub DisplayAttributes(ByVal t As Type)

        outputBlock.Text &= "Attributes for type " & t.Name & ":" & vbLf

        Dim attr As TypeAttributes = t.Attributes

        ' To test for visibility attributes, you must use the visibility
        ' mask.
        Dim visibility As TypeAttributes = attr And TypeAttributes.VisibilityMask
        Select Case visibility
            Case TypeAttributes.NotPublic:
                outputBlock.Text &= "   ...is not Public" & vbLf
            Case TypeAttributes.Public:
                outputBlock.Text &= "   ...is Public" & vbLf
            Case TypeAttributes.NestedPublic:
                outputBlock.Text &= "   ...is nested and Public" & vbLf
            Case TypeAttributes.NestedPrivate:
                outputBlock.Text &= "   ...is nested and Private" & vbLf
            Case TypeAttributes.NestedFamANDAssem:
                outputBlock.Text &= "   ...is nested, and inheritable only within the assembly" & _
                   vbLf & "         (cannot be declared in Visual Basic)" & vbLf
            Case TypeAttributes.NestedAssembly:
                outputBlock.Text &= "   ...is nested and Friend" & vbLf
            Case TypeAttributes.NestedFamily:
                outputBlock.Text &= "   ...is nested and Protected" & vbLf
            Case TypeAttributes.NestedFamORAssem:
                outputBlock.Text &= "   ...is nested and Protected Friend" & vbLf
        End Select

        Dim layout As TypeAttributes = attr And TypeAttributes.LayoutMask
        Select Case layout
            Case TypeAttributes.AutoLayout:
                outputBlock.Text &= "   ...is AutoLayout" & vbLf
            Case TypeAttributes.SequentialLayout:
                outputBlock.Text &= "   ...is SequentialLayout" & vbLf
            Case TypeAttributes.ExplicitLayout:
                outputBlock.Text &= "   ...is ExplicitLayout" & vbLf
        End Select

        Dim classSemantics As TypeAttributes = attr And TypeAttributes.ClassSemanticsMask
        Select Case classSemantics
            Case TypeAttributes.Class:
                If t.IsValueType Then
                    outputBlock.Text &= "   ...is a value type" & vbLf
                Else
                    outputBlock.Text &= "   ...is a class" & vbLf
                End If
            Case TypeAttributes.Interface:
                outputBlock.Text &= "   ...is an interface" & vbLf
        End Select

        If 0 <> (attr And TypeAttributes.Abstract) Then _
            outputBlock.Text &= "   ...is MustInherit" & vbLf

        If 0 <> (attr And TypeAttributes.Sealed) Then _
            outputBlock.Text &= "   ...is NotInheritable" & vbLf
   End Sub 
End Class 

' This example produces the following output:
'
'Attributes for type Example:
'    ...is Public
'    ...is AutoLayout
'    ...is a class
'    ...is MustInherit
'Attributes for type NestedClass:
'    ...is nested and Protected
'    ...is AutoLayout
'    ...is a class
'    ...is NotInheritable
'Attributes for type INested:
'    ...is nested and Public
'    ...is AutoLayout
'    ...is an interface
'    ...is MustInherit
'Attributes for type S:
'    ...is not Public
'    ...is SequentialLayout
'    ...is a value type
'    ...is NotInheritable

using System;
using System.Reflection;

internal struct S
{
    public int X;
}

public abstract class Example
{
    protected sealed class NestedClass {}

    public interface INested {}

    private static System.Windows.Controls.TextBlock outputBlock;

    public static void Demo(System.Windows.Controls.TextBlock outputBlock)
    {
        Example.outputBlock = outputBlock;

        DisplayAttributes(typeof(Example));
        DisplayAttributes(typeof(NestedClass));
        DisplayAttributes(typeof(INested));
        DisplayAttributes(typeof(S));
    }

    private static void DisplayAttributes(Type t)
    {
        outputBlock.Text += "Attributes for type "+t.Name+":\n";

        TypeAttributes attr = t.Attributes;

        // To test for visibility attributes, you must use the visibility
        // mask.
        TypeAttributes visibility = attr & TypeAttributes.VisibilityMask;
        switch (visibility)
        {
            case TypeAttributes.NotPublic:
                outputBlock.Text += "   ...is not public\n";
                break;
            case TypeAttributes.Public:
                outputBlock.Text += "   ...is public\n";
                break;
            case TypeAttributes.NestedPublic:
                outputBlock.Text += "   ...is nested and public\n";
                break;
            case TypeAttributes.NestedPrivate:
                outputBlock.Text += "   ...is nested and private\n";
                break;
            case TypeAttributes.NestedFamANDAssem:
                outputBlock.Text += "   ...is nested, and inheritable only within the assembly" +
                   "\n         (cannot be declared in C#)\n";
                break;
            case TypeAttributes.NestedAssembly:
                outputBlock.Text += "   ...is nested and internal\n";
                break;
            case TypeAttributes.NestedFamily:
                outputBlock.Text += "   ...is nested and protected\n";
                break;
            case TypeAttributes.NestedFamORAssem:
                outputBlock.Text += "   ...is nested and protected internal\n";
                break;
        }

        TypeAttributes layout = attr & TypeAttributes.LayoutMask;
        switch (layout)
        {
            case TypeAttributes.AutoLayout:
                outputBlock.Text += "   ...is AutoLayout\n";
                break;
            case TypeAttributes.SequentialLayout:
                outputBlock.Text += "   ...is SequentialLayout\n";
                break;
            case TypeAttributes.ExplicitLayout:
                outputBlock.Text += "   ...is ExplicitLayout\n";
                break;
        }

        TypeAttributes classSemantics = attr & TypeAttributes.ClassSemanticsMask;
        switch (classSemantics)
        {
            case TypeAttributes.Class:
                if (t.IsValueType)
                {
                    outputBlock.Text += "   ...is a value type\n";
                }
                else
                {
                    outputBlock.Text += "   ...is a class\n";
                }
                break;
            case TypeAttributes.Interface:
                outputBlock.Text += "   ...is an interface\n";
                break;
        }

        if (0!=(attr & TypeAttributes.Abstract)) 
        {
            outputBlock.Text += "   ...is abstract\n";
        }

        if (0!=(attr & TypeAttributes.Sealed)) 
        {
            outputBlock.Text += "   ...is sealed\n";
        }
    }
}

/* This example produces the following output:

Attributes for type Example:
    ...is public
    ...is AutoLayout
    ...is a class
    ...is abstract
Attributes for type NestedClass:
    ...is nested and protected
    ...is AutoLayout
    ...is a class
    ...is sealed
Attributes for type INested:
    ...is nested and public
    ...is AutoLayout
    ...is an interface
    ...is abstract
Attributes for type S:
    ...is not public
    ...is SequentialLayout
    ...is a value type
    ...is sealed
 */