Requêtes pour la table WVDConnectionNetworkData

Article
11/05/2024

Pour plus d’informations sur l’utilisation de ces requêtes dans le Portail Azure, consultez le didacticiel Log Analytics. Pour l’API REST, consultez Requête.

Durée moyenne des allers-retours au fil du temps

Affichez un graphique de temps d’aller-retour (en millisecondes) sur toutes les connexions de 10 minutes à intervalles au 10e, au 50e et au 90e centiles.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Moyenne BW sur toutes les connexions

Affiche un graphique de bande passante (en kilo-octets par seconde) sur toutes les connexions de plus de 10 minutes d’intervalles au 10e, au 50e et au 90e centiles.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

10 premiers utilisateurs ayant le temps d’aller-retour le plus élevé

Retourne la liste des 10 premiers utilisateurs ayant le temps moyen moyen le plus élevé (en millisecondes).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

10 premiers utilisateurs disposant d’une bande passante inférieure

Retourne une liste des 10 premiers utilisateurs avec la bande passante moyenne la plus faible (en kilo-octets par seconde).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Résumé du temps d’aller-retour et de la bande passante

Retourne les 90e centiles pour le temps d’aller-retour (en millisecondes) et la bande passante (en kilo-octets) pour chaque connexion, ainsi que des détails de connexion supplémentaires.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Partager via