DISABLE TRIGGER (Transact-SQL)

Syntaxe

DISABLE TRIGGER { [ schema_name . ] trigger_name [ ,...n ] | ALL }
ON { object_name | DATABASE | ALL SERVER } [ ; ]

Arguments

• schema_name
  Nom du schéma auquel appartient le déclencheur. schema_name ne peut pas être spécifié pour les déclencheurs DDL ou de connexion.

• trigger_name
  Nom du déclencheur à désactiver.

• ALL
  Indique que tous les déclencheurs définis sur l'étendue de la clause ON sont désactivés.

  Attention
  SQL Server crée des déclencheurs dans des bases de données qui sont publiées pour la réplication de fusion. Le fait de spécifier ALL dans les bases de données publiées désactive ces déclencheurs, ce qui interrompt la réplication. Vérifiez que la base de données active n'est pas publiée pour la réplication de fusion avant de spécifier ALL.

• object_name
  Nom de la table ou de la vue sur laquelle le déclencheur DML trigger_name a été créé pour s'exécuter.

• DATABASE
  Pour un déclencheur DDL, indique que trigger_name a été créé ou modifié pour s'exécuter sur l'étendue de la base de données.

• ALL SERVER
  Pour un déclencheur DDL, indique que trigger_name a été créé ou modifié pour s'exécuter sur l'étendue du serveur. ALL SERVER s'applique également aux déclencheurs de connexion.

Notes

Les déclencheurs sont activés par défaut lors de leur création. La désactivation d'un déclencheur ne le supprime pas. Il continue d'exister en tant qu'objet dans la base de données active. Cependant, il ne se déclenche pas lorsque des instructions Transact-SQL sur lesquelles il a été programmé sont exécutées. Il est possible de réactiver des déclencheurs à l'aide de ENABLE TRIGGER. Il est également possible d'activer ou de désactiver les déclencheurs DML définis sur des tables au moyen de la commande ALTER TABLE.

Autorisations

Pour désactiver un déclencheur DML, un utilisateur doit avoir au minimum l'autorisation ALTER pour la table ou la vue sur laquelle le déclencheur a été créé.

La désactivation d'un déclencheur DDL avec une étendue de serveur (ON ALL SERVER) ou d'un déclencheur de connexion nécessite l'autorisation CONTROL SERVER sur le serveur. Pour désactiver un déclencheur DDL sur l'étendue d'une base de données (ON DATABASE), un utilisateur doit avoir au minimum l'autorisation ALTER ANY DATABASE DDL TRIGGER pour la base de données active.

Exemples

A. Désactivation d'un déclencheur DML sur une table

USE AdventureWorks;
GO
DISABLE TRIGGER Person.uAddress ON Person.Address;
GO

B. Désactivation d'un déclencheur DDL

IF EXISTS (SELECT * FROM sys.triggers
    WHERE parent_class = 0 AND name = 'safety')
DROP TRIGGER safety ON DATABASE;
GO
CREATE TRIGGER safety 
ON DATABASE 
FOR DROP_TABLE, ALTER_TABLE 
AS 
   PRINT 'You must disable Trigger "safety" to drop or alter tables!' 
   ROLLBACK;
GO
DISABLE TRIGGER safety ON DATABASE;
GO

C. Désactivation de tous les déclencheurs définis sur la même étendue

USE AdventureWorks;
GO
DISABLE Trigger ALL ON ALL SERVER;
GO

Voir aussi

Référence