Requêtes pour la table ACSCallRecordingSummary

Article
11/05/2024

Pour plus d’informations sur l’utilisation de ces requêtes dans le Portail Azure, consultez le didacticiel Log Analytics. Pour l’API REST, consultez Requête.

Histogramme de durée de l’enregistrement des appels

Produit un histogramme des durées d’enregistrement des appels en secondes.

ACSCallRecordingSummary
| distinct RecordingId, RecordingLength
// Count call duration bins (60 second intervals)
| summarize duration_counts=count() by bin(RecordingLength, 6000)
| order by RecordingLength asc
| render columnchart with (xcolumn = RecordingLength, title="Recording duration histogram")

Centiles de durée d’enregistrement des appels

Calcule la durée moyenne de l’enregistrement des appels en secondes, ainsi que les centiles de durée d’appel de 50 %, 90 % et 99 %.

ACSCallRecordingSummary
// Get the distinct combinations of RecordingId, RecordingLength
| distinct RecordingId, RecordingLength
// Calculate average and percentiles (50%, 90%, and 99%) of call durations (in seconds)
| summarize avg(RecordingLength), percentiles(RecordingLength, 50, 90, 99)

Taux de raison de fin de l’enregistrement d’appel

Produit un graphique en secteurs de la proportion de la raison de fin de l’enregistrement des appels.

ACSCallRecordingSummary
// Count distinct calls (dcount(CorrelationId)) per call type
| summarize call_types=dcount(RecordingId) by RecordingEndReason
| render piechart title="Recording End Reason Ratio"

Enregistrements d’appels quotidiens

Produit un histogramme des enregistrements effectués par jour dans la semaine dernière.

ACSCallRecordingSummary
// To filter out recordings made over a week ago, uncomment the next line
// | where TimeGenerated > ago(7d)
// Get the distinct combinations of RecordingId and CallStartTime
| distinct RecordingId, TimeGenerated
// Adds a new column with the call start day
| extend day = floor(TimeGenerated, 1d)
// Count the number of calls per day
| summarize event_count=count() by day
| sort by day asc
| render columnchart title="Number of recordings per day"

Enregistrements d’appels horaires

Produit un histogramme des enregistrements effectués par heure au cours du dernier jour.

    ACSCallRecordingSummary
    // To filter out recordings made over a day ago, uncomment the next line
    | where TimeGenerated > ago(1d)
    // Get the distinct combinations of RecordingId and TimeGenerated
    | distinct RecordingId, TimeGenerated
    // Adds a new column with the call start hour
    | extend hour = floor(TimeGenerated, 1h)
    // Count the number of calls per hour
    | summarize event_count=count() by hour
    | sort by hour asc
    | render columnchart title="Number of recordings per hour in last day"

Taux de mode de l’enregistrement d’appel

Produit un graphique en secteurs de la proportion des modes d’enregistrement (types de contenu/format).

ACSCallRecordingSummary
| summarize count() by ContentType, FormatType
| extend ContentFormat = strcat(ContentType, "/", FormatType)
| project ContentFormat, count_
| render piechart title="Recording by mode (content/format types)"

Partager via