Collecter et interroger des données de qualité de connexion

La qualité de la connexion est essentielle pour une bonne expérience utilisateur. Il est donc important de pouvoir surveiller les connexions pour détecter les problèmes potentiels et de résoudre les problèmes à mesure qu’ils se produisent. Azure Virtual Desktop s’intègre à des outils tels que analytique des journaux d'activité qui peuvent vous aider à surveiller l’intégrité des connexions de votre déploiement. Cet article vous explique comment configurer vos paramètres de diagnostic pour vous permettre de collecter des données de qualité de connexion et d’interroger des données pour des paramètres spécifiques.

Prérequis

Pour commencer à collecter des données de qualité de connexion, vous devez configurer un espace de travail Log Analytics à utiliser avec Azure Virtual Desktop.

Configurer les paramètres de diagnostic

Pour vérifier et modifier vos paramètres de diagnostic dans le portail Azure :

1. Connectez-vous au portail Azure, puis accédez à Azure Virtual Desktop et sélectionnez Pools d’hôtes.

2. Sélectionnez le pool d’hôtes pour lequel vous souhaitez collecter les données réseau.

3. Sélectionnez Paramètres de diagnostic, puis créez un nouveau paramètre si vous n’avez pas encore configuré vos paramètres de diagnostic. Si vous avez déjà configuré vos paramètres de diagnostic, sélectionnez Modifier le paramètre.

4. Sélectionnez allLogs si vous souhaitez collecter des données pour toutes les tables. Le paramètre allLogs ajoutera automatiquement de nouvelles tables à votre table de données à l’avenir.

   Si vous préférez afficher des tables plus spécifiques, sélectionnez d’abord Journaux de données réseau et Journaux de données graphiques de connexion en préversion, puis sélectionnez les noms des autres tables que vous souhaitez voir.

5. Sélectionnez l’emplacement où vous souhaitez envoyer les données collectées. Les utilisateurs d’Azure Virtual Desktop Inisghts doivent sélectionner un espace de travail Log Analytics.

6. Sélectionnez Enregistrer pour enregistrer vos modifications.

7. Répétez ce processus pour tous les autres pools d’hôtes que vous souhaitez mesurer.

8. Pour vérifier les données réseau, revenez à la page de ressources du pool d’hôtes, sélectionnez Journaux, puis exécutez une des requêtes de Exemples de requêtes pour Azure Log Analytics. Pour que votre requête puisse obtenir des résultats, votre pool d’hôtes doit avoir des utilisateurs actifs qui se sont auparavant connectés à des sessions. N’oubliez pas qu’il peut falloir jusqu’à 15 minutes pour que les données réseau s’affichent dans le portail Azure.

Exemples de requêtes pour les données réseau Azure Log Analytics

Dans cette section, nous proposons une liste de requêtes qui vous aideront à examiner les informations sur la qualité de la connexion. Vous pouvez exécuter des requêtes dans l’éditeur de requête Log Analytics.

Moyenne de durée RTT et bande passante des requêtes

Pour rechercher la moyenne de durée des boucles et de bande passante :

// 90th, 50th, 10th Percentile for RTT in 10 min increments
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),RTTP50=percentile(EstRoundTripTimeInMs,50),RTTP10=percentile(EstRoundTripTimeInMs,10) by bin(TimeGenerated,10m)
| render timechart
// 90th, 50th, 10th Percentile for BW in 10 min increments
WVDConnectionNetworkData
| summarize BWP90=percentile(EstAvailableBandwidthKBps,90),BWP50=percentile(EstAvailableBandwidthKBps,50),BWP10=percentile(EstAvailableBandwidthKBps,10) by bin(TimeGenerated,10m)
| render timechart

Pour rechercher la durée des boucles et la bande passante par connexion :

// RTT and BW Per Connection Summary
// Returns P90 Round Trip Time (ms) and Bandwidth (KBps) per connection with connection details.
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),BWP90=percentile(EstAvailableBandwidthKBps,90),StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=leftouter (
WVDConnections
| extend Protocol = iff(UdpUse in ("0","<>"),"TCP","UDP")
| distinct CorrelationId, SessionHostName, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion, UserName
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Interroger des données pour un utilisateur spécifique

Pour rechercher la bande passante d’un utilisateur spécifique :

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstAvailableBandwidthKBps, TimeGenerated
| render columnchart  

Pour rechercher la durée du trajet aller-retour pour un utilisateur spécifique :

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
WVDConnections
| distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstRoundTripTimeInMs, TimeGenerated
| render columnchart  

Pour rechercher les 10 premiers utilisateurs avec le temps d’aller-retour le plus élevé :

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=avg(EstRoundTripTimeInMs),RTT_P95=percentile(EstRoundTripTimeInMs,95) by UserName
| top 10 by AvgRTT desc

Pour rechercher les 10 utilisateurs avec la bande passante la plus faible :

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps),BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Étapes suivantes

Pour en savoir plus sur la qualité de la connexion, consultez la rubrique Qualité de la connexion dans Azure Virtual Desktop.