Requêtes pour la table ASCDeviceEvents

Article
11/05/2024

Pour plus d’informations sur l’utilisation de ces requêtes dans le Portail Azure, consultez le didacticiel Log Analytics. Pour l’API REST, consultez Requête.

Échecs d’authentification et d’attestation des appareils Azure Sphere

Liste des échecs d’authentification et d’attestation des appareils Azure Sphere pour la semaine dernière, triées par heure.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and
        Properties.EventType == "DeviceAttestationFailure" or Properties.EventType == "DeviceCertificateEvent" and
        ResultType == "Failure" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| project TimeGenerated, DeviceId, Properties, ResultDescription, Location
| sort by TimeGenerated desc
| limit 100

Chronologie des événements d’appareil Azure Sphere

Chronologie triée de tous les événements générés par un appareil Azure Sphere au cours de la dernière semaine, pour surveiller et résoudre les défaillances inattendues.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" or Properties.DeviceTelemetryEventCategory == "AppCrash" // Remove/Add filters to see all/specific events. Filter data by Device by adding " | where DeviceId == "Your Device ID" " 
| project TimeGenerated, OperationName, ResultType, ResultDescription, Properties, Location
| sort by TimeGenerated desc
| limit 100

Organigramme des événements de pulsation d’appareil Azure Sphere

Organigramme de tous les événements de génération de certificats initiés par les appareils Azure Sphere au cours de la semaine dernière, pour surveiller en permanence l’intégrité des appareils et voir les tendances.

let Interval = timespan(1d); // Interval for the Chart 
ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and 
        Properties.EventType == "DeviceCertificatesGenerate" and 
        ResultType == "Success"
| summarize Device_Heartbeat_Events=count() by bin(TimeGenerated, Interval)
| render timechart

Appareils Azure Sphere non mis à jour vers le système d’exploitation le plus récent

Liste des appareils Azure Sphere qui n’ont pas été mis à jour vers la dernière version du système d’exploitation au cours de la semaine dernière.

ASCDeviceEvents
| where OperationName == "DeviceUpdateEvent" and  
        todouble(Properties.InstalledOSVersion) != todouble(Properties.TargetedOSVersion) // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize by DeviceId
| limit 100

Résumé des événements de télémétrie des appareils Azure Sphere

Graphique en secteurs récapitunant le partage de chacune des catégories d’événements générées par les appareils Azure Sphere au cours de la semaine dernière, pour surveiller l’intégrité globale des appareils.

ASCDeviceEvents
| where OperationName == "DeviceTelemetryEvent" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize count() by tostring(Properties.DeviceTelemetryEventCategory)
| render piechart

Partager via