IDENTITY (Fonction) (Transact-SQL)

Syntaxe

IDENTITY (data_type [ , seed , increment ] ) AS column_name

Arguments

• data_type
  Type de données de la colonne d'identité. Tous les types de données de la catégorie de type entier (excepté le type bit) ou le type decimal sont valides pour une colonne d'identité.

• seed
  Entier à affecter à la première ligne de la table. La valeur d'identité suivante est affectée à chaque ligne suivante. Cette valeur est égale à la dernière valeur IDENTITY augmentée de la valeur increment. Si vous ne spécifiez ni seed ni increment , les deux arguments reçoivent par défaut la valeur 1.

• increment
  Entier à ajouter à la valeur seed pour les lignes successives de la table.

• column_name
  Nom de la colonne qui doit être insérée dans la nouvelle table.

Types des valeurs renvoyées

Renvoie le même type que data_type*.*

Notes

Étant donné que cette fonction crée une colonne dans une table, vous devez spécifier pour la colonne un nom figurant dans la liste de sélection de l'une des manières suivantes :

--(1)
SELECT IDENTITY(int, 1,1) AS ID_Num
INTO NewTable
FROM OldTable;

--(2)
SELECT ID_Num = IDENTITY(int, 1, 1)
INTO NewTable
FROM OldTable;

Exemple

L'exemple suivant insère toutes les lignes de la table Person de la base de données AdventureWorks2008R2 dans une nouvelle table appelée NewContact. La fonction IDENTITY est utilisée pour démarrer les numéros d'identification à 100 au lieu de 1 dans la table NewContact.

USE AdventureWorks2008R2;
GO
IF OBJECT_ID (N'Person.NewContact', N'U') IS NOT NULL
    DROP TABLE Person.NewContact;
GO
ALTER DATABASE AdventureWorks2008R2 SET RECOVERY BULK_LOGGED;
GO
SELECT  IDENTITY(smallint, 100, 1) AS ContactNum,
        FirstName AS First,
        LastName AS Last
INTO Person.NewContact
FROM Person.Person;
GO
ALTER DATABASE AdventureWorks2008R2 SET RECOVERY FULL;
GO
SELECT ContactNum, First, Last FROM Person.NewContact;
GO

Voir aussi

Référence

Concepts