IteratorStateMachineAttribute Classe

Définition

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Héritage

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Attributs

AttributeUsageAttribute SerializableAttribute

Exemples

L’exemple suivant montre comment déterminer si une méthode est une méthode d’itérateur. Dans l’exemple, IsIteratorMethod effectue les étapes suivantes :

• Obtient un MethodInfo objet pour le nom de la méthode à l’aide de Type.GetMethod.

• Obtient un Type objet pour l’attribut à l’aide de l’opérateur GetType.

• Obtient un objet d’attribut pour la méthode et le type d’attribut à l’aide de MethodInfo.GetCustomAttribute. Si GetCustomAttribute retourne Nothing (Visual Basic), la méthode ne contient pas l’attribut.

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Remarques

Vous ne devez pas appliquer l’attribut IteratorStateMachine aux méthodes de votre code. Pour les méthodes en Visual Basic qui ont le modificateur Iterator , le compilateur applique l’attribut IteratorStateMachine dans l’IL qu’il émet.

Lorsqu’une méthode (MethodName) en Visual Basic a le Iterator modificateur, le compilateur émet une structure d’état qui inclut une structure de machine d’état. Cette structure contient le code dans la méthode . Cette il contient également une méthode stub (MethodName) qui appelle l’ordinateur d’état. Le compilateur ajoute l’attribut IteratorStateMachine à la méthode stub afin que les outils puissent identifier l’ordinateur d’état correspondant. Les détails de l’il émis peuvent changer dans les versions ultérieures des compilateurs.

Une méthode d’itérateur effectue une itération personnalisée sur une collection à l’aide de l’instruction Yield (Visual Basic) pour renvoyer chaque élément un par un. Pour plus d'informations, consultez Itérateurs.

Constructeurs

Propriétés

Méthodes

Implémentations d’interfaces explicites

S’applique à

Voir aussi

• AsyncStateMachineAttribute
• StateMachineType