sp_helptracertokenhistory (Transact-SQL)

  • Article

S’applique à : SQL Server Azure SQL Managed Instance

Retourne des informations de latence détaillées pour des jetons de suivi donnés, avec une ligne retournée par abonné. Cette procédure stockée est exécutée sur la base de données de publication du serveur de publication ou sur la base de données de distribution du serveur de distribution.

Conventions de la syntaxe Transact-SQL

Syntaxe

sp_helptracertokenhistory
    [ @publication = ] N'publication'
    , [ @tracer_id = ] tracer_id
    [ , [ @publisher = ] N'publisher' ]
    [ , [ @publisher_db = ] N'publisher_db' ]
[ ; ]

Arguments

[ @publication = ] N’publication'

Nom de la composition dans laquelle le jeton de suivi a été inséré. @publication est sysname, sans valeur par défaut.

[ @tracer_id = ] tracer_id

ID du jeton de suivi dans la table MStracer_tokens , pour laquelle les informations d’historique sont retournées. @tracer_id est int, sans valeur par défaut.

[ @publisher = ] N’publisher'

Nom du serveur de publication. @publisher est sysname, avec la valeur par défaut NULL.

@publisher ne doit être spécifié que pour les serveurs de publication non-SQL Server.

[ @publisher_db = ] N’publisher_db'

Nom de la base de données de publication. @publisher_db est sysname, avec la valeur par défaut NULL. Ce paramètre est ignoré si la procédure stockée est exécutée sur le serveur de publication.

Jeu de résultats

Nom de la colonne Type de données Description
distributor_latency bigint Nombre de secondes s'écoulant entre la validation de l'enregistrement du jeton de suivi sur le serveur de publication et la validation de l'enregistrement sur le serveur de distribution.
subscriber sysname Nom de l'Abonné qui a reçu le jeton de suivi.
subscriber_db sysname Nom de la base de données d'abonnement dans laquelle l'enregistrement du jeton de suivi a été inséré.
subscriber_latency bigint Nombre de secondes s'écoulant entre la validation de l'enregistrement du jeton de suivi sur le serveur de distribution et la validation de l'enregistrement sur l'Abonné.
overall_latency bigint Nombre de secondes s'écoulant entre la validation de l'enregistrement du jeton de suivi sur le serveur de publication et la validation de l'enregistrement du jeton sur l'Abonné.

Valeurs des codes de retour

0 (réussite) ou 1 (échec).

Notes

sp_helptracertokenhistory est utilisé dans la réplication transactionnelle.

Exécutez sp_helptracertokens pour obtenir une liste de jetons de suivi pour la publication.

Une valeur du jeu de NULL résultats signifie que les statistiques de latence ne peuvent pas être calculées. Cela est dû au fait que le jeton de suivi n’a pas été reçu au serveur de distribution ou à l’un des abonnés.

Exemples

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2022]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

autorisations

Seuls les membres du rôle serveur fixe sysadmin , le rôle de base de données fixe db_owner dans la base de données de publication, ou db_owner base de données fixe ou les rôles replmonitor dans la base de données de distribution peuvent s’exécuter sp_helptracertokenhistory.

Contenu connexe