Exercice – définir des ressources enfants

• 10 minutes

Vous commencez à travailler sur les requêtes de votre équipe R&D et vous décidez de commencer par créer une base de données Azure Cosmos DB pour les données de test du drone-jouet. Dans cet exercice, vous crée le compte Azure Cosmos DB et deux ressources enfants, l’une à l’aide de la propriété parent et l’autre en tant que ressource imbriquée.

Pendant ce processus :

Cet exercice utilise l’extension Bicep pour Visual Studio Code. Assurez-vous d’installer cette extension dans Visual Studio Code.

Créer un modèle Bicep qui contient un compte Azure Cosmos DB

Tout d’abord, vous créez un nouveau modèle Bicep avec un compte Azure Cosmos DB. Pour cela, procédez de la façon suivante :

1. Ouvrez Visual Studio Code.

2. Créez un fichier nommé main.bicep.

3. Enregistrez le fichier vide afin que Visual Studio Code charge les outils Bicep.

   Vous pouvez soit sélectionner Fichier>Enregistrer sous, soit appuyer sur Ctrl+S dans Windows (⌘+S sur macOS). Assurez-vous de bien noter l’emplacement de sauvegarde du fichier. Vous pouvez par exemple créer un dossier scripts pour l’y enregistrer.

4. Ajoutez le contenu suivant au fichier. Il est judicieux de l’entrer manuellement plutôt que d’effectuer un copier-coller. De cette façon, vous pouvez voir comment les outils vous aident à écrire vos fichiers Bicep.

   param cosmosDBAccountName string = 'toyrnd-${uniqueString(resourceGroup().id)}'
   param location string = resourceGroup().location
   
   resource cosmosDBAccount 'Microsoft.DocumentDB/databaseAccounts@2024-05-15' = {
     name: cosmosDBAccountName
     location: location
     properties: {
       databaseAccountOfferType: 'Standard'
       locations: [
         {
           locationName: location
         }
       ]
     }
   }
   

   Conseil

   Bicep est strict quant à l’emplacement des sauts de ligne. Veillez donc à ajouter des sauts de ligne uniquement comme indiqué ici.

   Ce modèle Bicep déploie un compte Azure Cosmos DB qui est la ressource parente à générer dans la section suivante.

5. Enregistrez les modifications du fichier.

Ajouter une base de données

Ensuite, vous créez la base de données, qui est une ressource enfant du compte Azure Cosmos DB.

1. En haut du fichier, entre les deux paramètres existants, ajoutez le paramètre suivant :

   param cosmosDBDatabaseThroughput int = 400
   

2. Dans les déclarations de paramètre, ajoutez la variable suivante :

   var cosmosDBDatabaseName = 'FlightTests'
   

3. Ajoutez la définition de ressource suivante au bas du fichier, sous la définition de ressource de compte Azure Cosmos DB.

   resource cosmosDBDatabase 'Microsoft.DocumentDB/databaseAccounts/sqlDatabases@2024-05-15' = {
     parent: cosmosDBAccount
     name: cosmosDBDatabaseName
     properties: {
       resource: {
         id: cosmosDBDatabaseName
       }
       options: {
         throughput: cosmosDBDatabaseThroughput
       }
     }
   }
   

   Notez que ce code déploie la base de données, qui est une ressource enfant, à l’aide de la propriété parent. Remarquez également que le code utilise le type de ressource complet, avec la version de l’API spécifié explicitement.

4. Enregistrez les modifications du fichier.

Ajouter un conteneur

Vous ajoutez maintenant une autre ressource enfant. Cette fois, vous l’ajoutez en tant que ressource imbriquée plutôt que l’utilisation de la propriété parent.

1. Vers le haut du fichier, sous la définition de la variable cosmosDBDatabaseName, ajoutez les variables suivantes :

   var cosmosDBContainerName = 'FlightTests'
   var cosmosDBContainerPartitionKey = '/droneId'
   

2. Dans le bas du fichier, dans la définition de ressource de base de données et avant l’accolade fermante (}), ajoutez la définition de ressource imbriquée suivante :

   resource container 'containers' = {
     name: cosmosDBContainerName
     properties: {
       resource: {
         id: cosmosDBContainerName
         partitionKey: {
           kind: 'Hash'
           paths: [
             cosmosDBContainerPartitionKey
           ]
         }
       }
       options: {}
     }
   }
   

   Remarquez que vous avez utilisé un type de ressource court, containers, car Bicep comprend qu’il appartient au type de ressource parent. Bicep sait que le type de la ressource complet est Microsoft.DocumentDB/databaseAccounts/sqlDatabases/containers. Vous n’avez pas spécifié une version d’API. Bicep utilise donc la version de la ressource parent, 2020-04-01.

   Quand vous avez terminé, votre modèle Bicep entier doit ressembler à cet exemple :

   param cosmosDBAccountName string = 'toyrnd-${uniqueString(resourceGroup().id)}'
   param cosmosDBDatabaseThroughput int = 400
   param location string = resourceGroup().location
   
   var cosmosDBDatabaseName = 'FlightTests'
   var cosmosDBContainerName = 'FlightTests'
   var cosmosDBContainerPartitionKey = '/droneId'
   
   resource cosmosDBAccount 'Microsoft.DocumentDB/databaseAccounts@2024-05-15' = {
     name: cosmosDBAccountName
     location: location
     properties: {
       databaseAccountOfferType: 'Standard'
       locations: [
         {
           locationName: location
         }
       ]
     }
   }
   
   resource cosmosDBDatabase 'Microsoft.DocumentDB/databaseAccounts/sqlDatabases@2024-05-15' = {
     parent: cosmosDBAccount
     name: cosmosDBDatabaseName
     properties: {
       resource: {
         id: cosmosDBDatabaseName
       }
       options: {
         throughput: cosmosDBDatabaseThroughput
       }
     }
   
     resource container 'containers' = {
       name: cosmosDBContainerName
       properties: {
         resource: {
           id: cosmosDBContainerName
           partitionKey: {
             kind: 'Hash'
             paths: [
               cosmosDBContainerPartitionKey
             ]
           }
         }
         options: {}
       }
     }
   }
   

3. Enregistrez les modifications du fichier.

Déployer le modèle sur Azure

az bicep install && az bicep upgrade

az configure --defaults group="<rgn>[sandbox resource group name]</rgn>"

az deployment group create --template-file main.bicep

Set-AzDefault -ResourceGroupName <rgn>[sandbox resource group name]</rgn>

New-AzResourceGroupDeployment -TemplateFile main.bicep

Vérifier le déploiement

1. Accédez au portail Azure et vérifiez que vous êtes bien dans l’abonnement de bac à sable :

   1. Sélectionnez votre avatar dans le coin supérieur droit de la page.

   2. Sélectionnez Changer de répertoire. Dans la liste, choisissez le répertoire Bac à sable Microsoft Learn.

2. Sur la page d’accueil, sélectionnez Groupes de ressources. Le volet Groupes de ressources s’affiche.

3. Sélectionnez [nom du groupe de ressources du bac à sable].

4. Dans la Vue d’ensemble, vous voyez qu’un déploiement a réussi.

   

5. Sélectionnez 1 réussi pour afficher les détails du déploiement.

   

6. Sélectionnez le déploiement appelé main pour voir quelles ressources ont été déployées, puis sélectionnez Détails du déploiement pour le développer. Dans ce cas, un compte Cosmos DB, une base de données et un conteneur sont répertoriés.

   

7. Laissez la page ouverte dans votre navigateur afin de pouvoir vérifier les déploiements ultérieurement.