Requêtes pour la table VIAudit

  • Article

Pour plus d’informations sur l’utilisation de ces requêtes dans le Portail Azure, consultez le didacticiel Log Analytics. Pour l’API REST, consultez Requête.

Video Indexer Audit by account ID

Afficher les événements d’audit pour le compte (AccountId = <ID> guid), avec un filtre facultatif par UPN utilisateur.

VIAudit
| where AccountId == "<AccountId>"  // please fill in the accountId <Guid>
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| limit 100

Video Indexer Audit top 10 utilisateurs par opérations

Afficher l’organigramme des 10 premiers utilisateurs par opérations, avec un ID de compte facultatif pour le filtrage.

// Trend of top 10 active Upn's
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where TimeGenerated > ago(30d)
| summarize count() by Upn
| top 10 by count_ desc
| project Upn
| join (VIAudit
| where TimeGenerated > ago(30d)
| summarize count() by Upn, bin(TimeGenerated,1d)) on Upn
| project TimeGenerated, Upn, count_
| render timechart

Message d’erreur analysé par Video Indexer Audit

Afficher les événements d’audit ayant échoué avec un ID de compte facultatif pour le filtrage.

// Project failures with detailed error message.
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where  Status == "Failure"
| parse Description with "ErrorType: " ErrorType ". Message: " ErrorMessage ". Trace" *
| project TimeGenerated, OperationName, ErrorMessage, ErrorType, CorrelationId, _ResourceId

Échec des opérations d’audit Video Indexer

Affichez les journaux d’audit de toutes les tentatives d’opérations ayant échoué, avec un filtre facultatif par ID de compte et UPN utilisateur.

VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| where Status == "Failure"
| limit 100